LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
subroutine ctpqrt ( integer  M,
integer  N,
integer  L,
integer  NB,
complex, dimension( lda, * )  A,
integer  LDA,
complex, dimension( ldb, * )  B,
integer  LDB,
complex, dimension( ldt, * )  T,
integer  LDT,
complex, dimension( * )  WORK,
integer  INFO 
)

CTPQRT

Download CTPQRT + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 CTPQRT computes a blocked QR factorization of a complex 
 "triangular-pentagonal" matrix C, which is composed of a 
 triangular block A and pentagonal block B, using the compact 
 WY representation for Q.
Parameters
[in]M
          M is INTEGER
          The number of rows of the matrix B.  
          M >= 0.
[in]N
          N is INTEGER
          The number of columns of the matrix B, and the order of the
          triangular matrix A.
          N >= 0.
[in]L
          L is INTEGER
          The number of rows of the upper trapezoidal part of B.
          MIN(M,N) >= L >= 0.  See Further Details.
[in]NB
          NB is INTEGER
          The block size to be used in the blocked QR.  N >= NB >= 1.
[in,out]A
          A is COMPLEX array, dimension (LDA,N)
          On entry, the upper triangular N-by-N matrix A.
          On exit, the elements on and above the diagonal of the array
          contain the upper triangular matrix R.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,N).
[in,out]B
          B is COMPLEX array, dimension (LDB,N)
          On entry, the pentagonal M-by-N matrix B.  The first M-L rows 
          are rectangular, and the last L rows are upper trapezoidal.
          On exit, B contains the pentagonal matrix V.  See Further Details.
[in]LDB
          LDB is INTEGER
          The leading dimension of the array B.  LDB >= max(1,M).
[out]T
          T is COMPLEX array, dimension (LDT,N)
          The upper triangular block reflectors stored in compact form
          as a sequence of upper triangular blocks.  See Further Details.
[in]LDT
          LDT is INTEGER
          The leading dimension of the array T.  LDT >= NB.
[out]WORK
          WORK is COMPLEX array, dimension (NB*N)
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
November 2013
Further Details:
  The input matrix C is a (N+M)-by-N matrix  

               C = [ A ]
                   [ B ]        

  where A is an upper triangular N-by-N matrix, and B is M-by-N pentagonal
  matrix consisting of a (M-L)-by-N rectangular matrix B1 on top of a L-by-N
  upper trapezoidal matrix B2:

               B = [ B1 ]  <- (M-L)-by-N rectangular
                   [ B2 ]  <-     L-by-N upper trapezoidal.

  The upper trapezoidal matrix B2 consists of the first L rows of a
  N-by-N upper triangular matrix, where 0 <= L <= MIN(M,N).  If L=0, 
  B is rectangular M-by-N; if M=L=N, B is upper triangular.  

  The matrix W stores the elementary reflectors H(i) in the i-th column
  below the diagonal (of A) in the (N+M)-by-N input matrix C

               C = [ A ]  <- upper triangular N-by-N
                   [ B ]  <- M-by-N pentagonal

  so that W can be represented as

               W = [ I ]  <- identity, N-by-N
                   [ V ]  <- M-by-N, same form as B.

  Thus, all of information needed for W is contained on exit in B, which
  we call V above.  Note that V has the same form as B; that is, 

               V = [ V1 ] <- (M-L)-by-N rectangular
                   [ V2 ] <-     L-by-N upper trapezoidal.

  The columns of V represent the vectors which define the H(i)'s.  

  The number of blocks is B = ceiling(N/NB), where each
  block is of order NB except for the last block, which is of order 
  IB = N - (B-1)*NB.  For each of the B blocks, a upper triangular block
  reflector factor is computed: T1, T2, ..., TB.  The NB-by-NB (and IB-by-IB 
  for the last block) T's are stored in the NB-by-N matrix T as

               T = [T1 T2 ... TB].

Definition at line 191 of file ctpqrt.f.

191 *
192 * -- LAPACK computational routine (version 3.5.0) --
193 * -- LAPACK is a software package provided by Univ. of Tennessee, --
194 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
195 * November 2013
196 *
197 * .. Scalar Arguments ..
198  INTEGER info, lda, ldb, ldt, n, m, l, nb
199 * ..
200 * .. Array Arguments ..
201  COMPLEX a( lda, * ), b( ldb, * ), t( ldt, * ), work( * )
202 * ..
203 *
204 * =====================================================================
205 *
206 * ..
207 * .. Local Scalars ..
208  INTEGER i, ib, lb, mb, iinfo
209 * ..
210 * .. External Subroutines ..
211  EXTERNAL ctpqrt2, ctprfb, xerbla
212 * ..
213 * .. Executable Statements ..
214 *
215 * Test the input arguments
216 *
217  info = 0
218  IF( m.LT.0 ) THEN
219  info = -1
220  ELSE IF( n.LT.0 ) THEN
221  info = -2
222  ELSE IF( l.LT.0 .OR. (l.GT.min(m,n) .AND. min(m,n).GE.0)) THEN
223  info = -3
224  ELSE IF( nb.LT.1 .OR. (nb.GT.n .AND. n.GT.0)) THEN
225  info = -4
226  ELSE IF( lda.LT.max( 1, n ) ) THEN
227  info = -6
228  ELSE IF( ldb.LT.max( 1, m ) ) THEN
229  info = -8
230  ELSE IF( ldt.LT.nb ) THEN
231  info = -10
232  END IF
233  IF( info.NE.0 ) THEN
234  CALL xerbla( 'CTPQRT', -info )
235  RETURN
236  END IF
237 *
238 * Quick return if possible
239 *
240  IF( m.EQ.0 .OR. n.EQ.0 ) RETURN
241 *
242  DO i = 1, n, nb
243 *
244 * Compute the QR factorization of the current block
245 *
246  ib = min( n-i+1, nb )
247  mb = min( m-l+i+ib-1, m )
248  IF( i.GE.l ) THEN
249  lb = 0
250  ELSE
251  lb = mb-m+l-i+1
252  END IF
253 *
254  CALL ctpqrt2( mb, ib, lb, a(i,i), lda, b( 1, i ), ldb,
255  $ t(1, i ), ldt, iinfo )
256 *
257 * Update by applying H**H to B(:,I+IB:N) from the left
258 *
259  IF( i+ib.LE.n ) THEN
260  CALL ctprfb( 'L', 'C', 'F', 'C', mb, n-i-ib+1, ib, lb,
261  $ b( 1, i ), ldb, t( 1, i ), ldt,
262  $ a( i, i+ib ), lda, b( 1, i+ib ), ldb,
263  $ work, ib )
264  END IF
265  END DO
266  RETURN
267 *
268 * End of CTPQRT
269 *
subroutine ctpqrt2(M, N, L, A, LDA, B, LDB, T, LDT, INFO)
CTPQRT2 computes a QR factorization of a real or complex "triangular-pentagonal" matrix, which is composed of a triangular block and a pentagonal block, using the compact WY representation for Q.
Definition: ctpqrt2.f:175
subroutine ctprfb(SIDE, TRANS, DIRECT, STOREV, M, N, K, L, V, LDV, T, LDT, A, LDA, B, LDB, WORK, LDWORK)
CTPRFB applies a real or complex "triangular-pentagonal" blocked reflector to a real or complex matri...
Definition: ctprfb.f:253
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62

Here is the call graph for this function:

Here is the caller graph for this function: