LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
subroutine cspsvx ( character  FACT,
character  UPLO,
integer  N,
integer  NRHS,
complex, dimension( * )  AP,
complex, dimension( * )  AFP,
integer, dimension( * )  IPIV,
complex, dimension( ldb, * )  B,
integer  LDB,
complex, dimension( ldx, * )  X,
integer  LDX,
real  RCOND,
real, dimension( * )  FERR,
real, dimension( * )  BERR,
complex, dimension( * )  WORK,
real, dimension( * )  RWORK,
integer  INFO 
)

CSPSVX computes the solution to system of linear equations A * X = B for OTHER matrices

Download CSPSVX + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 CSPSVX uses the diagonal pivoting factorization A = U*D*U**T or
 A = L*D*L**T to compute the solution to a complex system of linear
 equations A * X = B, where A is an N-by-N symmetric matrix stored
 in packed format and X and B are N-by-NRHS matrices.

 Error bounds on the solution and a condition estimate are also
 provided.
Description:
 The following steps are performed:

 1. If FACT = 'N', the diagonal pivoting method is used to factor A as
       A = U * D * U**T,  if UPLO = 'U', or
       A = L * D * L**T,  if UPLO = 'L',
    where U (or L) is a product of permutation and unit upper (lower)
    triangular matrices and D is symmetric and block diagonal with
    1-by-1 and 2-by-2 diagonal blocks.

 2. If some D(i,i)=0, so that D is exactly singular, then the routine
    returns with INFO = i. Otherwise, the factored form of A is used
    to estimate the condition number of the matrix A.  If the
    reciprocal of the condition number is less than machine precision,
    INFO = N+1 is returned as a warning, but the routine still goes on
    to solve for X and compute error bounds as described below.

 3. The system of equations is solved for X using the factored form
    of A.

 4. Iterative refinement is applied to improve the computed solution
    matrix and calculate error bounds and backward error estimates
    for it.
Parameters
[in]FACT
          FACT is CHARACTER*1
          Specifies whether or not the factored form of A has been
          supplied on entry.
          = 'F':  On entry, AFP and IPIV contain the factored form
                  of A.  AP, AFP and IPIV will not be modified.
          = 'N':  The matrix A will be copied to AFP and factored.
[in]UPLO
          UPLO is CHARACTER*1
          = 'U':  Upper triangle of A is stored;
          = 'L':  Lower triangle of A is stored.
[in]N
          N is INTEGER
          The number of linear equations, i.e., the order of the
          matrix A.  N >= 0.
[in]NRHS
          NRHS is INTEGER
          The number of right hand sides, i.e., the number of columns
          of the matrices B and X.  NRHS >= 0.
[in]AP
          AP is COMPLEX array, dimension (N*(N+1)/2)
          The upper or lower triangle of the symmetric matrix A, packed
          columnwise in a linear array.  The j-th column of A is stored
          in the array AP as follows:
          if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
          if UPLO = 'L', AP(i + (j-1)*(2*n-j)/2) = A(i,j) for j<=i<=n.
          See below for further details.
[in,out]AFP
          AFP is COMPLEX array, dimension (N*(N+1)/2)
          If FACT = 'F', then AFP is an input argument and on entry
          contains the block diagonal matrix D and the multipliers used
          to obtain the factor U or L from the factorization
          A = U*D*U**T or A = L*D*L**T as computed by CSPTRF, stored as
          a packed triangular matrix in the same storage format as A.

          If FACT = 'N', then AFP is an output argument and on exit
          contains the block diagonal matrix D and the multipliers used
          to obtain the factor U or L from the factorization
          A = U*D*U**T or A = L*D*L**T as computed by CSPTRF, stored as
          a packed triangular matrix in the same storage format as A.
[in,out]IPIV
          IPIV is INTEGER array, dimension (N)
          If FACT = 'F', then IPIV is an input argument and on entry
          contains details of the interchanges and the block structure
          of D, as determined by CSPTRF.
          If IPIV(k) > 0, then rows and columns k and IPIV(k) were
          interchanged and D(k,k) is a 1-by-1 diagonal block.
          If UPLO = 'U' and IPIV(k) = IPIV(k-1) < 0, then rows and
          columns k-1 and -IPIV(k) were interchanged and D(k-1:k,k-1:k)
          is a 2-by-2 diagonal block.  If UPLO = 'L' and IPIV(k) =
          IPIV(k+1) < 0, then rows and columns k+1 and -IPIV(k) were
          interchanged and D(k:k+1,k:k+1) is a 2-by-2 diagonal block.

          If FACT = 'N', then IPIV is an output argument and on exit
          contains details of the interchanges and the block structure
          of D, as determined by CSPTRF.
[in]B
          B is COMPLEX array, dimension (LDB,NRHS)
          The N-by-NRHS right hand side matrix B.
[in]LDB
          LDB is INTEGER
          The leading dimension of the array B.  LDB >= max(1,N).
[out]X
          X is COMPLEX array, dimension (LDX,NRHS)
          If INFO = 0 or INFO = N+1, the N-by-NRHS solution matrix X.
[in]LDX
          LDX is INTEGER
          The leading dimension of the array X.  LDX >= max(1,N).
[out]RCOND
          RCOND is REAL
          The estimate of the reciprocal condition number of the matrix
          A.  If RCOND is less than the machine precision (in
          particular, if RCOND = 0), the matrix is singular to working
          precision.  This condition is indicated by a return code of
          INFO > 0.
[out]FERR
          FERR is REAL array, dimension (NRHS)
          The estimated forward error bound for each solution vector
          X(j) (the j-th column of the solution matrix X).
          If XTRUE is the true solution corresponding to X(j), FERR(j)
          is an estimated upper bound for the magnitude of the largest
          element in (X(j) - XTRUE) divided by the magnitude of the
          largest element in X(j).  The estimate is as reliable as
          the estimate for RCOND, and is almost always a slight
          overestimate of the true error.
[out]BERR
          BERR is REAL array, dimension (NRHS)
          The componentwise relative backward error of each solution
          vector X(j) (i.e., the smallest relative change in
          any element of A or B that makes X(j) an exact solution).
[out]WORK
          WORK is COMPLEX array, dimension (2*N)
[out]RWORK
          RWORK is REAL array, dimension (N)
[out]INFO
          INFO is INTEGER
          = 0: successful exit
          < 0: if INFO = -i, the i-th argument had an illegal value
          > 0:  if INFO = i, and i is
                <= N:  D(i,i) is exactly zero.  The factorization
                       has been completed but the factor D is exactly
                       singular, so the solution and error bounds could
                       not be computed. RCOND = 0 is returned.
                = N+1: D is nonsingular, but RCOND is less than machine
                       precision, meaning that the matrix is singular
                       to working precision.  Nevertheless, the
                       solution and error bounds are computed because
                       there are a number of situations where the
                       computed solution can be more accurate than the
                       value of RCOND would suggest.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
April 2012
Further Details:
  The packed storage scheme is illustrated by the following example
  when N = 4, UPLO = 'U':

  Two-dimensional storage of the symmetric matrix A:

     a11 a12 a13 a14
         a22 a23 a24
             a33 a34     (aij = aji)
                 a44

  Packed storage of the upper triangle of A:

  AP = [ a11, a12, a22, a13, a23, a33, a14, a24, a34, a44 ]

Definition at line 279 of file cspsvx.f.

279 *
280 * -- LAPACK driver routine (version 3.4.1) --
281 * -- LAPACK is a software package provided by Univ. of Tennessee, --
282 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
283 * April 2012
284 *
285 * .. Scalar Arguments ..
286  CHARACTER fact, uplo
287  INTEGER info, ldb, ldx, n, nrhs
288  REAL rcond
289 * ..
290 * .. Array Arguments ..
291  INTEGER ipiv( * )
292  REAL berr( * ), ferr( * ), rwork( * )
293  COMPLEX afp( * ), ap( * ), b( ldb, * ), work( * ),
294  $ x( ldx, * )
295 * ..
296 *
297 * =====================================================================
298 *
299 * .. Parameters ..
300  REAL zero
301  parameter ( zero = 0.0e+0 )
302 * ..
303 * .. Local Scalars ..
304  LOGICAL nofact
305  REAL anorm
306 * ..
307 * .. External Functions ..
308  LOGICAL lsame
309  REAL clansp, slamch
310  EXTERNAL lsame, clansp, slamch
311 * ..
312 * .. External Subroutines ..
313  EXTERNAL ccopy, clacpy, cspcon, csprfs, csptrf, csptrs,
314  $ xerbla
315 * ..
316 * .. Intrinsic Functions ..
317  INTRINSIC max
318 * ..
319 * .. Executable Statements ..
320 *
321 * Test the input parameters.
322 *
323  info = 0
324  nofact = lsame( fact, 'N' )
325  IF( .NOT.nofact .AND. .NOT.lsame( fact, 'F' ) ) THEN
326  info = -1
327  ELSE IF( .NOT.lsame( uplo, 'U' ) .AND. .NOT.lsame( uplo, 'L' ) )
328  $ THEN
329  info = -2
330  ELSE IF( n.LT.0 ) THEN
331  info = -3
332  ELSE IF( nrhs.LT.0 ) THEN
333  info = -4
334  ELSE IF( ldb.LT.max( 1, n ) ) THEN
335  info = -9
336  ELSE IF( ldx.LT.max( 1, n ) ) THEN
337  info = -11
338  END IF
339  IF( info.NE.0 ) THEN
340  CALL xerbla( 'CSPSVX', -info )
341  RETURN
342  END IF
343 *
344  IF( nofact ) THEN
345 *
346 * Compute the factorization A = U*D*U**T or A = L*D*L**T.
347 *
348  CALL ccopy( n*( n+1 ) / 2, ap, 1, afp, 1 )
349  CALL csptrf( uplo, n, afp, ipiv, info )
350 *
351 * Return if INFO is non-zero.
352 *
353  IF( info.GT.0 )THEN
354  rcond = zero
355  RETURN
356  END IF
357  END IF
358 *
359 * Compute the norm of the matrix A.
360 *
361  anorm = clansp( 'I', uplo, n, ap, rwork )
362 *
363 * Compute the reciprocal of the condition number of A.
364 *
365  CALL cspcon( uplo, n, afp, ipiv, anorm, rcond, work, info )
366 *
367 * Compute the solution vectors X.
368 *
369  CALL clacpy( 'Full', n, nrhs, b, ldb, x, ldx )
370  CALL csptrs( uplo, n, nrhs, afp, ipiv, x, ldx, info )
371 *
372 * Use iterative refinement to improve the computed solutions and
373 * compute error bounds and backward error estimates for them.
374 *
375  CALL csprfs( uplo, n, nrhs, ap, afp, ipiv, b, ldb, x, ldx, ferr,
376  $ berr, work, rwork, info )
377 *
378 * Set INFO = N+1 if the matrix is singular to working precision.
379 *
380  IF( rcond.LT.slamch( 'Epsilon' ) )
381  $ info = n + 1
382 *
383  RETURN
384 *
385 * End of CSPSVX
386 *
real function clansp(NORM, UPLO, N, AP, WORK)
CLANSP returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a symmetric matrix supplied in packed form.
Definition: clansp.f:117
subroutine cspcon(UPLO, N, AP, IPIV, ANORM, RCOND, WORK, INFO)
CSPCON
Definition: cspcon.f:120
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
subroutine csptrf(UPLO, N, AP, IPIV, INFO)
CSPTRF
Definition: csptrf.f:160
subroutine csptrs(UPLO, N, NRHS, AP, IPIV, B, LDB, INFO)
CSPTRS
Definition: csptrs.f:117
subroutine clacpy(UPLO, M, N, A, LDA, B, LDB)
CLACPY copies all or part of one two-dimensional array to another.
Definition: clacpy.f:105
subroutine csprfs(UPLO, N, NRHS, AP, AFP, IPIV, B, LDB, X, LDX, FERR, BERR, WORK, RWORK, INFO)
CSPRFS
Definition: csprfs.f:182
subroutine ccopy(N, CX, INCX, CY, INCY)
CCOPY
Definition: ccopy.f:52
real function slamch(CMACH)
SLAMCH
Definition: slamch.f:69
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55

Here is the call graph for this function:

Here is the caller graph for this function: