LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
sla_gerfsx_extended.f
Go to the documentation of this file.
1 *> \brief \b SLA_GERFSX_EXTENDED improves the computed solution to a system of linear equations for general matrices by performing extra-precise iterative refinement and provides error bounds and backward error estimates for the solution.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download SLA_GERFSX_EXTENDED + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sla_gerfsx_extended.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sla_gerfsx_extended.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sla_gerfsx_extended.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE SLA_GERFSX_EXTENDED( PREC_TYPE, TRANS_TYPE, N, NRHS, A,
22 * LDA, AF, LDAF, IPIV, COLEQU, C, B,
23 * LDB, Y, LDY, BERR_OUT, N_NORMS,
24 * ERRS_N, ERRS_C, RES,
25 * AYB, DY, Y_TAIL, RCOND, ITHRESH,
26 * RTHRESH, DZ_UB, IGNORE_CWISE,
27 * INFO )
28 *
29 * .. Scalar Arguments ..
30 * INTEGER INFO, LDA, LDAF, LDB, LDY, N, NRHS, PREC_TYPE,
31 * $ TRANS_TYPE, N_NORMS, ITHRESH
32 * LOGICAL COLEQU, IGNORE_CWISE
33 * REAL RTHRESH, DZ_UB
34 * ..
35 * .. Array Arguments ..
36 * INTEGER IPIV( * )
37 * REAL A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
38 * $ Y( LDY, * ), RES( * ), DY( * ), Y_TAIL( * )
39 * REAL C( * ), AYB( * ), RCOND, BERR_OUT( * ),
40 * $ ERRS_N( NRHS, * ),
41 * $ ERRS_C( NRHS, * )
42 * ..
43 *
44 *
45 *> \par Purpose:
46 * =============
47 *>
48 *> \verbatim
49 *>
50 *> SLA_GERFSX_EXTENDED improves the computed solution to a system of
51 *> linear equations by performing extra-precise iterative refinement
52 *> and provides error bounds and backward error estimates for the solution.
53 *> This subroutine is called by SGERFSX to perform iterative refinement.
54 *> In addition to normwise error bound, the code provides maximum
55 *> componentwise error bound if possible. See comments for ERRS_N
56 *> and ERRS_C for details of the error bounds. Note that this
57 *> subroutine is only resonsible for setting the second fields of
58 *> ERRS_N and ERRS_C.
59 *> \endverbatim
60 *
61 * Arguments:
62 * ==========
63 *
64 *> \param[in] PREC_TYPE
65 *> \verbatim
66 *> PREC_TYPE is INTEGER
67 *> Specifies the intermediate precision to be used in refinement.
68 *> The value is defined by ILAPREC(P) where P is a CHARACTER and
69 *> P = 'S': Single
70 *> = 'D': Double
71 *> = 'I': Indigenous
72 *> = 'X', 'E': Extra
73 *> \endverbatim
74 *>
75 *> \param[in] TRANS_TYPE
76 *> \verbatim
77 *> TRANS_TYPE is INTEGER
78 *> Specifies the transposition operation on A.
79 *> The value is defined by ILATRANS(T) where T is a CHARACTER and
80 *> T = 'N': No transpose
81 *> = 'T': Transpose
82 *> = 'C': Conjugate transpose
83 *> \endverbatim
84 *>
85 *> \param[in] N
86 *> \verbatim
87 *> N is INTEGER
88 *> The number of linear equations, i.e., the order of the
89 *> matrix A. N >= 0.
90 *> \endverbatim
91 *>
92 *> \param[in] NRHS
93 *> \verbatim
94 *> NRHS is INTEGER
95 *> The number of right-hand-sides, i.e., the number of columns of the
96 *> matrix B.
97 *> \endverbatim
98 *>
99 *> \param[in] A
100 *> \verbatim
101 *> A is REAL array, dimension (LDA,N)
102 *> On entry, the N-by-N matrix A.
103 *> \endverbatim
104 *>
105 *> \param[in] LDA
106 *> \verbatim
107 *> LDA is INTEGER
108 *> The leading dimension of the array A. LDA >= max(1,N).
109 *> \endverbatim
110 *>
111 *> \param[in] AF
112 *> \verbatim
113 *> AF is REAL array, dimension (LDAF,N)
114 *> The factors L and U from the factorization
115 *> A = P*L*U as computed by SGETRF.
116 *> \endverbatim
117 *>
118 *> \param[in] LDAF
119 *> \verbatim
120 *> LDAF is INTEGER
121 *> The leading dimension of the array AF. LDAF >= max(1,N).
122 *> \endverbatim
123 *>
124 *> \param[in] IPIV
125 *> \verbatim
126 *> IPIV is INTEGER array, dimension (N)
127 *> The pivot indices from the factorization A = P*L*U
128 *> as computed by SGETRF; row i of the matrix was interchanged
129 *> with row IPIV(i).
130 *> \endverbatim
131 *>
132 *> \param[in] COLEQU
133 *> \verbatim
134 *> COLEQU is LOGICAL
135 *> If .TRUE. then column equilibration was done to A before calling
136 *> this routine. This is needed to compute the solution and error
137 *> bounds correctly.
138 *> \endverbatim
139 *>
140 *> \param[in] C
141 *> \verbatim
142 *> C is REAL array, dimension (N)
143 *> The column scale factors for A. If COLEQU = .FALSE., C
144 *> is not accessed. If C is input, each element of C should be a power
145 *> of the radix to ensure a reliable solution and error estimates.
146 *> Scaling by powers of the radix does not cause rounding errors unless
147 *> the result underflows or overflows. Rounding errors during scaling
148 *> lead to refining with a matrix that is not equivalent to the
149 *> input matrix, producing error estimates that may not be
150 *> reliable.
151 *> \endverbatim
152 *>
153 *> \param[in] B
154 *> \verbatim
155 *> B is REAL array, dimension (LDB,NRHS)
156 *> The right-hand-side matrix B.
157 *> \endverbatim
158 *>
159 *> \param[in] LDB
160 *> \verbatim
161 *> LDB is INTEGER
162 *> The leading dimension of the array B. LDB >= max(1,N).
163 *> \endverbatim
164 *>
165 *> \param[in,out] Y
166 *> \verbatim
167 *> Y is REAL array, dimension (LDY,NRHS)
168 *> On entry, the solution matrix X, as computed by SGETRS.
169 *> On exit, the improved solution matrix Y.
170 *> \endverbatim
171 *>
172 *> \param[in] LDY
173 *> \verbatim
174 *> LDY is INTEGER
175 *> The leading dimension of the array Y. LDY >= max(1,N).
176 *> \endverbatim
177 *>
178 *> \param[out] BERR_OUT
179 *> \verbatim
180 *> BERR_OUT is REAL array, dimension (NRHS)
181 *> On exit, BERR_OUT(j) contains the componentwise relative backward
182 *> error for right-hand-side j from the formula
183 *> max(i) ( abs(RES(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
184 *> where abs(Z) is the componentwise absolute value of the matrix
185 *> or vector Z. This is computed by SLA_LIN_BERR.
186 *> \endverbatim
187 *>
188 *> \param[in] N_NORMS
189 *> \verbatim
190 *> N_NORMS is INTEGER
191 *> Determines which error bounds to return (see ERRS_N
192 *> and ERRS_C).
193 *> If N_NORMS >= 1 return normwise error bounds.
194 *> If N_NORMS >= 2 return componentwise error bounds.
195 *> \endverbatim
196 *>
197 *> \param[in,out] ERRS_N
198 *> \verbatim
199 *> ERRS_N is REAL array, dimension (NRHS, N_ERR_BNDS)
200 *> For each right-hand side, this array contains information about
201 *> various error bounds and condition numbers corresponding to the
202 *> normwise relative error, which is defined as follows:
203 *>
204 *> Normwise relative error in the ith solution vector:
205 *> max_j (abs(XTRUE(j,i) - X(j,i)))
206 *> ------------------------------
207 *> max_j abs(X(j,i))
208 *>
209 *> The array is indexed by the type of error information as described
210 *> below. There currently are up to three pieces of information
211 *> returned.
212 *>
213 *> The first index in ERRS_N(i,:) corresponds to the ith
214 *> right-hand side.
215 *>
216 *> The second index in ERRS_N(:,err) contains the following
217 *> three fields:
218 *> err = 1 "Trust/don't trust" boolean. Trust the answer if the
219 *> reciprocal condition number is less than the threshold
220 *> sqrt(n) * slamch('Epsilon').
221 *>
222 *> err = 2 "Guaranteed" error bound: The estimated forward error,
223 *> almost certainly within a factor of 10 of the true error
224 *> so long as the next entry is greater than the threshold
225 *> sqrt(n) * slamch('Epsilon'). This error bound should only
226 *> be trusted if the previous boolean is true.
227 *>
228 *> err = 3 Reciprocal condition number: Estimated normwise
229 *> reciprocal condition number. Compared with the threshold
230 *> sqrt(n) * slamch('Epsilon') to determine if the error
231 *> estimate is "guaranteed". These reciprocal condition
232 *> numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
233 *> appropriately scaled matrix Z.
234 *> Let Z = S*A, where S scales each row by a power of the
235 *> radix so all absolute row sums of Z are approximately 1.
236 *>
237 *> This subroutine is only responsible for setting the second field
238 *> above.
239 *> See Lapack Working Note 165 for further details and extra
240 *> cautions.
241 *> \endverbatim
242 *>
243 *> \param[in,out] ERRS_C
244 *> \verbatim
245 *> ERRS_C is REAL array, dimension (NRHS, N_ERR_BNDS)
246 *> For each right-hand side, this array contains information about
247 *> various error bounds and condition numbers corresponding to the
248 *> componentwise relative error, which is defined as follows:
249 *>
250 *> Componentwise relative error in the ith solution vector:
251 *> abs(XTRUE(j,i) - X(j,i))
252 *> max_j ----------------------
253 *> abs(X(j,i))
254 *>
255 *> The array is indexed by the right-hand side i (on which the
256 *> componentwise relative error depends), and the type of error
257 *> information as described below. There currently are up to three
258 *> pieces of information returned for each right-hand side. If
259 *> componentwise accuracy is not requested (PARAMS(3) = 0.0), then
260 *> ERRS_C is not accessed. If N_ERR_BNDS .LT. 3, then at most
261 *> the first (:,N_ERR_BNDS) entries are returned.
262 *>
263 *> The first index in ERRS_C(i,:) corresponds to the ith
264 *> right-hand side.
265 *>
266 *> The second index in ERRS_C(:,err) contains the following
267 *> three fields:
268 *> err = 1 "Trust/don't trust" boolean. Trust the answer if the
269 *> reciprocal condition number is less than the threshold
270 *> sqrt(n) * slamch('Epsilon').
271 *>
272 *> err = 2 "Guaranteed" error bound: The estimated forward error,
273 *> almost certainly within a factor of 10 of the true error
274 *> so long as the next entry is greater than the threshold
275 *> sqrt(n) * slamch('Epsilon'). This error bound should only
276 *> be trusted if the previous boolean is true.
277 *>
278 *> err = 3 Reciprocal condition number: Estimated componentwise
279 *> reciprocal condition number. Compared with the threshold
280 *> sqrt(n) * slamch('Epsilon') to determine if the error
281 *> estimate is "guaranteed". These reciprocal condition
282 *> numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
283 *> appropriately scaled matrix Z.
284 *> Let Z = S*(A*diag(x)), where x is the solution for the
285 *> current right-hand side and S scales each row of
286 *> A*diag(x) by a power of the radix so all absolute row
287 *> sums of Z are approximately 1.
288 *>
289 *> This subroutine is only responsible for setting the second field
290 *> above.
291 *> See Lapack Working Note 165 for further details and extra
292 *> cautions.
293 *> \endverbatim
294 *>
295 *> \param[in] RES
296 *> \verbatim
297 *> RES is REAL array, dimension (N)
298 *> Workspace to hold the intermediate residual.
299 *> \endverbatim
300 *>
301 *> \param[in] AYB
302 *> \verbatim
303 *> AYB is REAL array, dimension (N)
304 *> Workspace. This can be the same workspace passed for Y_TAIL.
305 *> \endverbatim
306 *>
307 *> \param[in] DY
308 *> \verbatim
309 *> DY is REAL array, dimension (N)
310 *> Workspace to hold the intermediate solution.
311 *> \endverbatim
312 *>
313 *> \param[in] Y_TAIL
314 *> \verbatim
315 *> Y_TAIL is REAL array, dimension (N)
316 *> Workspace to hold the trailing bits of the intermediate solution.
317 *> \endverbatim
318 *>
319 *> \param[in] RCOND
320 *> \verbatim
321 *> RCOND is REAL
322 *> Reciprocal scaled condition number. This is an estimate of the
323 *> reciprocal Skeel condition number of the matrix A after
324 *> equilibration (if done). If this is less than the machine
325 *> precision (in particular, if it is zero), the matrix is singular
326 *> to working precision. Note that the error may still be small even
327 *> if this number is very small and the matrix appears ill-
328 *> conditioned.
329 *> \endverbatim
330 *>
331 *> \param[in] ITHRESH
332 *> \verbatim
333 *> ITHRESH is INTEGER
334 *> The maximum number of residual computations allowed for
335 *> refinement. The default is 10. For 'aggressive' set to 100 to
336 *> permit convergence using approximate factorizations or
337 *> factorizations other than LU. If the factorization uses a
338 *> technique other than Gaussian elimination, the guarantees in
339 *> ERRS_N and ERRS_C may no longer be trustworthy.
340 *> \endverbatim
341 *>
342 *> \param[in] RTHRESH
343 *> \verbatim
344 *> RTHRESH is REAL
345 *> Determines when to stop refinement if the error estimate stops
346 *> decreasing. Refinement will stop when the next solution no longer
347 *> satisfies norm(dx_{i+1}) < RTHRESH * norm(dx_i) where norm(Z) is
348 *> the infinity norm of Z. RTHRESH satisfies 0 < RTHRESH <= 1. The
349 *> default value is 0.5. For 'aggressive' set to 0.9 to permit
350 *> convergence on extremely ill-conditioned matrices. See LAWN 165
351 *> for more details.
352 *> \endverbatim
353 *>
354 *> \param[in] DZ_UB
355 *> \verbatim
356 *> DZ_UB is REAL
357 *> Determines when to start considering componentwise convergence.
358 *> Componentwise convergence is only considered after each component
359 *> of the solution Y is stable, which we definte as the relative
360 *> change in each component being less than DZ_UB. The default value
361 *> is 0.25, requiring the first bit to be stable. See LAWN 165 for
362 *> more details.
363 *> \endverbatim
364 *>
365 *> \param[in] IGNORE_CWISE
366 *> \verbatim
367 *> IGNORE_CWISE is LOGICAL
368 *> If .TRUE. then ignore componentwise convergence. Default value
369 *> is .FALSE..
370 *> \endverbatim
371 *>
372 *> \param[out] INFO
373 *> \verbatim
374 *> INFO is INTEGER
375 *> = 0: Successful exit.
376 *> < 0: if INFO = -i, the ith argument to SGETRS had an illegal
377 *> value
378 *> \endverbatim
379 *
380 * Authors:
381 * ========
382 *
383 *> \author Univ. of Tennessee
384 *> \author Univ. of California Berkeley
385 *> \author Univ. of Colorado Denver
386 *> \author NAG Ltd.
387 *
388 *> \date September 2012
389 *
390 *> \ingroup realGEcomputational
391 *
392 * =====================================================================
393  SUBROUTINE sla_gerfsx_extended( PREC_TYPE, TRANS_TYPE, N, NRHS, A,
394  $ lda, af, ldaf, ipiv, colequ, c, b,
395  $ ldb, y, ldy, berr_out, n_norms,
396  $ errs_n, errs_c, res,
397  $ ayb, dy, y_tail, rcond, ithresh,
398  $ rthresh, dz_ub, ignore_cwise,
399  $ info )
400 *
401 * -- LAPACK computational routine (version 3.4.2) --
402 * -- LAPACK is a software package provided by Univ. of Tennessee, --
403 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
404 * September 2012
405 *
406 * .. Scalar Arguments ..
407  INTEGER INFO, LDA, LDAF, LDB, LDY, N, NRHS, PREC_TYPE,
408  $ trans_type, n_norms, ithresh
409  LOGICAL COLEQU, IGNORE_CWISE
410  REAL RTHRESH, DZ_UB
411 * ..
412 * .. Array Arguments ..
413  INTEGER IPIV( * )
414  REAL A( lda, * ), AF( ldaf, * ), B( ldb, * ),
415  $ y( ldy, * ), res( * ), dy( * ), y_tail( * )
416  REAL C( * ), AYB( * ), RCOND, BERR_OUT( * ),
417  $ errs_n( nrhs, * ),
418  $ errs_c( nrhs, * )
419 * ..
420 *
421 * =====================================================================
422 *
423 * .. Local Scalars ..
424  CHARACTER TRANS
425  INTEGER CNT, I, J, X_STATE, Z_STATE, Y_PREC_STATE
426  REAL YK, DYK, YMIN, NORMY, NORMX, NORMDX, DXRAT,
427  $ dzrat, prevnormdx, prev_dz_z, dxratmax,
428  $ dzratmax, dx_x, dz_z, final_dx_x, final_dz_z,
429  $ eps, hugeval, incr_thresh
430  LOGICAL INCR_PREC
431 * ..
432 * .. Parameters ..
433  INTEGER UNSTABLE_STATE, WORKING_STATE, CONV_STATE,
434  $ noprog_state, base_residual, extra_residual,
435  $ extra_y
436  parameter ( unstable_state = 0, working_state = 1,
437  $ conv_state = 2, noprog_state = 3 )
438  parameter ( base_residual = 0, extra_residual = 1,
439  $ extra_y = 2 )
440  INTEGER FINAL_NRM_ERR_I, FINAL_CMP_ERR_I, BERR_I
441  INTEGER RCOND_I, NRM_RCOND_I, NRM_ERR_I, CMP_RCOND_I
442  INTEGER CMP_ERR_I, PIV_GROWTH_I
443  parameter ( final_nrm_err_i = 1, final_cmp_err_i = 2,
444  $ berr_i = 3 )
445  parameter ( rcond_i = 4, nrm_rcond_i = 5, nrm_err_i = 6 )
446  parameter ( cmp_rcond_i = 7, cmp_err_i = 8,
447  $ piv_growth_i = 9 )
448  INTEGER LA_LINRX_ITREF_I, LA_LINRX_ITHRESH_I,
449  $ la_linrx_cwise_i
450  parameter ( la_linrx_itref_i = 1,
451  $ la_linrx_ithresh_i = 2 )
452  parameter ( la_linrx_cwise_i = 3 )
453  INTEGER LA_LINRX_TRUST_I, LA_LINRX_ERR_I,
454  $ la_linrx_rcond_i
455  parameter ( la_linrx_trust_i = 1, la_linrx_err_i = 2 )
456  parameter ( la_linrx_rcond_i = 3 )
457 * ..
458 * .. External Subroutines ..
459  EXTERNAL saxpy, scopy, sgetrs, sgemv, blas_sgemv_x,
460  $ blas_sgemv2_x, sla_geamv, sla_wwaddw, slamch,
462  REAL SLAMCH
463  CHARACTER CHLA_TRANSTYPE
464 * ..
465 * .. Intrinsic Functions ..
466  INTRINSIC abs, max, min
467 * ..
468 * .. Executable Statements ..
469 *
470  IF ( info.NE.0 ) RETURN
471  trans = chla_transtype(trans_type)
472  eps = slamch( 'Epsilon' )
473  hugeval = slamch( 'Overflow' )
474 * Force HUGEVAL to Inf
475  hugeval = hugeval * hugeval
476 * Using HUGEVAL may lead to spurious underflows.
477  incr_thresh = REAL( N ) * EPS
478 *
479  DO j = 1, nrhs
480  y_prec_state = extra_residual
481  IF ( y_prec_state .EQ. extra_y ) THEN
482  DO i = 1, n
483  y_tail( i ) = 0.0
484  END DO
485  END IF
486 
487  dxrat = 0.0
488  dxratmax = 0.0
489  dzrat = 0.0
490  dzratmax = 0.0
491  final_dx_x = hugeval
492  final_dz_z = hugeval
493  prevnormdx = hugeval
494  prev_dz_z = hugeval
495  dz_z = hugeval
496  dx_x = hugeval
497 
498  x_state = working_state
499  z_state = unstable_state
500  incr_prec = .false.
501 
502  DO cnt = 1, ithresh
503 *
504 * Compute residual RES = B_s - op(A_s) * Y,
505 * op(A) = A, A**T, or A**H depending on TRANS (and type).
506 *
507  CALL scopy( n, b( 1, j ), 1, res, 1 )
508  IF ( y_prec_state .EQ. base_residual ) THEN
509  CALL sgemv( trans, n, n, -1.0, a, lda, y( 1, j ), 1,
510  $ 1.0, res, 1 )
511  ELSE IF ( y_prec_state .EQ. extra_residual ) THEN
512  CALL blas_sgemv_x( trans_type, n, n, -1.0, a, lda,
513  $ y( 1, j ), 1, 1.0, res, 1, prec_type )
514  ELSE
515  CALL blas_sgemv2_x( trans_type, n, n, -1.0, a, lda,
516  $ y( 1, j ), y_tail, 1, 1.0, res, 1, prec_type )
517  END IF
518 
519 ! XXX: RES is no longer needed.
520  CALL scopy( n, res, 1, dy, 1 )
521  CALL sgetrs( trans, n, 1, af, ldaf, ipiv, dy, n, info )
522 *
523 * Calculate relative changes DX_X, DZ_Z and ratios DXRAT, DZRAT.
524 *
525  normx = 0.0
526  normy = 0.0
527  normdx = 0.0
528  dz_z = 0.0
529  ymin = hugeval
530 *
531  DO i = 1, n
532  yk = abs( y( i, j ) )
533  dyk = abs( dy( i ) )
534 
535  IF ( yk .NE. 0.0 ) THEN
536  dz_z = max( dz_z, dyk / yk )
537  ELSE IF ( dyk .NE. 0.0 ) THEN
538  dz_z = hugeval
539  END IF
540 
541  ymin = min( ymin, yk )
542 
543  normy = max( normy, yk )
544 
545  IF ( colequ ) THEN
546  normx = max( normx, yk * c( i ) )
547  normdx = max( normdx, dyk * c( i ) )
548  ELSE
549  normx = normy
550  normdx = max( normdx, dyk )
551  END IF
552  END DO
553 
554  IF ( normx .NE. 0.0 ) THEN
555  dx_x = normdx / normx
556  ELSE IF ( normdx .EQ. 0.0 ) THEN
557  dx_x = 0.0
558  ELSE
559  dx_x = hugeval
560  END IF
561 
562  dxrat = normdx / prevnormdx
563  dzrat = dz_z / prev_dz_z
564 *
565 * Check termination criteria
566 *
567  IF (.NOT.ignore_cwise
568  $ .AND. ymin*rcond .LT. incr_thresh*normy
569  $ .AND. y_prec_state .LT. extra_y)
570  $ incr_prec = .true.
571 
572  IF ( x_state .EQ. noprog_state .AND. dxrat .LE. rthresh )
573  $ x_state = working_state
574  IF ( x_state .EQ. working_state ) THEN
575  IF ( dx_x .LE. eps ) THEN
576  x_state = conv_state
577  ELSE IF ( dxrat .GT. rthresh ) THEN
578  IF ( y_prec_state .NE. extra_y ) THEN
579  incr_prec = .true.
580  ELSE
581  x_state = noprog_state
582  END IF
583  ELSE
584  IF ( dxrat .GT. dxratmax ) dxratmax = dxrat
585  END IF
586  IF ( x_state .GT. working_state ) final_dx_x = dx_x
587  END IF
588 
589  IF ( z_state .EQ. unstable_state .AND. dz_z .LE. dz_ub )
590  $ z_state = working_state
591  IF ( z_state .EQ. noprog_state .AND. dzrat .LE. rthresh )
592  $ z_state = working_state
593  IF ( z_state .EQ. working_state ) THEN
594  IF ( dz_z .LE. eps ) THEN
595  z_state = conv_state
596  ELSE IF ( dz_z .GT. dz_ub ) THEN
597  z_state = unstable_state
598  dzratmax = 0.0
599  final_dz_z = hugeval
600  ELSE IF ( dzrat .GT. rthresh ) THEN
601  IF ( y_prec_state .NE. extra_y ) THEN
602  incr_prec = .true.
603  ELSE
604  z_state = noprog_state
605  END IF
606  ELSE
607  IF ( dzrat .GT. dzratmax ) dzratmax = dzrat
608  END IF
609  IF ( z_state .GT. working_state ) final_dz_z = dz_z
610  END IF
611 *
612 * Exit if both normwise and componentwise stopped working,
613 * but if componentwise is unstable, let it go at least two
614 * iterations.
615 *
616  IF ( x_state.NE.working_state ) THEN
617  IF ( ignore_cwise) GOTO 666
618  IF ( z_state.EQ.noprog_state .OR. z_state.EQ.conv_state )
619  $ GOTO 666
620  IF ( z_state.EQ.unstable_state .AND. cnt.GT.1 ) GOTO 666
621  END IF
622 
623  IF ( incr_prec ) THEN
624  incr_prec = .false.
625  y_prec_state = y_prec_state + 1
626  DO i = 1, n
627  y_tail( i ) = 0.0
628  END DO
629  END IF
630 
631  prevnormdx = normdx
632  prev_dz_z = dz_z
633 *
634 * Update soluton.
635 *
636  IF ( y_prec_state .LT. extra_y ) THEN
637  CALL saxpy( n, 1.0, dy, 1, y( 1, j ), 1 )
638  ELSE
639  CALL sla_wwaddw( n, y( 1, j ), y_tail, dy )
640  END IF
641 
642  END DO
643 * Target of "IF (Z_STOP .AND. X_STOP)". Sun's f77 won't EXIT.
644  666 CONTINUE
645 *
646 * Set final_* when cnt hits ithresh.
647 *
648  IF ( x_state .EQ. working_state ) final_dx_x = dx_x
649  IF ( z_state .EQ. working_state ) final_dz_z = dz_z
650 *
651 * Compute error bounds
652 *
653  IF (n_norms .GE. 1) THEN
654  errs_n( j, la_linrx_err_i ) =
655  $ final_dx_x / (1 - dxratmax)
656  END IF
657  IF ( n_norms .GE. 2 ) THEN
658  errs_c( j, la_linrx_err_i ) =
659  $ final_dz_z / (1 - dzratmax)
660  END IF
661 *
662 * Compute componentwise relative backward error from formula
663 * max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
664 * where abs(Z) is the componentwise absolute value of the matrix
665 * or vector Z.
666 *
667 * Compute residual RES = B_s - op(A_s) * Y,
668 * op(A) = A, A**T, or A**H depending on TRANS (and type).
669 *
670  CALL scopy( n, b( 1, j ), 1, res, 1 )
671  CALL sgemv( trans, n, n, -1.0, a, lda, y(1,j), 1, 1.0, res, 1 )
672 
673  DO i = 1, n
674  ayb( i ) = abs( b( i, j ) )
675  END DO
676 *
677 * Compute abs(op(A_s))*abs(Y) + abs(B_s).
678 *
679  CALL sla_geamv ( trans_type, n, n, 1.0,
680  $ a, lda, y(1, j), 1, 1.0, ayb, 1 )
681 
682  CALL sla_lin_berr ( n, n, 1, res, ayb, berr_out( j ) )
683 *
684 * End of loop for each RHS.
685 *
686  END DO
687 *
688  RETURN
689  END
subroutine sgetrs(TRANS, N, NRHS, A, LDA, IPIV, B, LDB, INFO)
SGETRS
Definition: sgetrs.f:123
subroutine sgemv(TRANS, M, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
SGEMV
Definition: sgemv.f:158
character *1 function chla_transtype(TRANS)
CHLA_TRANSTYPE
subroutine sla_geamv(TRANS, M, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
SLA_GEAMV computes a matrix-vector product using a general matrix to calculate error bounds...
Definition: sla_geamv.f:176
subroutine saxpy(N, SA, SX, INCX, SY, INCY)
SAXPY
Definition: saxpy.f:54
subroutine sla_gerfsx_extended(PREC_TYPE, TRANS_TYPE, N, NRHS, A, LDA, AF, LDAF, IPIV, COLEQU, C, B, LDB, Y, LDY, BERR_OUT, N_NORMS, ERRS_N, ERRS_C, RES, AYB, DY, Y_TAIL, RCOND, ITHRESH, RTHRESH, DZ_UB, IGNORE_CWISE, INFO)
SLA_GERFSX_EXTENDED improves the computed solution to a system of linear equations for general matric...
real function slamch(CMACH)
SLAMCH
Definition: slamch.f:69
subroutine sla_lin_berr(N, NZ, NRHS, RES, AYB, BERR)
SLA_LIN_BERR computes a component-wise relative backward error.
Definition: sla_lin_berr.f:103
subroutine sla_wwaddw(N, X, Y, W)
SLA_WWADDW adds a vector into a doubled-single vector.
Definition: sla_wwaddw.f:83
subroutine scopy(N, SX, INCX, SY, INCY)
SCOPY
Definition: scopy.f:53