LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
subroutine dgebd2 ( integer  M,
integer  N,
double precision, dimension( lda, * )  A,
integer  LDA,
double precision, dimension( * )  D,
double precision, dimension( * )  E,
double precision, dimension( * )  TAUQ,
double precision, dimension( * )  TAUP,
double precision, dimension( * )  WORK,
integer  INFO 
)

DGEBD2 reduces a general matrix to bidiagonal form using an unblocked algorithm.

Download DGEBD2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 DGEBD2 reduces a real general m by n matrix A to upper or lower
 bidiagonal form B by an orthogonal transformation: Q**T * A * P = B.

 If m >= n, B is upper bidiagonal; if m < n, B is lower bidiagonal.
Parameters
[in]M
          M is INTEGER
          The number of rows in the matrix A.  M >= 0.
[in]N
          N is INTEGER
          The number of columns in the matrix A.  N >= 0.
[in,out]A
          A is DOUBLE PRECISION array, dimension (LDA,N)
          On entry, the m by n general matrix to be reduced.
          On exit,
          if m >= n, the diagonal and the first superdiagonal are
            overwritten with the upper bidiagonal matrix B; the
            elements below the diagonal, with the array TAUQ, represent
            the orthogonal matrix Q as a product of elementary
            reflectors, and the elements above the first superdiagonal,
            with the array TAUP, represent the orthogonal matrix P as
            a product of elementary reflectors;
          if m < n, the diagonal and the first subdiagonal are
            overwritten with the lower bidiagonal matrix B; the
            elements below the first subdiagonal, with the array TAUQ,
            represent the orthogonal matrix Q as a product of
            elementary reflectors, and the elements above the diagonal,
            with the array TAUP, represent the orthogonal matrix P as
            a product of elementary reflectors.
          See Further Details.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,M).
[out]D
          D is DOUBLE PRECISION array, dimension (min(M,N))
          The diagonal elements of the bidiagonal matrix B:
          D(i) = A(i,i).
[out]E
          E is DOUBLE PRECISION array, dimension (min(M,N)-1)
          The off-diagonal elements of the bidiagonal matrix B:
          if m >= n, E(i) = A(i,i+1) for i = 1,2,...,n-1;
          if m < n, E(i) = A(i+1,i) for i = 1,2,...,m-1.
[out]TAUQ
          TAUQ is DOUBLE PRECISION array dimension (min(M,N))
          The scalar factors of the elementary reflectors which
          represent the orthogonal matrix Q. See Further Details.
[out]TAUP
          TAUP is DOUBLE PRECISION array, dimension (min(M,N))
          The scalar factors of the elementary reflectors which
          represent the orthogonal matrix P. See Further Details.
[out]WORK
          WORK is DOUBLE PRECISION array, dimension (max(M,N))
[out]INFO
          INFO is INTEGER
          = 0: successful exit.
          < 0: if INFO = -i, the i-th argument had an illegal value.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
September 2012
Further Details:
  The matrices Q and P are represented as products of elementary
  reflectors:

  If m >= n,

     Q = H(1) H(2) . . . H(n)  and  P = G(1) G(2) . . . G(n-1)

  Each H(i) and G(i) has the form:

     H(i) = I - tauq * v * v**T  and G(i) = I - taup * u * u**T

  where tauq and taup are real scalars, and v and u are real vectors;
  v(1:i-1) = 0, v(i) = 1, and v(i+1:m) is stored on exit in A(i+1:m,i);
  u(1:i) = 0, u(i+1) = 1, and u(i+2:n) is stored on exit in A(i,i+2:n);
  tauq is stored in TAUQ(i) and taup in TAUP(i).

  If m < n,

     Q = H(1) H(2) . . . H(m-1)  and  P = G(1) G(2) . . . G(m)

  Each H(i) and G(i) has the form:

     H(i) = I - tauq * v * v**T  and G(i) = I - taup * u * u**T

  where tauq and taup are real scalars, and v and u are real vectors;
  v(1:i) = 0, v(i+1) = 1, and v(i+2:m) is stored on exit in A(i+2:m,i);
  u(1:i-1) = 0, u(i) = 1, and u(i+1:n) is stored on exit in A(i,i+1:n);
  tauq is stored in TAUQ(i) and taup in TAUP(i).

  The contents of A on exit are illustrated by the following examples:

  m = 6 and n = 5 (m > n):          m = 5 and n = 6 (m < n):

    (  d   e   u1  u1  u1 )           (  d   u1  u1  u1  u1  u1 )
    (  v1  d   e   u2  u2 )           (  e   d   u2  u2  u2  u2 )
    (  v1  v2  d   e   u3 )           (  v1  e   d   u3  u3  u3 )
    (  v1  v2  v3  d   e  )           (  v1  v2  e   d   u4  u4 )
    (  v1  v2  v3  v4  d  )           (  v1  v2  v3  e   d   u5 )
    (  v1  v2  v3  v4  v5 )

  where d and e denote diagonal and off-diagonal elements of B, vi
  denotes an element of the vector defining H(i), and ui an element of
  the vector defining G(i).

Definition at line 191 of file dgebd2.f.

191 *
192 * -- LAPACK computational routine (version 3.4.2) --
193 * -- LAPACK is a software package provided by Univ. of Tennessee, --
194 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
195 * September 2012
196 *
197 * .. Scalar Arguments ..
198  INTEGER info, lda, m, n
199 * ..
200 * .. Array Arguments ..
201  DOUBLE PRECISION a( lda, * ), d( * ), e( * ), taup( * ),
202  $ tauq( * ), work( * )
203 * ..
204 *
205 * =====================================================================
206 *
207 * .. Parameters ..
208  DOUBLE PRECISION zero, one
209  parameter ( zero = 0.0d+0, one = 1.0d+0 )
210 * ..
211 * .. Local Scalars ..
212  INTEGER i
213 * ..
214 * .. External Subroutines ..
215  EXTERNAL dlarf, dlarfg, xerbla
216 * ..
217 * .. Intrinsic Functions ..
218  INTRINSIC max, min
219 * ..
220 * .. Executable Statements ..
221 *
222 * Test the input parameters
223 *
224  info = 0
225  IF( m.LT.0 ) THEN
226  info = -1
227  ELSE IF( n.LT.0 ) THEN
228  info = -2
229  ELSE IF( lda.LT.max( 1, m ) ) THEN
230  info = -4
231  END IF
232  IF( info.LT.0 ) THEN
233  CALL xerbla( 'DGEBD2', -info )
234  RETURN
235  END IF
236 *
237  IF( m.GE.n ) THEN
238 *
239 * Reduce to upper bidiagonal form
240 *
241  DO 10 i = 1, n
242 *
243 * Generate elementary reflector H(i) to annihilate A(i+1:m,i)
244 *
245  CALL dlarfg( m-i+1, a( i, i ), a( min( i+1, m ), i ), 1,
246  $ tauq( i ) )
247  d( i ) = a( i, i )
248  a( i, i ) = one
249 *
250 * Apply H(i) to A(i:m,i+1:n) from the left
251 *
252  IF( i.LT.n )
253  $ CALL dlarf( 'Left', m-i+1, n-i, a( i, i ), 1, tauq( i ),
254  $ a( i, i+1 ), lda, work )
255  a( i, i ) = d( i )
256 *
257  IF( i.LT.n ) THEN
258 *
259 * Generate elementary reflector G(i) to annihilate
260 * A(i,i+2:n)
261 *
262  CALL dlarfg( n-i, a( i, i+1 ), a( i, min( i+2, n ) ),
263  $ lda, taup( i ) )
264  e( i ) = a( i, i+1 )
265  a( i, i+1 ) = one
266 *
267 * Apply G(i) to A(i+1:m,i+1:n) from the right
268 *
269  CALL dlarf( 'Right', m-i, n-i, a( i, i+1 ), lda,
270  $ taup( i ), a( i+1, i+1 ), lda, work )
271  a( i, i+1 ) = e( i )
272  ELSE
273  taup( i ) = zero
274  END IF
275  10 CONTINUE
276  ELSE
277 *
278 * Reduce to lower bidiagonal form
279 *
280  DO 20 i = 1, m
281 *
282 * Generate elementary reflector G(i) to annihilate A(i,i+1:n)
283 *
284  CALL dlarfg( n-i+1, a( i, i ), a( i, min( i+1, n ) ), lda,
285  $ taup( i ) )
286  d( i ) = a( i, i )
287  a( i, i ) = one
288 *
289 * Apply G(i) to A(i+1:m,i:n) from the right
290 *
291  IF( i.LT.m )
292  $ CALL dlarf( 'Right', m-i, n-i+1, a( i, i ), lda,
293  $ taup( i ), a( i+1, i ), lda, work )
294  a( i, i ) = d( i )
295 *
296  IF( i.LT.m ) THEN
297 *
298 * Generate elementary reflector H(i) to annihilate
299 * A(i+2:m,i)
300 *
301  CALL dlarfg( m-i, a( i+1, i ), a( min( i+2, m ), i ), 1,
302  $ tauq( i ) )
303  e( i ) = a( i+1, i )
304  a( i+1, i ) = one
305 *
306 * Apply H(i) to A(i+1:m,i+1:n) from the left
307 *
308  CALL dlarf( 'Left', m-i, n-i, a( i+1, i ), 1, tauq( i ),
309  $ a( i+1, i+1 ), lda, work )
310  a( i+1, i ) = e( i )
311  ELSE
312  tauq( i ) = zero
313  END IF
314  20 CONTINUE
315  END IF
316  RETURN
317 *
318 * End of DGEBD2
319 *
subroutine dlarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
DLARF applies an elementary reflector to a general rectangular matrix.
Definition: dlarf.f:126
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine dlarfg(N, ALPHA, X, INCX, TAU)
DLARFG generates an elementary reflector (Householder matrix).
Definition: dlarfg.f:108

Here is the call graph for this function:

Here is the caller graph for this function: