subroutine cgetrf	(	integer	M,
		integer	N,
		complex, dimension( lda, * )	A,
		integer	LDA,
		integer, dimension( * )	IPIV,
		integer	INFO
	)

CGETRF VARIANT: left-looking Level 3 BLAS version of the algorithm.

Purpose:

 CGETRF computes an LU factorization of a general M-by-N matrix A
 using partial pivoting with row interchanges.

 The factorization has the form
    A = P * L * U
 where P is a permutation matrix, L is lower triangular with unit
 diagonal elements (lower trapezoidal if m > n), and U is upper
 triangular (upper trapezoidal if m < n).

 This is the left-looking Level 3 BLAS version of the algorithm.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix A. N >= 0.
[in,out]	A	A is COMPLEX array, dimension (LDA,N) On entry, the M-by-N matrix to be factored. On exit, the factors L and U from the factorization A = P*L*U; the unit diagonal elements of L are not stored.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).
[out]	IPIV	IPIV is INTEGER array, dimension (min(M,N)) The pivot indices; for 1 <= i <= min(M,N), row i of the matrix was interchanged with row IPIV(i).
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value > 0: if INFO = i, U(i,i) is exactly zero. The factorization has been completed, but the factor U is exactly singular, and division by zero will occur if it is used to solve a system of equations.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 102 of file cgetrf.f.

*
*  -- LAPACK computational routine (version 3.1) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            info, lda, m, n
*     ..
*     .. Array Arguments ..
      INTEGER            ipiv( * )
      COMPLEX            a( lda, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            one
      parameter                ( one = (1.0e+0, 0.0e+0) )
*     ..
*     .. Local Scalars ..
      INTEGER            i, iinfo, j, jb, k, nb
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm, cgetf2, claswp, ctrsm, xerbla
*     ..
*     .. External Functions ..
      INTEGER            ilaenv
      EXTERNAL           ilaenv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CGETRF', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 )
     $   RETURN
*
*     Determine the block size for this environment.
*
      nb = ilaenv( 1, 'CGETRF', ' ', m, n, -1, -1 )
      IF( nb.LE.1 .OR. nb.GE.min( m, n ) ) THEN
*
*        Use unblocked code.
*
         CALL cgetf2( m, n, a, lda, ipiv, info )

      ELSE
*
*        Use blocked code.
*
         DO 20 j = 1, min( m, n ), nb
            jb = min( min( m, n )-j+1, nb )
*
*
*           Update before factoring the current panel
*
            DO 30 k = 1, j-nb, nb
*            
*              Apply interchanges to rows K:K+NB-1.
* 
               CALL claswp( jb, a(1, j), lda, k, k+nb-1, ipiv, 1 )
*
*              Compute block row of U.
*
               CALL ctrsm( 'Left', 'Lower', 'No transpose', 'Unit',
     $                    nb, jb, one, a( k, k ), lda, 
     $                    a( k, j ), lda )
*
*              Update trailing submatrix.
*
               CALL cgemm( 'No transpose', 'No transpose', 
     $                    m-k-nb+1, jb, nb, -one, 
     $                    a( k+nb, k ), lda, a( k, j ), lda, one,
     $                    a( k+nb, j ), lda )
   30       CONTINUE
*
*           Factor diagonal and subdiagonal blocks and test for exact
*           singularity.
*
            CALL cgetf2( m-j+1, jb, a( j, j ), lda, ipiv( j ), iinfo )
*
*           Adjust INFO and the pivot indices.
*
            IF( info.EQ.0 .AND. iinfo.GT.0 )
     $         info = iinfo + j - 1
            DO 10 i = j, min( m, j+jb-1 )
               ipiv( i ) = j - 1 + ipiv( i )
   10       CONTINUE
*
   20    CONTINUE

*
*        Apply interchanges to the left-overs
*
         DO 40 k = 1, min( m, n ), nb
            CALL claswp( k-1, a( 1, 1 ), lda, k, 
     $                  min(k+nb-1, min( m, n )), ipiv, 1 )
   40    CONTINUE 
*
*        Apply update to the M+1:N columns when N > M
*
         IF ( n.GT.m ) THEN

            CALL claswp( n-m, a(1, m+1), lda, 1, m, ipiv, 1 )

            DO 50 k = 1, m, nb

               jb = min( m-k+1, nb )
*
               CALL ctrsm( 'Left', 'Lower', 'No transpose', 'Unit',
     $                    jb, n-m, one, a( k, k ), lda, 
     $                    a( k, m+1 ), lda )

*     
               IF ( k+nb.LE.m ) THEN
                    CALL cgemm( 'No transpose', 'No transpose', 
     $                         m-k-nb+1, n-m, nb, -one, 
     $                         a( k+nb, k ), lda, a( k, m+1 ), lda, one,
     $                        a( k+nb, m+1 ), lda )
               END IF
   50       CONTINUE  
         END IF
*
      END IF
      RETURN
*
*     End of CGETRF
*

Here is the call graph for this function: