subroutine zqrt02	(	integer	M,
		integer	N,
		integer	K,
		complex*16, dimension( lda, * )	A,
		complex*16, dimension( lda, * )	AF,
		complex*16, dimension( lda, * )	Q,
		complex*16, dimension( lda, * )	R,
		integer	LDA,
		complex*16, dimension( * )	TAU,
		complex*16, dimension( lwork )	WORK,
		integer	LWORK,
		double precision, dimension( * )	RWORK,
		double precision, dimension( * )	RESULT
	)

ZQRT02

Purpose:

 ZQRT02 tests ZUNGQR, which generates an m-by-n matrix Q with
 orthonornmal columns that is defined as the product of k elementary
 reflectors.

 Given the QR factorization of an m-by-n matrix A, ZQRT02 generates
 the orthogonal matrix Q defined by the factorization of the first k
 columns of A; it compares R(1:n,1:k) with Q(1:m,1:n)'*A(1:m,1:k),
 and checks that the columns of Q are orthonormal.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix Q to be generated. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix Q to be generated. M >= N >= 0.
[in]	K	K is INTEGER The number of elementary reflectors whose product defines the matrix Q. N >= K >= 0.
[in]	A	A is COMPLEX*16 array, dimension (LDA,N) The m-by-n matrix A which was factorized by ZQRT01.
[in]	AF	AF is COMPLEX*16 array, dimension (LDA,N) Details of the QR factorization of A, as returned by ZGEQRF. See ZGEQRF for further details.
[out]	Q	Q is COMPLEX*16 array, dimension (LDA,N)
[out]	R	R is COMPLEX*16 array, dimension (LDA,N)
[in]	LDA	LDA is INTEGER The leading dimension of the arrays A, AF, Q and R. LDA >= M.
[in]	TAU	TAU is COMPLEX*16 array, dimension (N) The scalar factors of the elementary reflectors corresponding to the QR factorization in AF.
[out]	WORK	WORK is COMPLEX*16 array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The dimension of the array WORK.
[out]	RWORK	RWORK is DOUBLE PRECISION array, dimension (M)
[out]	RESULT	RESULT is DOUBLE PRECISION array, dimension (2) The test ratios: RESULT(1) = norm( R - Q'*A ) / ( M * norm(A) * EPS ) RESULT(2) = norm( I - Q'*Q ) / ( M * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 137 of file zqrt02.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            k, lda, lwork, m, n
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   result( * ), rwork( * )
      COMPLEX*16         a( lda, * ), af( lda, * ), q( lda, * ),
     $                   r( lda, * ), tau( * ), work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter                ( zero = 0.0d+0, one = 1.0d+0 )
      COMPLEX*16         rogue
      parameter                ( rogue = ( -1.0d+10, -1.0d+10 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            info
      DOUBLE PRECISION   anorm, eps, resid
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch, zlange, zlansy
      EXTERNAL           dlamch, zlange, zlansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           zgemm, zherk, zlacpy, zlaset, zungqr
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dcmplx, max
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       srnamt
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
      eps = dlamch( 'Epsilon' )
*
*     Copy the first k columns of the factorization to the array Q
*
      CALL zlaset( 'Full', m, n, rogue, rogue, q, lda )
      CALL zlacpy( 'Lower', m-1, k, af( 2, 1 ), lda, q( 2, 1 ), lda )
*
*     Generate the first n columns of the matrix Q
*
      srnamt = 'ZUNGQR'
      CALL zungqr( m, n, k, q, lda, tau, work, lwork, info )
*
*     Copy R(1:n,1:k)
*
      CALL zlaset( 'Full', n, k, dcmplx( zero ), dcmplx( zero ), r,
     $             lda )
      CALL zlacpy( 'Upper', n, k, af, lda, r, lda )
*
*     Compute R(1:n,1:k) - Q(1:m,1:n)' * A(1:m,1:k)
*
      CALL zgemm( 'Conjugate transpose', 'No transpose', n, k, m,
     $            dcmplx( -one ), q, lda, a, lda, dcmplx( one ), r,
     $            lda )
*
*     Compute norm( R - Q'*A ) / ( M * norm(A) * EPS ) .
*
      anorm = zlange( '1', m, k, a, lda, rwork )
      resid = zlange( '1', n, k, r, lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / dble( max( 1, m ) ) ) / anorm ) / eps
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute I - Q'*Q
*
      CALL zlaset( 'Full', n, n, dcmplx( zero ), dcmplx( one ), r, lda )
      CALL zherk( 'Upper', 'Conjugate transpose', n, m, -one, q, lda,
     $            one, r, lda )
*
*     Compute norm( I - Q'*Q ) / ( M * EPS ) .
*
      resid = zlansy( '1', 'Upper', n, r, lda, rwork )
*
      result( 2 ) = ( resid / dble( max( 1, m ) ) ) / eps
*
      RETURN
*
*     End of ZQRT02
*

Here is the call graph for this function:

Here is the caller graph for this function: