LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
sgetc2.f
Go to the documentation of this file.
1 *> \brief \b SGETC2 computes the LU factorization with complete pivoting of the general n-by-n matrix.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download SGETC2 + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sgetc2.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sgetc2.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sgetc2.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE SGETC2( N, A, LDA, IPIV, JPIV, INFO )
22 *
23 * .. Scalar Arguments ..
24 * INTEGER INFO, LDA, N
25 * ..
26 * .. Array Arguments ..
27 * INTEGER IPIV( * ), JPIV( * )
28 * REAL A( LDA, * )
29 * ..
30 *
31 *
32 *> \par Purpose:
33 * =============
34 *>
35 *> \verbatim
36 *>
37 *> SGETC2 computes an LU factorization with complete pivoting of the
38 *> n-by-n matrix A. The factorization has the form A = P * L * U * Q,
39 *> where P and Q are permutation matrices, L is lower triangular with
40 *> unit diagonal elements and U is upper triangular.
41 *>
42 *> This is the Level 2 BLAS algorithm.
43 *> \endverbatim
44 *
45 * Arguments:
46 * ==========
47 *
48 *> \param[in] N
49 *> \verbatim
50 *> N is INTEGER
51 *> The order of the matrix A. N >= 0.
52 *> \endverbatim
53 *>
54 *> \param[in,out] A
55 *> \verbatim
56 *> A is REAL array, dimension (LDA, N)
57 *> On entry, the n-by-n matrix A to be factored.
58 *> On exit, the factors L and U from the factorization
59 *> A = P*L*U*Q; the unit diagonal elements of L are not stored.
60 *> If U(k, k) appears to be less than SMIN, U(k, k) is given the
61 *> value of SMIN, i.e., giving a nonsingular perturbed system.
62 *> \endverbatim
63 *>
64 *> \param[in] LDA
65 *> \verbatim
66 *> LDA is INTEGER
67 *> The leading dimension of the array A. LDA >= max(1,N).
68 *> \endverbatim
69 *>
70 *> \param[out] IPIV
71 *> \verbatim
72 *> IPIV is INTEGER array, dimension(N).
73 *> The pivot indices; for 1 <= i <= N, row i of the
74 *> matrix has been interchanged with row IPIV(i).
75 *> \endverbatim
76 *>
77 *> \param[out] JPIV
78 *> \verbatim
79 *> JPIV is INTEGER array, dimension(N).
80 *> The pivot indices; for 1 <= j <= N, column j of the
81 *> matrix has been interchanged with column JPIV(j).
82 *> \endverbatim
83 *>
84 *> \param[out] INFO
85 *> \verbatim
86 *> INFO is INTEGER
87 *> = 0: successful exit
88 *> > 0: if INFO = k, U(k, k) is likely to produce owerflow if
89 *> we try to solve for x in Ax = b. So U is perturbed to
90 *> avoid the overflow.
91 *> \endverbatim
92 *
93 * Authors:
94 * ========
95 *
96 *> \author Univ. of Tennessee
97 *> \author Univ. of California Berkeley
98 *> \author Univ. of Colorado Denver
99 *> \author NAG Ltd.
100 *
101 *> \date June 2016
102 *
103 *> \ingroup realGEauxiliary
104 *
105 *> \par Contributors:
106 * ==================
107 *>
108 *> Bo Kagstrom and Peter Poromaa, Department of Computing Science,
109 *> Umea University, S-901 87 Umea, Sweden.
110 *
111 * =====================================================================
112  SUBROUTINE sgetc2( N, A, LDA, IPIV, JPIV, INFO )
113 *
114 * -- LAPACK auxiliary routine (version 3.6.1) --
115 * -- LAPACK is a software package provided by Univ. of Tennessee, --
116 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
117 * June 2016
118 *
119 * .. Scalar Arguments ..
120  INTEGER INFO, LDA, N
121 * ..
122 * .. Array Arguments ..
123  INTEGER IPIV( * ), JPIV( * )
124  REAL A( lda, * )
125 * ..
126 *
127 * =====================================================================
128 *
129 * .. Parameters ..
130  REAL ZERO, ONE
131  parameter ( zero = 0.0e+0, one = 1.0e+0 )
132 * ..
133 * .. Local Scalars ..
134  INTEGER I, IP, IPV, J, JP, JPV
135  REAL BIGNUM, EPS, SMIN, SMLNUM, XMAX
136 * ..
137 * .. External Subroutines ..
138  EXTERNAL sger, slabad, sswap
139 * ..
140 * .. External Functions ..
141  REAL SLAMCH
142  EXTERNAL slamch
143 * ..
144 * .. Intrinsic Functions ..
145  INTRINSIC abs, max
146 * ..
147 * .. Executable Statements ..
148 *
149  info = 0
150 *
151 * Quick return if possible
152 *
153  IF( n.EQ.0 )
154  $ RETURN
155 *
156 * Set constants to control overflow
157 *
158  eps = slamch( 'P' )
159  smlnum = slamch( 'S' ) / eps
160  bignum = one / smlnum
161  CALL slabad( smlnum, bignum )
162 *
163 * Handle the case N=1 by itself
164 *
165  IF( n.EQ.1 ) THEN
166  ipiv( 1 ) = 1
167  jpiv( 1 ) = 1
168  IF( abs( a( 1, 1 ) ).LT.smlnum ) THEN
169  info = 1
170  a( 1, 1 ) = smlnum
171  END IF
172  RETURN
173  END IF
174 *
175 * Factorize A using complete pivoting.
176 * Set pivots less than SMIN to SMIN.
177 *
178  DO 40 i = 1, n - 1
179 *
180 * Find max element in matrix A
181 *
182  xmax = zero
183  DO 20 ip = i, n
184  DO 10 jp = i, n
185  IF( abs( a( ip, jp ) ).GE.xmax ) THEN
186  xmax = abs( a( ip, jp ) )
187  ipv = ip
188  jpv = jp
189  END IF
190  10 CONTINUE
191  20 CONTINUE
192  IF( i.EQ.1 )
193  $ smin = max( eps*xmax, smlnum )
194 *
195 * Swap rows
196 *
197  IF( ipv.NE.i )
198  $ CALL sswap( n, a( ipv, 1 ), lda, a( i, 1 ), lda )
199  ipiv( i ) = ipv
200 *
201 * Swap columns
202 *
203  IF( jpv.NE.i )
204  $ CALL sswap( n, a( 1, jpv ), 1, a( 1, i ), 1 )
205  jpiv( i ) = jpv
206 *
207 * Check for singularity
208 *
209  IF( abs( a( i, i ) ).LT.smin ) THEN
210  info = i
211  a( i, i ) = smin
212  END IF
213  DO 30 j = i + 1, n
214  a( j, i ) = a( j, i ) / a( i, i )
215  30 CONTINUE
216  CALL sger( n-i, n-i, -one, a( i+1, i ), 1, a( i, i+1 ), lda,
217  $ a( i+1, i+1 ), lda )
218  40 CONTINUE
219 *
220  IF( abs( a( n, n ) ).LT.smin ) THEN
221  info = n
222  a( n, n ) = smin
223  END IF
224 *
225 * Set last pivots to N
226 *
227  ipiv( n ) = n
228  jpiv( n ) = n
229 *
230  RETURN
231 *
232 * End of SGETC2
233 *
234  END
subroutine sger(M, N, ALPHA, X, INCX, Y, INCY, A, LDA)
SGER
Definition: sger.f:132
subroutine slabad(SMALL, LARGE)
SLABAD
Definition: slabad.f:76
subroutine sgetc2(N, A, LDA, IPIV, JPIV, INFO)
SGETC2 computes the LU factorization with complete pivoting of the general n-by-n matrix...
Definition: sgetc2.f:113
subroutine sswap(N, SX, INCX, SY, INCY)
SSWAP
Definition: sswap.f:53