subroutine cpotrf	(	character	UPLO,
		integer	N,
		complex, dimension( lda, * )	A,
		integer	LDA,
		integer	INFO
	)

CPOTRF VARIANT: right looking block version of the algorithm, calling Level 3 BLAS.

Purpose:

 CPOTRF computes the Cholesky factorization of a real Hermitian
 positive definite matrix A.

 The factorization has the form
    A = U**H * U,  if UPLO = 'U', or
    A = L  * L**H,  if UPLO = 'L',
 where U is an upper triangular matrix and L is lower triangular.

 This is the right looking block version of the algorithm, calling Level 3 BLAS.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 = 'U': Upper triangle of A is stored; = 'L': Lower triangle of A is stored.
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in,out]	A	A is COMPLEX array, dimension (LDA,N) On entry, the Hermitian matrix A. If UPLO = 'U', the leading N-by-N upper triangular part of A contains the upper triangular part of the matrix A, and the strictly lower triangular part of A is not referenced. If UPLO = 'L', the leading N-by-N lower triangular part of A contains the lower triangular part of the matrix A, and the strictly upper triangular part of A is not referenced. On exit, if INFO = 0, the factor U or L from the Cholesky factorization A = U**H*U or A = L*L**H.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value > 0: if INFO = i, the leading minor of order i is not positive definite, and the factorization could not be completed.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 102 of file cpotrf.f.

*
*  -- LAPACK computational routine (version 3.1) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            info, lda, n
*     ..
*     .. Array Arguments ..
      COMPLEX            a( lda, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               one
      COMPLEX            cone
      parameter                ( one = 1.0e+0, cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            upper
      INTEGER            j, jb, nb
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      INTEGER            ilaenv
      EXTERNAL           lsame, ilaenv
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm, cpotf2, cherk, ctrsm, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CPOTRF', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Determine the block size for this environment.
*
      nb = ilaenv( 1, 'CPOTRF', uplo, n, -1, -1, -1 )
      IF( nb.LE.1 .OR. nb.GE.n ) THEN
*
*        Use unblocked code.
*
         CALL cpotf2( uplo, n, a, lda, info )
      ELSE
*
*        Use blocked code.
*
         IF( upper ) THEN
*
*           Compute the Cholesky factorization A = U'*U.
*
            DO 10 j = 1, n, nb
*
*              Update and factorize the current diagonal block and test
*              for non-positive-definiteness.
*
               jb = min( nb, n-j+1 )

               CALL cpotf2( 'Upper', jb, a( j, j ), lda, info )

               IF( info.NE.0 )
     $            GO TO 30

               IF( j+jb.LE.n ) THEN
*
*                 Updating the trailing submatrix.
*
                  CALL ctrsm( 'Left', 'Upper', 'Conjugate Transpose', 
     $                        'Non-unit', jb, n-j-jb+1, cone, a( j, j ),
     $                        lda, a( j, j+jb ), lda )
                  CALL cherk( 'Upper', 'Conjugate transpose', n-j-jb+1, 
     $                        jb, -one, a( j, j+jb ), lda, 
     $                        one, a( j+jb, j+jb ), lda )
               END IF
   10       CONTINUE
*
         ELSE
*
*           Compute the Cholesky factorization A = L*L'.
*
            DO 20 j = 1, n, nb
*
*              Update and factorize the current diagonal block and test
*              for non-positive-definiteness.
*
               jb = min( nb, n-j+1 )

               CALL cpotf2( 'Lower', jb, a( j, j ), lda, info )

               IF( info.NE.0 )
     $            GO TO 30

               IF( j+jb.LE.n ) THEN
*
*                Updating the trailing submatrix.
*
                 CALL ctrsm( 'Right', 'Lower', 'Conjugate Transpose', 
     $                       'Non-unit', n-j-jb+1, jb, cone, a( j, j ),
     $                       lda, a( j+jb, j ), lda )

                 CALL cherk( 'Lower', 'No Transpose', n-j-jb+1, jb, 
     $                       -one, a( j+jb, j ), lda, 
     $                       one, a( j+jb, j+jb ), lda )
               END IF
   20       CONTINUE
         END IF
      END IF
      GO TO 40
*
   30 CONTINUE
      info = info + j - 1
*
   40 CONTINUE
      RETURN
*
*     End of CPOTRF
*

Here is the call graph for this function: