LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
slahr2.f
Go to the documentation of this file.
1 *> \brief \b SLAHR2 reduces the specified number of first columns of a general rectangular matrix A so that elements below the specified subdiagonal are zero, and returns auxiliary matrices which are needed to apply the transformation to the unreduced part of A.
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download SLAHR2 + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/slahr2.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/slahr2.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/slahr2.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE SLAHR2( N, K, NB, A, LDA, TAU, T, LDT, Y, LDY )
22 *
23 * .. Scalar Arguments ..
24 * INTEGER K, LDA, LDT, LDY, N, NB
25 * ..
26 * .. Array Arguments ..
27 * REAL A( LDA, * ), T( LDT, NB ), TAU( NB ),
28 * $ Y( LDY, NB )
29 * ..
30 *
31 *
32 *> \par Purpose:
33 * =============
34 *>
35 *> \verbatim
36 *>
37 *> SLAHR2 reduces the first NB columns of A real general n-BY-(n-k+1)
38 *> matrix A so that elements below the k-th subdiagonal are zero. The
39 *> reduction is performed by an orthogonal similarity transformation
40 *> Q**T * A * Q. The routine returns the matrices V and T which determine
41 *> Q as a block reflector I - V*T*V**T, and also the matrix Y = A * V * T.
42 *>
43 *> This is an auxiliary routine called by SGEHRD.
44 *> \endverbatim
45 *
46 * Arguments:
47 * ==========
48 *
49 *> \param[in] N
50 *> \verbatim
51 *> N is INTEGER
52 *> The order of the matrix A.
53 *> \endverbatim
54 *>
55 *> \param[in] K
56 *> \verbatim
57 *> K is INTEGER
58 *> The offset for the reduction. Elements below the k-th
59 *> subdiagonal in the first NB columns are reduced to zero.
60 *> K < N.
61 *> \endverbatim
62 *>
63 *> \param[in] NB
64 *> \verbatim
65 *> NB is INTEGER
66 *> The number of columns to be reduced.
67 *> \endverbatim
68 *>
69 *> \param[in,out] A
70 *> \verbatim
71 *> A is REAL array, dimension (LDA,N-K+1)
72 *> On entry, the n-by-(n-k+1) general matrix A.
73 *> On exit, the elements on and above the k-th subdiagonal in
74 *> the first NB columns are overwritten with the corresponding
75 *> elements of the reduced matrix; the elements below the k-th
76 *> subdiagonal, with the array TAU, represent the matrix Q as a
77 *> product of elementary reflectors. The other columns of A are
78 *> unchanged. See Further Details.
79 *> \endverbatim
80 *>
81 *> \param[in] LDA
82 *> \verbatim
83 *> LDA is INTEGER
84 *> The leading dimension of the array A. LDA >= max(1,N).
85 *> \endverbatim
86 *>
87 *> \param[out] TAU
88 *> \verbatim
89 *> TAU is REAL array, dimension (NB)
90 *> The scalar factors of the elementary reflectors. See Further
91 *> Details.
92 *> \endverbatim
93 *>
94 *> \param[out] T
95 *> \verbatim
96 *> T is REAL array, dimension (LDT,NB)
97 *> The upper triangular matrix T.
98 *> \endverbatim
99 *>
100 *> \param[in] LDT
101 *> \verbatim
102 *> LDT is INTEGER
103 *> The leading dimension of the array T. LDT >= NB.
104 *> \endverbatim
105 *>
106 *> \param[out] Y
107 *> \verbatim
108 *> Y is REAL array, dimension (LDY,NB)
109 *> The n-by-nb matrix Y.
110 *> \endverbatim
111 *>
112 *> \param[in] LDY
113 *> \verbatim
114 *> LDY is INTEGER
115 *> The leading dimension of the array Y. LDY >= N.
116 *> \endverbatim
117 *
118 * Authors:
119 * ========
120 *
121 *> \author Univ. of Tennessee
122 *> \author Univ. of California Berkeley
123 *> \author Univ. of Colorado Denver
124 *> \author NAG Ltd.
125 *
126 *> \date September 2012
127 *
128 *> \ingroup realOTHERauxiliary
129 *
130 *> \par Further Details:
131 * =====================
132 *>
133 *> \verbatim
134 *>
135 *> The matrix Q is represented as a product of nb elementary reflectors
136 *>
137 *> Q = H(1) H(2) . . . H(nb).
138 *>
139 *> Each H(i) has the form
140 *>
141 *> H(i) = I - tau * v * v**T
142 *>
143 *> where tau is a real scalar, and v is a real vector with
144 *> v(1:i+k-1) = 0, v(i+k) = 1; v(i+k+1:n) is stored on exit in
145 *> A(i+k+1:n,i), and tau in TAU(i).
146 *>
147 *> The elements of the vectors v together form the (n-k+1)-by-nb matrix
148 *> V which is needed, with T and Y, to apply the transformation to the
149 *> unreduced part of the matrix, using an update of the form:
150 *> A := (I - V*T*V**T) * (A - Y*V**T).
151 *>
152 *> The contents of A on exit are illustrated by the following example
153 *> with n = 7, k = 3 and nb = 2:
154 *>
155 *> ( a a a a a )
156 *> ( a a a a a )
157 *> ( a a a a a )
158 *> ( h h a a a )
159 *> ( v1 h a a a )
160 *> ( v1 v2 a a a )
161 *> ( v1 v2 a a a )
162 *>
163 *> where a denotes an element of the original matrix A, h denotes a
164 *> modified element of the upper Hessenberg matrix H, and vi denotes an
165 *> element of the vector defining H(i).
166 *>
167 *> This subroutine is a slight modification of LAPACK-3.0's DLAHRD
168 *> incorporating improvements proposed by Quintana-Orti and Van de
169 *> Gejin. Note that the entries of A(1:K,2:NB) differ from those
170 *> returned by the original LAPACK-3.0's DLAHRD routine. (This
171 *> subroutine is not backward compatible with LAPACK-3.0's DLAHRD.)
172 *> \endverbatim
173 *
174 *> \par References:
175 * ================
176 *>
177 *> Gregorio Quintana-Orti and Robert van de Geijn, "Improving the
178 *> performance of reduction to Hessenberg form," ACM Transactions on
179 *> Mathematical Software, 32(2):180-194, June 2006.
180 *>
181 * =====================================================================
182  SUBROUTINE slahr2( N, K, NB, A, LDA, TAU, T, LDT, Y, LDY )
183 *
184 * -- LAPACK auxiliary routine (version 3.4.2) --
185 * -- LAPACK is a software package provided by Univ. of Tennessee, --
186 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
187 * September 2012
188 *
189 * .. Scalar Arguments ..
190  INTEGER K, LDA, LDT, LDY, N, NB
191 * ..
192 * .. Array Arguments ..
193  REAL A( lda, * ), T( ldt, nb ), TAU( nb ),
194  $ y( ldy, nb )
195 * ..
196 *
197 * =====================================================================
198 *
199 * .. Parameters ..
200  REAL ZERO, ONE
201  parameter ( zero = 0.0e+0,
202  $ one = 1.0e+0 )
203 * ..
204 * .. Local Scalars ..
205  INTEGER I
206  REAL EI
207 * ..
208 * .. External Subroutines ..
209  EXTERNAL saxpy, scopy, sgemm, sgemv, slacpy,
210  $ slarfg, sscal, strmm, strmv
211 * ..
212 * .. Intrinsic Functions ..
213  INTRINSIC min
214 * ..
215 * .. Executable Statements ..
216 *
217 * Quick return if possible
218 *
219  IF( n.LE.1 )
220  $ RETURN
221 *
222  DO 10 i = 1, nb
223  IF( i.GT.1 ) THEN
224 *
225 * Update A(K+1:N,I)
226 *
227 * Update I-th column of A - Y * V**T
228 *
229  CALL sgemv( 'NO TRANSPOSE', n-k, i-1, -one, y(k+1,1), ldy,
230  $ a( k+i-1, 1 ), lda, one, a( k+1, i ), 1 )
231 *
232 * Apply I - V * T**T * V**T to this column (call it b) from the
233 * left, using the last column of T as workspace
234 *
235 * Let V = ( V1 ) and b = ( b1 ) (first I-1 rows)
236 * ( V2 ) ( b2 )
237 *
238 * where V1 is unit lower triangular
239 *
240 * w := V1**T * b1
241 *
242  CALL scopy( i-1, a( k+1, i ), 1, t( 1, nb ), 1 )
243  CALL strmv( 'Lower', 'Transpose', 'UNIT',
244  $ i-1, a( k+1, 1 ),
245  $ lda, t( 1, nb ), 1 )
246 *
247 * w := w + V2**T * b2
248 *
249  CALL sgemv( 'Transpose', n-k-i+1, i-1,
250  $ one, a( k+i, 1 ),
251  $ lda, a( k+i, i ), 1, one, t( 1, nb ), 1 )
252 *
253 * w := T**T * w
254 *
255  CALL strmv( 'Upper', 'Transpose', 'NON-UNIT',
256  $ i-1, t, ldt,
257  $ t( 1, nb ), 1 )
258 *
259 * b2 := b2 - V2*w
260 *
261  CALL sgemv( 'NO TRANSPOSE', n-k-i+1, i-1, -one,
262  $ a( k+i, 1 ),
263  $ lda, t( 1, nb ), 1, one, a( k+i, i ), 1 )
264 *
265 * b1 := b1 - V1*w
266 *
267  CALL strmv( 'Lower', 'NO TRANSPOSE',
268  $ 'UNIT', i-1,
269  $ a( k+1, 1 ), lda, t( 1, nb ), 1 )
270  CALL saxpy( i-1, -one, t( 1, nb ), 1, a( k+1, i ), 1 )
271 *
272  a( k+i-1, i-1 ) = ei
273  END IF
274 *
275 * Generate the elementary reflector H(I) to annihilate
276 * A(K+I+1:N,I)
277 *
278  CALL slarfg( n-k-i+1, a( k+i, i ), a( min( k+i+1, n ), i ), 1,
279  $ tau( i ) )
280  ei = a( k+i, i )
281  a( k+i, i ) = one
282 *
283 * Compute Y(K+1:N,I)
284 *
285  CALL sgemv( 'NO TRANSPOSE', n-k, n-k-i+1,
286  $ one, a( k+1, i+1 ),
287  $ lda, a( k+i, i ), 1, zero, y( k+1, i ), 1 )
288  CALL sgemv( 'Transpose', n-k-i+1, i-1,
289  $ one, a( k+i, 1 ), lda,
290  $ a( k+i, i ), 1, zero, t( 1, i ), 1 )
291  CALL sgemv( 'NO TRANSPOSE', n-k, i-1, -one,
292  $ y( k+1, 1 ), ldy,
293  $ t( 1, i ), 1, one, y( k+1, i ), 1 )
294  CALL sscal( n-k, tau( i ), y( k+1, i ), 1 )
295 *
296 * Compute T(1:I,I)
297 *
298  CALL sscal( i-1, -tau( i ), t( 1, i ), 1 )
299  CALL strmv( 'Upper', 'No Transpose', 'NON-UNIT',
300  $ i-1, t, ldt,
301  $ t( 1, i ), 1 )
302  t( i, i ) = tau( i )
303 *
304  10 CONTINUE
305  a( k+nb, nb ) = ei
306 *
307 * Compute Y(1:K,1:NB)
308 *
309  CALL slacpy( 'ALL', k, nb, a( 1, 2 ), lda, y, ldy )
310  CALL strmm( 'RIGHT', 'Lower', 'NO TRANSPOSE',
311  $ 'UNIT', k, nb,
312  $ one, a( k+1, 1 ), lda, y, ldy )
313  IF( n.GT.k+nb )
314  $ CALL sgemm( 'NO TRANSPOSE', 'NO TRANSPOSE', k,
315  $ nb, n-k-nb, one,
316  $ a( 1, 2+nb ), lda, a( k+1+nb, 1 ), lda, one, y,
317  $ ldy )
318  CALL strmm( 'RIGHT', 'Upper', 'NO TRANSPOSE',
319  $ 'NON-UNIT', k, nb,
320  $ one, t, ldt, y, ldy )
321 *
322  RETURN
323 *
324 * End of SLAHR2
325 *
326  END
subroutine slarfg(N, ALPHA, X, INCX, TAU)
SLARFG generates an elementary reflector (Householder matrix).
Definition: slarfg.f:108
subroutine sgemm(TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
SGEMM
Definition: sgemm.f:189
subroutine slahr2(N, K, NB, A, LDA, TAU, T, LDT, Y, LDY)
SLAHR2 reduces the specified number of first columns of a general rectangular matrix A so that elemen...
Definition: slahr2.f:183
subroutine sgemv(TRANS, M, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
SGEMV
Definition: sgemv.f:158
subroutine slacpy(UPLO, M, N, A, LDA, B, LDB)
SLACPY copies all or part of one two-dimensional array to another.
Definition: slacpy.f:105
subroutine strmm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
STRMM
Definition: strmm.f:179
subroutine strmv(UPLO, TRANS, DIAG, N, A, LDA, X, INCX)
STRMV
Definition: strmv.f:149
subroutine saxpy(N, SA, SX, INCX, SY, INCY)
SAXPY
Definition: saxpy.f:54
subroutine sscal(N, SA, SX, INCX)
SSCAL
Definition: sscal.f:55
subroutine scopy(N, SX, INCX, SY, INCY)
SCOPY
Definition: scopy.f:53