LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
real function slatm2 ( integer  M,
integer  N,
integer  I,
integer  J,
integer  KL,
integer  KU,
integer  IDIST,
integer, dimension( 4 )  ISEED,
real, dimension( * )  D,
integer  IGRADE,
real, dimension( * )  DL,
real, dimension( * )  DR,
integer  IPVTNG,
integer, dimension( * )  IWORK,
real  SPARSE 
)

SLATM2

Purpose: 
    SLATM2 returns the (I,J) entry of a random matrix of dimension
    (M, N) described by the other parameters. It is called by the
    SLATMR routine in order to build random test matrices. No error
    checking on parameters is done, because this routine is called in
    a tight loop by SLATMR which has already checked the parameters.

    Use of SLATM2 differs from SLATM3 in the order in which the random
    number generator is called to fill in random matrix entries.
    With SLATM2, the generator is called to fill in the pivoted matrix
    columnwise. With SLATM3, the generator is called to fill in the
    matrix columnwise, after which it is pivoted. Thus, SLATM3 can
    be used to construct random matrices which differ only in their
    order of rows and/or columns. SLATM2 is used to construct band
    matrices while avoiding calling the random number generator for
    entries outside the band (and therefore generating random numbers

    The matrix whose (I,J) entry is returned is constructed as
    follows (this routine only computes one entry):

      If I is outside (1..M) or J is outside (1..N), return zero
         (this is convenient for generating matrices in band format).

      Generate a matrix A with random entries of distribution IDIST.

      Set the diagonal to D.

      Grade the matrix, if desired, from the left (by DL) and/or
         from the right (by DR or DL) as specified by IGRADE.

      Permute, if desired, the rows and/or columns as specified by
         IPVTNG and IWORK.

      Band the matrix to have lower bandwidth KL and upper
         bandwidth KU.

      Set random entries to zero as specified by SPARSE.
Parameters
[in]M
          M is INTEGER
           Number of rows of matrix. Not modified.
[in]N
          N is INTEGER
           Number of columns of matrix. Not modified.
[in]I
          I is INTEGER
           Row of entry to be returned. Not modified.
[in]J
          J is INTEGER
           Column of entry to be returned. Not modified.
[in]KL
          KL is INTEGER
           Lower bandwidth. Not modified.
[in]KU
          KU is INTEGER
           Upper bandwidth. Not modified.
[in]IDIST
          IDIST is INTEGER
           On entry, IDIST specifies the type of distribution to be
           used to generate a random matrix .
           1 => UNIFORM( 0, 1 )
           2 => UNIFORM( -1, 1 )
           3 => NORMAL( 0, 1 )
           Not modified.
[in,out]ISEED
          ISEED is INTEGER array of dimension ( 4 )
           Seed for random number generator.
           Changed on exit.
[in]D
          D is REAL array of dimension ( MIN( I , J ) )
           Diagonal entries of matrix. Not modified.
[in]IGRADE
          IGRADE is INTEGER
           Specifies grading of matrix as follows:
           0  => no grading
           1  => matrix premultiplied by diag( DL )
           2  => matrix postmultiplied by diag( DR )
           3  => matrix premultiplied by diag( DL ) and
                         postmultiplied by diag( DR )
           4  => matrix premultiplied by diag( DL ) and
                         postmultiplied by inv( diag( DL ) )
           5  => matrix premultiplied by diag( DL ) and
                         postmultiplied by diag( DL )
           Not modified.
[in]DL
          DL is REAL array ( I or J, as appropriate )
           Left scale factors for grading matrix.  Not modified.
[in]DR
          DR is REAL array ( I or J, as appropriate )
           Right scale factors for grading matrix.  Not modified.
[in]IPVTNG
          IPVTNG is INTEGER
           On entry specifies pivoting permutations as follows:
           0 => none.
           1 => row pivoting.
           2 => column pivoting.
           3 => full pivoting, i.e., on both sides.
           Not modified.
[out]IWORK
          IWORK is INTEGER array ( I or J, as appropriate )
           This array specifies the permutation used. The
           row (or column) in position K was originally in
           position IWORK( K ).
           This differs from IWORK for SLATM3. Not modified.
[in]SPARSE
          SPARSE is REAL between 0. and 1.
           On entry specifies the sparsity of the matrix
           if sparse matix is to be generated.
           SPARSE should lie between 0 and 1.
           A uniform ( 0, 1 ) random number x is generated and
           compared to SPARSE; if x is larger the matrix entry
           is unchanged and if x is smaller the entry is set
           to zero. Thus on the average a fraction SPARSE of the
           entries will be set to zero.
           Not modified.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
June 2016

Definition at line 210 of file slatm2.f.

210 *
211 * -- LAPACK auxiliary routine (version 3.6.1) --
212 * -- LAPACK is a software package provided by Univ. of Tennessee, --
213 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
214 * June 2016
215 *
216 * .. Scalar Arguments ..
217 *
218  INTEGER i, idist, igrade, ipvtng, j, kl, ku, m, n
219  REAL sparse
220 * ..
221 *
222 * .. Array Arguments ..
223 *
224  INTEGER iseed( 4 ), iwork( * )
225  REAL d( * ), dl( * ), dr( * )
226 * ..
227 *
228 * =====================================================================
229 *
230 * .. Parameters ..
231 *
232  REAL zero
233  parameter ( zero = 0.0e0 )
234 * ..
235 *
236 * .. Local Scalars ..
237 *
238  INTEGER isub, jsub
239  REAL temp
240 * ..
241 *
242 * .. External Functions ..
243 *
244  REAL slaran, slarnd
245  EXTERNAL slaran, slarnd
246 * ..
247 *
248 *-----------------------------------------------------------------------
249 *
250 * .. Executable Statements ..
251 *
252 *
253 * Check for I and J in range
254 *
255  IF( i.LT.1 .OR. i.GT.m .OR. j.LT.1 .OR. j.GT.n ) THEN
256  slatm2 = zero
257  RETURN
258  END IF
259 *
260 * Check for banding
261 *
262  IF( j.GT.i+ku .OR. j.LT.i-kl ) THEN
263  slatm2 = zero
264  RETURN
265  END IF
266 *
267 * Check for sparsity
268 *
269  IF( sparse.GT.zero ) THEN
270  IF( slaran( iseed ).LT.sparse ) THEN
271  slatm2 = zero
272  RETURN
273  END IF
274  END IF
275 *
276 * Compute subscripts depending on IPVTNG
277 *
278  IF( ipvtng.EQ.0 ) THEN
279  isub = i
280  jsub = j
281  ELSE IF( ipvtng.EQ.1 ) THEN
282  isub = iwork( i )
283  jsub = j
284  ELSE IF( ipvtng.EQ.2 ) THEN
285  isub = i
286  jsub = iwork( j )
287  ELSE IF( ipvtng.EQ.3 ) THEN
288  isub = iwork( i )
289  jsub = iwork( j )
290  END IF
291 *
292 * Compute entry and grade it according to IGRADE
293 *
294  IF( isub.EQ.jsub ) THEN
295  temp = d( isub )
296  ELSE
297  temp = slarnd( idist, iseed )
298  END IF
299  IF( igrade.EQ.1 ) THEN
300  temp = temp*dl( isub )
301  ELSE IF( igrade.EQ.2 ) THEN
302  temp = temp*dr( jsub )
303  ELSE IF( igrade.EQ.3 ) THEN
304  temp = temp*dl( isub )*dr( jsub )
305  ELSE IF( igrade.EQ.4 .AND. isub.NE.jsub ) THEN
306  temp = temp*dl( isub ) / dl( jsub )
307  ELSE IF( igrade.EQ.5 ) THEN
308  temp = temp*dl( isub )*dl( jsub )
309  END IF
310  slatm2 = temp
311  RETURN
312 *
313 * End of SLATM2
314 *
slarnd
real function slarnd(IDIST, ISEED)
SLARND
Definition: slarnd.f:75
slaran
real function slaran(ISEED)
SLARAN
Definition: slaran.f:69
slatm2
real function slatm2(M, N, I, J, KL, KU, IDIST, ISEED, D, IGRADE, DL, DR, IPVTNG, IWORK, SPARSE)
SLATM2
Definition: slatm2.f:210