LAPACK  3.10.1 LAPACK: Linear Algebra PACKage

## ◆ ssyrfsx()

 subroutine ssyrfsx ( character UPLO, character EQUED, integer N, integer NRHS, real, dimension( lda, * ) A, integer LDA, real, dimension( ldaf, * ) AF, integer LDAF, integer, dimension( * ) IPIV, real, dimension( * ) S, real, dimension( ldb, * ) B, integer LDB, real, dimension( ldx, * ) X, integer LDX, real RCOND, real, dimension( * ) BERR, integer N_ERR_BNDS, real, dimension( nrhs, * ) ERR_BNDS_NORM, real, dimension( nrhs, * ) ERR_BNDS_COMP, integer NPARAMS, real, dimension( * ) PARAMS, real, dimension( * ) WORK, integer, dimension( * ) IWORK, integer INFO )

SSYRFSX

Purpose:
```    SSYRFSX improves the computed solution to a system of linear
equations when the coefficient matrix is symmetric indefinite, and
provides error bounds and backward error estimates for the
solution.  In addition to normwise error bound, the code provides
maximum componentwise error bound if possible.  See comments for
ERR_BNDS_NORM and ERR_BNDS_COMP for details of the error bounds.

The original system of linear equations may have been equilibrated
before calling this routine, as described by arguments EQUED and S
below. In this case, the solution and error bounds returned are
for the original unequilibrated system.```
```     Some optional parameters are bundled in the PARAMS array.  These
settings determine how refinement is performed, but often the
defaults are acceptable.  If the defaults are acceptable, users
can pass NPARAMS = 0 which prevents the source code from accessing
the PARAMS argument.```
Parameters
 [in] UPLO ``` UPLO is CHARACTER*1 = 'U': Upper triangle of A is stored; = 'L': Lower triangle of A is stored.``` [in] EQUED ``` EQUED is CHARACTER*1 Specifies the form of equilibration that was done to A before calling this routine. This is needed to compute the solution and error bounds correctly. = 'N': No equilibration = 'Y': Both row and column equilibration, i.e., A has been replaced by diag(S) * A * diag(S). The right hand side B has been changed accordingly.``` [in] N ``` N is INTEGER The order of the matrix A. N >= 0.``` [in] NRHS ``` NRHS is INTEGER The number of right hand sides, i.e., the number of columns of the matrices B and X. NRHS >= 0.``` [in] A ``` A is REAL array, dimension (LDA,N) The symmetric matrix A. If UPLO = 'U', the leading N-by-N upper triangular part of A contains the upper triangular part of the matrix A, and the strictly lower triangular part of A is not referenced. If UPLO = 'L', the leading N-by-N lower triangular part of A contains the lower triangular part of the matrix A, and the strictly upper triangular part of A is not referenced.``` [in] LDA ``` LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).``` [in] AF ``` AF is REAL array, dimension (LDAF,N) The factored form of the matrix A. AF contains the block diagonal matrix D and the multipliers used to obtain the factor U or L from the factorization A = U*D*U**T or A = L*D*L**T as computed by SSYTRF.``` [in] LDAF ``` LDAF is INTEGER The leading dimension of the array AF. LDAF >= max(1,N).``` [in] IPIV ``` IPIV is INTEGER array, dimension (N) Details of the interchanges and the block structure of D as determined by SSYTRF.``` [in,out] S ``` S is REAL array, dimension (N) The scale factors for A. If EQUED = 'Y', A is multiplied on the left and right by diag(S). S is an input argument if FACT = 'F'; otherwise, S is an output argument. If FACT = 'F' and EQUED = 'Y', each element of S must be positive. If S is output, each element of S is a power of the radix. If S is input, each element of S should be a power of the radix to ensure a reliable solution and error estimates. Scaling by powers of the radix does not cause rounding errors unless the result underflows or overflows. Rounding errors during scaling lead to refining with a matrix that is not equivalent to the input matrix, producing error estimates that may not be reliable.``` [in] B ``` B is REAL array, dimension (LDB,NRHS) The right hand side matrix B.``` [in] LDB ``` LDB is INTEGER The leading dimension of the array B. LDB >= max(1,N).``` [in,out] X ``` X is REAL array, dimension (LDX,NRHS) On entry, the solution matrix X, as computed by SGETRS. On exit, the improved solution matrix X.``` [in] LDX ``` LDX is INTEGER The leading dimension of the array X. LDX >= max(1,N).``` [out] RCOND ``` RCOND is REAL Reciprocal scaled condition number. This is an estimate of the reciprocal Skeel condition number of the matrix A after equilibration (if done). If this is less than the machine precision (in particular, if it is zero), the matrix is singular to working precision. Note that the error may still be small even if this number is very small and the matrix appears ill- conditioned.``` [out] BERR ``` BERR is REAL array, dimension (NRHS) Componentwise relative backward error. This is the componentwise relative backward error of each solution vector X(j) (i.e., the smallest relative change in any element of A or B that makes X(j) an exact solution).``` [in] N_ERR_BNDS ``` N_ERR_BNDS is INTEGER Number of error bounds to return for each right hand side and each type (normwise or componentwise). See ERR_BNDS_NORM and ERR_BNDS_COMP below.``` [out] ERR_BNDS_NORM ``` ERR_BNDS_NORM is REAL array, dimension (NRHS, N_ERR_BNDS) For each right-hand side, this array contains information about various error bounds and condition numbers corresponding to the normwise relative error, which is defined as follows: Normwise relative error in the ith solution vector: max_j (abs(XTRUE(j,i) - X(j,i))) ------------------------------ max_j abs(X(j,i)) The array is indexed by the type of error information as described below. There currently are up to three pieces of information returned. The first index in ERR_BNDS_NORM(i,:) corresponds to the ith right-hand side. The second index in ERR_BNDS_NORM(:,err) contains the following three fields: err = 1 "Trust/don't trust" boolean. Trust the answer if the reciprocal condition number is less than the threshold sqrt(n) * slamch('Epsilon'). err = 2 "Guaranteed" error bound: The estimated forward error, almost certainly within a factor of 10 of the true error so long as the next entry is greater than the threshold sqrt(n) * slamch('Epsilon'). This error bound should only be trusted if the previous boolean is true. err = 3 Reciprocal condition number: Estimated normwise reciprocal condition number. Compared with the threshold sqrt(n) * slamch('Epsilon') to determine if the error estimate is "guaranteed". These reciprocal condition numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some appropriately scaled matrix Z. Let Z = S*A, where S scales each row by a power of the radix so all absolute row sums of Z are approximately 1. See Lapack Working Note 165 for further details and extra cautions.``` [out] ERR_BNDS_COMP ``` ERR_BNDS_COMP is REAL array, dimension (NRHS, N_ERR_BNDS) For each right-hand side, this array contains information about various error bounds and condition numbers corresponding to the componentwise relative error, which is defined as follows: Componentwise relative error in the ith solution vector: abs(XTRUE(j,i) - X(j,i)) max_j ---------------------- abs(X(j,i)) The array is indexed by the right-hand side i (on which the componentwise relative error depends), and the type of error information as described below. There currently are up to three pieces of information returned for each right-hand side. If componentwise accuracy is not requested (PARAMS(3) = 0.0), then ERR_BNDS_COMP is not accessed. If N_ERR_BNDS < 3, then at most the first (:,N_ERR_BNDS) entries are returned. The first index in ERR_BNDS_COMP(i,:) corresponds to the ith right-hand side. The second index in ERR_BNDS_COMP(:,err) contains the following three fields: err = 1 "Trust/don't trust" boolean. Trust the answer if the reciprocal condition number is less than the threshold sqrt(n) * slamch('Epsilon'). err = 2 "Guaranteed" error bound: The estimated forward error, almost certainly within a factor of 10 of the true error so long as the next entry is greater than the threshold sqrt(n) * slamch('Epsilon'). This error bound should only be trusted if the previous boolean is true. err = 3 Reciprocal condition number: Estimated componentwise reciprocal condition number. Compared with the threshold sqrt(n) * slamch('Epsilon') to determine if the error estimate is "guaranteed". These reciprocal condition numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some appropriately scaled matrix Z. Let Z = S*(A*diag(x)), where x is the solution for the current right-hand side and S scales each row of A*diag(x) by a power of the radix so all absolute row sums of Z are approximately 1. See Lapack Working Note 165 for further details and extra cautions.``` [in] NPARAMS ``` NPARAMS is INTEGER Specifies the number of parameters set in PARAMS. If <= 0, the PARAMS array is never referenced and default values are used.``` [in,out] PARAMS ``` PARAMS is REAL array, dimension NPARAMS Specifies algorithm parameters. If an entry is < 0.0, then that entry will be filled with default value used for that parameter. Only positions up to NPARAMS are accessed; defaults are used for higher-numbered parameters. PARAMS(LA_LINRX_ITREF_I = 1) : Whether to perform iterative refinement or not. Default: 1.0 = 0.0: No refinement is performed, and no error bounds are computed. = 1.0: Use the double-precision refinement algorithm, possibly with doubled-single computations if the compilation environment does not support DOUBLE PRECISION. (other values are reserved for future use) PARAMS(LA_LINRX_ITHRESH_I = 2) : Maximum number of residual computations allowed for refinement. Default: 10 Aggressive: Set to 100 to permit convergence using approximate factorizations or factorizations other than LU. If the factorization uses a technique other than Gaussian elimination, the guarantees in err_bnds_norm and err_bnds_comp may no longer be trustworthy. PARAMS(LA_LINRX_CWISE_I = 3) : Flag determining if the code will attempt to find a solution with small componentwise relative error in the double-precision algorithm. Positive is true, 0.0 is false. Default: 1.0 (attempt componentwise convergence)``` [out] WORK ` WORK is REAL array, dimension (4*N)` [out] IWORK ` IWORK is INTEGER array, dimension (N)` [out] INFO ``` INFO is INTEGER = 0: Successful exit. The solution to every right-hand side is guaranteed. < 0: If INFO = -i, the i-th argument had an illegal value > 0 and <= N: U(INFO,INFO) is exactly zero. The factorization has been completed, but the factor U is exactly singular, so the solution and error bounds could not be computed. RCOND = 0 is returned. = N+J: The solution corresponding to the Jth right-hand side is not guaranteed. The solutions corresponding to other right- hand sides K with K > J may not be guaranteed as well, but only the first such right-hand side is reported. If a small componentwise error is not requested (PARAMS(3) = 0.0) then the Jth right-hand side is the first with a normwise error bound that is not guaranteed (the smallest J such that ERR_BNDS_NORM(J,1) = 0.0). By default (PARAMS(3) = 1.0) the Jth right-hand side is the first with either a normwise or componentwise error bound that is not guaranteed (the smallest J such that either ERR_BNDS_NORM(J,1) = 0.0 or ERR_BNDS_COMP(J,1) = 0.0). See the definition of ERR_BNDS_NORM(:,1) and ERR_BNDS_COMP(:,1). To get information about all of the right-hand sides check ERR_BNDS_NORM or ERR_BNDS_COMP.```

Definition at line 398 of file ssyrfsx.f.

402 *
403 * -- LAPACK computational routine --
404 * -- LAPACK is a software package provided by Univ. of Tennessee, --
405 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
406 *
407 * .. Scalar Arguments ..
408  CHARACTER UPLO, EQUED
409  INTEGER INFO, LDA, LDAF, LDB, LDX, N, NRHS, NPARAMS,
410  \$ N_ERR_BNDS
411  REAL RCOND
412 * ..
413 * .. Array Arguments ..
414  INTEGER IPIV( * ), IWORK( * )
415  REAL A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
416  \$ X( LDX, * ), WORK( * )
417  REAL S( * ), PARAMS( * ), BERR( * ),
418  \$ ERR_BNDS_NORM( NRHS, * ),
419  \$ ERR_BNDS_COMP( NRHS, * )
420 * ..
421 *
422 * ==================================================================
423 *
424 * .. Parameters ..
425  REAL ZERO, ONE
426  parameter( zero = 0.0e+0, one = 1.0e+0 )
427  REAL ITREF_DEFAULT, ITHRESH_DEFAULT,
428  \$ COMPONENTWISE_DEFAULT
429  REAL RTHRESH_DEFAULT, DZTHRESH_DEFAULT
430  parameter( itref_default = 1.0 )
431  parameter( ithresh_default = 10.0 )
432  parameter( componentwise_default = 1.0 )
433  parameter( rthresh_default = 0.5 )
434  parameter( dzthresh_default = 0.25 )
435  INTEGER LA_LINRX_ITREF_I, LA_LINRX_ITHRESH_I,
436  \$ LA_LINRX_CWISE_I
437  parameter( la_linrx_itref_i = 1,
438  \$ la_linrx_ithresh_i = 2 )
439  parameter( la_linrx_cwise_i = 3 )
440  INTEGER LA_LINRX_TRUST_I, LA_LINRX_ERR_I,
441  \$ LA_LINRX_RCOND_I
442  parameter( la_linrx_trust_i = 1, la_linrx_err_i = 2 )
443  parameter( la_linrx_rcond_i = 3 )
444 * ..
445 * .. Local Scalars ..
446  CHARACTER(1) NORM
447  LOGICAL RCEQU
448  INTEGER J, PREC_TYPE, REF_TYPE, N_NORMS
449  REAL ANORM, RCOND_TMP
450  REAL ILLRCOND_THRESH, ERR_LBND, CWISE_WRONG
451  LOGICAL IGNORE_CWISE
452  INTEGER ITHRESH
453  REAL RTHRESH, UNSTABLE_THRESH
454 * ..
455 * .. External Subroutines ..
457 * ..
458 * .. Intrinsic Functions ..
459  INTRINSIC max, sqrt
460 * ..
461 * .. External Functions ..
462  EXTERNAL lsame, ilaprec
463  EXTERNAL slamch, slansy, sla_syrcond
464  REAL SLAMCH, SLANSY, SLA_SYRCOND
465  LOGICAL LSAME
466  INTEGER ILAPREC
467 * ..
468 * .. Executable Statements ..
469 *
470 * Check the input parameters.
471 *
472  info = 0
473  ref_type = int( itref_default )
474  IF ( nparams .GE. la_linrx_itref_i ) THEN
475  IF ( params( la_linrx_itref_i ) .LT. 0.0 ) THEN
476  params( la_linrx_itref_i ) = itref_default
477  ELSE
478  ref_type = params( la_linrx_itref_i )
479  END IF
480  END IF
481 *
482 * Set default parameters.
483 *
484  illrcond_thresh = real( n )*slamch( 'Epsilon' )
485  ithresh = int( ithresh_default )
486  rthresh = rthresh_default
487  unstable_thresh = dzthresh_default
488  ignore_cwise = componentwise_default .EQ. 0.0
489 *
490  IF ( nparams.GE.la_linrx_ithresh_i ) THEN
491  IF ( params( la_linrx_ithresh_i ).LT.0.0 ) THEN
492  params( la_linrx_ithresh_i ) = ithresh
493  ELSE
494  ithresh = int( params( la_linrx_ithresh_i ) )
495  END IF
496  END IF
497  IF ( nparams.GE.la_linrx_cwise_i ) THEN
498  IF ( params( la_linrx_cwise_i ).LT.0.0 ) THEN
499  IF ( ignore_cwise ) THEN
500  params( la_linrx_cwise_i ) = 0.0
501  ELSE
502  params( la_linrx_cwise_i ) = 1.0
503  END IF
504  ELSE
505  ignore_cwise = params( la_linrx_cwise_i ) .EQ. 0.0
506  END IF
507  END IF
508  IF ( ref_type .EQ. 0 .OR. n_err_bnds .EQ. 0 ) THEN
509  n_norms = 0
510  ELSE IF ( ignore_cwise ) THEN
511  n_norms = 1
512  ELSE
513  n_norms = 2
514  END IF
515 *
516  rcequ = lsame( equed, 'Y' )
517 *
518 * Test input parameters.
519 *
520  IF ( .NOT.lsame( uplo, 'U' ) .AND. .NOT.lsame( uplo, 'L' ) ) THEN
521  info = -1
522  ELSE IF( .NOT.rcequ .AND. .NOT.lsame( equed, 'N' ) ) THEN
523  info = -2
524  ELSE IF( n.LT.0 ) THEN
525  info = -3
526  ELSE IF( nrhs.LT.0 ) THEN
527  info = -4
528  ELSE IF( lda.LT.max( 1, n ) ) THEN
529  info = -6
530  ELSE IF( ldaf.LT.max( 1, n ) ) THEN
531  info = -8
532  ELSE IF( ldb.LT.max( 1, n ) ) THEN
533  info = -12
534  ELSE IF( ldx.LT.max( 1, n ) ) THEN
535  info = -14
536  END IF
537  IF( info.NE.0 ) THEN
538  CALL xerbla( 'SSYRFSX', -info )
539  RETURN
540  END IF
541 *
542 * Quick return if possible.
543 *
544  IF( n.EQ.0 .OR. nrhs.EQ.0 ) THEN
545  rcond = 1.0
546  DO j = 1, nrhs
547  berr( j ) = 0.0
548  IF ( n_err_bnds .GE. 1 ) THEN
549  err_bnds_norm( j, la_linrx_trust_i ) = 1.0
550  err_bnds_comp( j, la_linrx_trust_i ) = 1.0
551  END IF
552  IF ( n_err_bnds .GE. 2 ) THEN
553  err_bnds_norm( j, la_linrx_err_i ) = 0.0
554  err_bnds_comp( j, la_linrx_err_i ) = 0.0
555  END IF
556  IF ( n_err_bnds .GE. 3 ) THEN
557  err_bnds_norm( j, la_linrx_rcond_i ) = 1.0
558  err_bnds_comp( j, la_linrx_rcond_i ) = 1.0
559  END IF
560  END DO
561  RETURN
562  END IF
563 *
564 * Default to failure.
565 *
566  rcond = 0.0
567  DO j = 1, nrhs
568  berr( j ) = 1.0
569  IF ( n_err_bnds .GE. 1 ) THEN
570  err_bnds_norm( j, la_linrx_trust_i ) = 1.0
571  err_bnds_comp( j, la_linrx_trust_i ) = 1.0
572  END IF
573  IF ( n_err_bnds .GE. 2 ) THEN
574  err_bnds_norm( j, la_linrx_err_i ) = 1.0
575  err_bnds_comp( j, la_linrx_err_i ) = 1.0
576  END IF
577  IF ( n_err_bnds .GE. 3 ) THEN
578  err_bnds_norm( j, la_linrx_rcond_i ) = 0.0
579  err_bnds_comp( j, la_linrx_rcond_i ) = 0.0
580  END IF
581  END DO
582 *
583 * Compute the norm of A and the reciprocal of the condition
584 * number of A.
585 *
586  norm = 'I'
587  anorm = slansy( norm, uplo, n, a, lda, work )
588  CALL ssycon( uplo, n, af, ldaf, ipiv, anorm, rcond, work,
589  \$ iwork, info )
590 *
591 * Perform refinement on each right-hand side
592 *
593  IF ( ref_type .NE. 0 ) THEN
594
595  prec_type = ilaprec( 'D' )
596
597  CALL sla_syrfsx_extended( prec_type, uplo, n,
598  \$ nrhs, a, lda, af, ldaf, ipiv, rcequ, s, b,
599  \$ ldb, x, ldx, berr, n_norms, err_bnds_norm, err_bnds_comp,
600  \$ work( n+1 ), work( 1 ), work( 2*n+1 ), work( 1 ), rcond,
601  \$ ithresh, rthresh, unstable_thresh, ignore_cwise,
602  \$ info )
603  END IF
604
605  err_lbnd = max( 10.0, sqrt( real( n ) ) )*slamch( 'Epsilon' )
606  IF (n_err_bnds .GE. 1 .AND. n_norms .GE. 1) THEN
607 *
608 * Compute scaled normwise condition number cond(A*C).
609 *
610  IF ( rcequ ) THEN
611  rcond_tmp = sla_syrcond( uplo, n, a, lda, af, ldaf, ipiv,
612  \$ -1, s, info, work, iwork )
613  ELSE
614  rcond_tmp = sla_syrcond( uplo, n, a, lda, af, ldaf, ipiv,
615  \$ 0, s, info, work, iwork )
616  END IF
617  DO j = 1, nrhs
618 *
619 * Cap the error at 1.0.
620 *
621  IF (n_err_bnds .GE. la_linrx_err_i
622  \$ .AND. err_bnds_norm( j, la_linrx_err_i ) .GT. 1.0)
623  \$ err_bnds_norm( j, la_linrx_err_i ) = 1.0
624 *
625 * Threshold the error (see LAWN).
626 *
627  IF ( rcond_tmp .LT. illrcond_thresh ) THEN
628  err_bnds_norm( j, la_linrx_err_i ) = 1.0
629  err_bnds_norm( j, la_linrx_trust_i ) = 0.0
630  IF ( info .LE. n ) info = n + j
631  ELSE IF (err_bnds_norm( j, la_linrx_err_i ) .LT. err_lbnd)
632  \$ THEN
633  err_bnds_norm( j, la_linrx_err_i ) = err_lbnd
634  err_bnds_norm( j, la_linrx_trust_i ) = 1.0
635  END IF
636 *
637 * Save the condition number.
638 *
639  IF (n_err_bnds .GE. la_linrx_rcond_i) THEN
640  err_bnds_norm( j, la_linrx_rcond_i ) = rcond_tmp
641  END IF
642  END DO
643  END IF
644
645  IF ( n_err_bnds .GE. 1 .AND. n_norms .GE. 2 ) THEN
646 *
647 * Compute componentwise condition number cond(A*diag(Y(:,J))) for
648 * each right-hand side using the current solution as an estimate of
649 * the true solution. If the componentwise error estimate is too
650 * large, then the solution is a lousy estimate of truth and the
651 * estimated RCOND may be too optimistic. To avoid misleading users,
652 * the inverse condition number is set to 0.0 when the estimated
653 * cwise error is at least CWISE_WRONG.
654 *
655  cwise_wrong = sqrt( slamch( 'Epsilon' ) )
656  DO j = 1, nrhs
657  IF ( err_bnds_comp( j, la_linrx_err_i ) .LT. cwise_wrong )
658  \$ THEN
659  rcond_tmp = sla_syrcond( uplo, n, a, lda, af, ldaf, ipiv,
660  \$ 1, x(1,j), info, work, iwork )
661  ELSE
662  rcond_tmp = 0.0
663  END IF
664 *
665 * Cap the error at 1.0.
666 *
667  IF ( n_err_bnds .GE. la_linrx_err_i
668  \$ .AND. err_bnds_comp( j, la_linrx_err_i ) .GT. 1.0 )
669  \$ err_bnds_comp( j, la_linrx_err_i ) = 1.0
670 *
671 * Threshold the error (see LAWN).
672 *
673  IF ( rcond_tmp .LT. illrcond_thresh ) THEN
674  err_bnds_comp( j, la_linrx_err_i ) = 1.0
675  err_bnds_comp( j, la_linrx_trust_i ) = 0.0
676  IF ( .NOT. ignore_cwise
677  \$ .AND. info.LT.n + j ) info = n + j
678  ELSE IF ( err_bnds_comp( j, la_linrx_err_i )
679  \$ .LT. err_lbnd ) THEN
680  err_bnds_comp( j, la_linrx_err_i ) = err_lbnd
681  err_bnds_comp( j, la_linrx_trust_i ) = 1.0
682  END IF
683 *
684 * Save the condition number.
685 *
686  IF ( n_err_bnds .GE. la_linrx_rcond_i ) THEN
687  err_bnds_comp( j, la_linrx_rcond_i ) = rcond_tmp
688  END IF
689
690  END DO
691  END IF
692 *
693  RETURN
694 *
695 * End of SSYRFSX
696 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
integer function ilaprec(PREC)
ILAPREC
Definition: ilaprec.f:58
real function slansy(NORM, UPLO, N, A, LDA, WORK)
SLANSY returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition: slansy.f:122
real function sla_syrcond(UPLO, N, A, LDA, AF, LDAF, IPIV, CMODE, C, INFO, WORK, IWORK)
SLA_SYRCOND estimates the Skeel condition number for a symmetric indefinite matrix.
Definition: sla_syrcond.f:146
subroutine sla_syrfsx_extended(PREC_TYPE, UPLO, N, NRHS, A, LDA, AF, LDAF, IPIV, COLEQU, C, B, LDB, Y, LDY, BERR_OUT, N_NORMS, ERR_BNDS_NORM, ERR_BNDS_COMP, RES, AYB, DY, Y_TAIL, RCOND, ITHRESH, RTHRESH, DZ_UB, IGNORE_CWISE, INFO)
SLA_SYRFSX_EXTENDED improves the computed solution to a system of linear equations for symmetric inde...
subroutine ssycon(UPLO, N, A, LDA, IPIV, ANORM, RCOND, WORK, IWORK, INFO)
SSYCON
Definition: ssycon.f:130
real function slamch(CMACH)
SLAMCH
Definition: slamch.f:68
Here is the call graph for this function:
Here is the caller graph for this function: