subroutine zlartg	(	complex*16	F,
		complex*16	G,
		double precision	CS,
		complex*16	SN,
		complex*16	R
	)

ZLARTG generates a plane rotation with real cosine and complex sine.

Download ZLARTG + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 ZLARTG generates a plane rotation so that

    [  CS  SN  ]     [ F ]     [ R ]
    [  __      ]  .  [   ]  =  [   ]   where CS**2 + |SN|**2 = 1.
    [ -SN  CS  ]     [ G ]     [ 0 ]

 This is a faster version of the BLAS1 routine ZROTG, except for
 the following differences:
    F and G are unchanged on return.
    If G=0, then CS=1 and SN=0.
    If F=0, then CS=0 and SN is chosen so that R is real.

Parameters

[in]	F	F is COMPLEX*16 The first component of vector to be rotated.
[in]	G	G is COMPLEX*16 The second component of vector to be rotated.
[out]	CS	CS is DOUBLE PRECISION The cosine of the rotation.
[out]	SN	SN is COMPLEX*16 The sine of the rotation.
[out]	R	R is COMPLEX*16 The nonzero component of the rotated vector.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2013

Further Details:

  3-5-96 - Modified with a new algorithm by W. Kahan and J. Demmel

  This version has a few statements commented out for thread safety
  (machine parameters are computed on each entry). 10 feb 03, SJH.

Definition at line 105 of file zlartg.f.

*
*  -- LAPACK auxiliary routine (version 3.5.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2013
*
*     .. Scalar Arguments ..
      DOUBLE PRECISION   cs
      COMPLEX*16         f, g, r, sn
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   two, one, zero
      parameter                ( two = 2.0d+0, one = 1.0d+0, zero = 0.0d+0 )
      COMPLEX*16         czero
      parameter                ( czero = ( 0.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
*     LOGICAL            FIRST
      INTEGER            count, i
      DOUBLE PRECISION   d, di, dr, eps, f2, f2s, g2, g2s, safmin,
     $                   safmn2, safmx2, scale
      COMPLEX*16         ff, fs, gs
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch, dlapy2
      LOGICAL            disnan
      EXTERNAL           dlamch, dlapy2, disnan
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dcmplx, dconjg, dimag, int, log,
     $                   max, sqrt
*     ..
*     .. Statement Functions ..
      DOUBLE PRECISION   abs1, abssq
*     ..
*     .. Statement Function definitions ..
      abs1( ff ) = max( abs( dble( ff ) ), abs( dimag( ff ) ) )
      abssq( ff ) = dble( ff )**2 + dimag( ff )**2
*     ..
*     .. Executable Statements ..
*
      safmin = dlamch( 'S' )
      eps = dlamch( 'E' )
      safmn2 = dlamch( 'B' )**int( log( safmin / eps ) /
     $         log( dlamch( 'B' ) ) / two )
      safmx2 = one / safmn2
      scale = max( abs1( f ), abs1( g ) )
      fs = f
      gs = g
      count = 0
      IF( scale.GE.safmx2 ) THEN
   10    CONTINUE
         count = count + 1
         fs = fs*safmn2
         gs = gs*safmn2
         scale = scale*safmn2
         IF( scale.GE.safmx2 )
     $      GO TO 10
      ELSE IF( scale.LE.safmn2 ) THEN
         IF( g.EQ.czero.OR.disnan( abs( g ) ) ) THEN
            cs = one
            sn = czero
            r = f
            RETURN
         END IF
   20    CONTINUE
         count = count - 1
         fs = fs*safmx2
         gs = gs*safmx2
         scale = scale*safmx2
         IF( scale.LE.safmn2 )
     $      GO TO 20
      END IF
      f2 = abssq( fs )
      g2 = abssq( gs )
      IF( f2.LE.max( g2, one )*safmin ) THEN
*
*        This is a rare case: F is very small.
*
         IF( f.EQ.czero ) THEN
            cs = zero
            r = dlapy2( dble( g ), dimag( g ) )
*           Do complex/real division explicitly with two real divisions
            d = dlapy2( dble( gs ), dimag( gs ) )
            sn = dcmplx( dble( gs ) / d, -dimag( gs ) / d )
            RETURN
         END IF
         f2s = dlapy2( dble( fs ), dimag( fs ) )
*        G2 and G2S are accurate
*        G2 is at least SAFMIN, and G2S is at least SAFMN2
         g2s = sqrt( g2 )
*        Error in CS from underflow in F2S is at most
*        UNFL / SAFMN2 .lt. sqrt(UNFL*EPS) .lt. EPS
*        If MAX(G2,ONE)=G2, then F2 .lt. G2*SAFMIN,
*        and so CS .lt. sqrt(SAFMIN)
*        If MAX(G2,ONE)=ONE, then F2 .lt. SAFMIN
*        and so CS .lt. sqrt(SAFMIN)/SAFMN2 = sqrt(EPS)
*        Therefore, CS = F2S/G2S / sqrt( 1 + (F2S/G2S)**2 ) = F2S/G2S
         cs = f2s / g2s
*        Make sure abs(FF) = 1
*        Do complex/real division explicitly with 2 real divisions
         IF( abs1( f ).GT.one ) THEN
            d = dlapy2( dble( f ), dimag( f ) )
            ff = dcmplx( dble( f ) / d, dimag( f ) / d )
         ELSE
            dr = safmx2*dble( f )
            di = safmx2*dimag( f )
            d = dlapy2( dr, di )
            ff = dcmplx( dr / d, di / d )
         END IF
         sn = ff*dcmplx( dble( gs ) / g2s, -dimag( gs ) / g2s )
         r = cs*f + sn*g
      ELSE
*
*        This is the most common case.
*        Neither F2 nor F2/G2 are less than SAFMIN
*        F2S cannot overflow, and it is accurate
*
         f2s = sqrt( one+g2 / f2 )
*        Do the F2S(real)*FS(complex) multiply with two real multiplies
         r = dcmplx( f2s*dble( fs ), f2s*dimag( fs ) )
         cs = one / f2s
         d = f2 + g2
*        Do complex/real division explicitly with two real divisions
         sn = dcmplx( dble( r ) / d, dimag( r ) / d )
         sn = sn*dconjg( gs )
         IF( count.NE.0 ) THEN
            IF( count.GT.0 ) THEN
               DO 30 i = 1, count
                  r = r*safmx2
   30          CONTINUE
            ELSE
               DO 40 i = 1, -count
                  r = r*safmn2
   40          CONTINUE
            END IF
         END IF
      END IF
      RETURN
*
*     End of ZLARTG
*

Here is the caller graph for this function: