LAPACK  3.4.2
LAPACK: Linear Algebra PACKage
 All Files Functions Groups
cunmrq.f
Go to the documentation of this file.
1 *> \brief \b CUNMRQ
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download CUNMRQ + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cunmrq.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cunmrq.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cunmrq.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE CUNMRQ( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
22 * WORK, LWORK, INFO )
23 *
24 * .. Scalar Arguments ..
25 * CHARACTER SIDE, TRANS
26 * INTEGER INFO, K, LDA, LDC, LWORK, M, N
27 * ..
28 * .. Array Arguments ..
29 * COMPLEX A( LDA, * ), C( LDC, * ), TAU( * ),
30 * $ WORK( * )
31 * ..
32 *
33 *
34 *> \par Purpose:
35 * =============
36 *>
37 *> \verbatim
38 *>
39 *> CUNMRQ overwrites the general complex M-by-N matrix C with
40 *>
41 *> SIDE = 'L' SIDE = 'R'
42 *> TRANS = 'N': Q * C C * Q
43 *> TRANS = 'C': Q**H * C C * Q**H
44 *>
45 *> where Q is a complex unitary matrix defined as the product of k
46 *> elementary reflectors
47 *>
48 *> Q = H(1)**H H(2)**H . . . H(k)**H
49 *>
50 *> as returned by CGERQF. Q is of order M if SIDE = 'L' and of order N
51 *> if SIDE = 'R'.
52 *> \endverbatim
53 *
54 * Arguments:
55 * ==========
56 *
57 *> \param[in] SIDE
58 *> \verbatim
59 *> SIDE is CHARACTER*1
60 *> = 'L': apply Q or Q**H from the Left;
61 *> = 'R': apply Q or Q**H from the Right.
62 *> \endverbatim
63 *>
64 *> \param[in] TRANS
65 *> \verbatim
66 *> TRANS is CHARACTER*1
67 *> = 'N': No transpose, apply Q;
68 *> = 'C': Transpose, apply Q**H.
69 *> \endverbatim
70 *>
71 *> \param[in] M
72 *> \verbatim
73 *> M is INTEGER
74 *> The number of rows of the matrix C. M >= 0.
75 *> \endverbatim
76 *>
77 *> \param[in] N
78 *> \verbatim
79 *> N is INTEGER
80 *> The number of columns of the matrix C. N >= 0.
81 *> \endverbatim
82 *>
83 *> \param[in] K
84 *> \verbatim
85 *> K is INTEGER
86 *> The number of elementary reflectors whose product defines
87 *> the matrix Q.
88 *> If SIDE = 'L', M >= K >= 0;
89 *> if SIDE = 'R', N >= K >= 0.
90 *> \endverbatim
91 *>
92 *> \param[in] A
93 *> \verbatim
94 *> A is COMPLEX array, dimension
95 *> (LDA,M) if SIDE = 'L',
96 *> (LDA,N) if SIDE = 'R'
97 *> The i-th row must contain the vector which defines the
98 *> elementary reflector H(i), for i = 1,2,...,k, as returned by
99 *> CGERQF in the last k rows of its array argument A.
100 *> \endverbatim
101 *>
102 *> \param[in] LDA
103 *> \verbatim
104 *> LDA is INTEGER
105 *> The leading dimension of the array A. LDA >= max(1,K).
106 *> \endverbatim
107 *>
108 *> \param[in] TAU
109 *> \verbatim
110 *> TAU is COMPLEX array, dimension (K)
111 *> TAU(i) must contain the scalar factor of the elementary
112 *> reflector H(i), as returned by CGERQF.
113 *> \endverbatim
114 *>
115 *> \param[in,out] C
116 *> \verbatim
117 *> C is COMPLEX array, dimension (LDC,N)
118 *> On entry, the M-by-N matrix C.
119 *> On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
120 *> \endverbatim
121 *>
122 *> \param[in] LDC
123 *> \verbatim
124 *> LDC is INTEGER
125 *> The leading dimension of the array C. LDC >= max(1,M).
126 *> \endverbatim
127 *>
128 *> \param[out] WORK
129 *> \verbatim
130 *> WORK is COMPLEX array, dimension (MAX(1,LWORK))
131 *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
132 *> \endverbatim
133 *>
134 *> \param[in] LWORK
135 *> \verbatim
136 *> LWORK is INTEGER
137 *> The dimension of the array WORK.
138 *> If SIDE = 'L', LWORK >= max(1,N);
139 *> if SIDE = 'R', LWORK >= max(1,M).
140 *> For optimum performance LWORK >= N*NB if SIDE = 'L', and
141 *> LWORK >= M*NB if SIDE = 'R', where NB is the optimal
142 *> blocksize.
143 *>
144 *> If LWORK = -1, then a workspace query is assumed; the routine
145 *> only calculates the optimal size of the WORK array, returns
146 *> this value as the first entry of the WORK array, and no error
147 *> message related to LWORK is issued by XERBLA.
148 *> \endverbatim
149 *>
150 *> \param[out] INFO
151 *> \verbatim
152 *> INFO is INTEGER
153 *> = 0: successful exit
154 *> < 0: if INFO = -i, the i-th argument had an illegal value
155 *> \endverbatim
156 *
157 * Authors:
158 * ========
159 *
160 *> \author Univ. of Tennessee
161 *> \author Univ. of California Berkeley
162 *> \author Univ. of Colorado Denver
163 *> \author NAG Ltd.
164 *
165 *> \date November 2011
166 *
167 *> \ingroup complexOTHERcomputational
168 *
169 * =====================================================================
170  SUBROUTINE cunmrq( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
171  $ work, lwork, info )
172 *
173 * -- LAPACK computational routine (version 3.4.0) --
174 * -- LAPACK is a software package provided by Univ. of Tennessee, --
175 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
176 * November 2011
177 *
178 * .. Scalar Arguments ..
179  CHARACTER side, trans
180  INTEGER info, k, lda, ldc, lwork, m, n
181 * ..
182 * .. Array Arguments ..
183  COMPLEX a( lda, * ), c( ldc, * ), tau( * ),
184  $ work( * )
185 * ..
186 *
187 * =====================================================================
188 *
189 * .. Parameters ..
190  INTEGER nbmax, ldt
191  parameter( nbmax = 64, ldt = nbmax+1 )
192 * ..
193 * .. Local Scalars ..
194  LOGICAL left, lquery, notran
195  CHARACTER transt
196  INTEGER i, i1, i2, i3, ib, iinfo, iws, ldwork, lwkopt,
197  $ mi, nb, nbmin, ni, nq, nw
198 * ..
199 * .. Local Arrays ..
200  COMPLEX t( ldt, nbmax )
201 * ..
202 * .. External Functions ..
203  LOGICAL lsame
204  INTEGER ilaenv
205  EXTERNAL lsame, ilaenv
206 * ..
207 * .. External Subroutines ..
208  EXTERNAL clarfb, clarft, cunmr2, xerbla
209 * ..
210 * .. Intrinsic Functions ..
211  INTRINSIC max, min
212 * ..
213 * .. Executable Statements ..
214 *
215 * Test the input arguments
216 *
217  info = 0
218  left = lsame( side, 'L' )
219  notran = lsame( trans, 'N' )
220  lquery = ( lwork.EQ.-1 )
221 *
222 * NQ is the order of Q and NW is the minimum dimension of WORK
223 *
224  IF( left ) THEN
225  nq = m
226  nw = max( 1, n )
227  ELSE
228  nq = n
229  nw = max( 1, m )
230  END IF
231  IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
232  info = -1
233  ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'C' ) ) THEN
234  info = -2
235  ELSE IF( m.LT.0 ) THEN
236  info = -3
237  ELSE IF( n.LT.0 ) THEN
238  info = -4
239  ELSE IF( k.LT.0 .OR. k.GT.nq ) THEN
240  info = -5
241  ELSE IF( lda.LT.max( 1, k ) ) THEN
242  info = -7
243  ELSE IF( ldc.LT.max( 1, m ) ) THEN
244  info = -10
245  END IF
246 *
247  IF( info.EQ.0 ) THEN
248  IF( m.EQ.0 .OR. n.EQ.0 ) THEN
249  lwkopt = 1
250  ELSE
251 *
252 * Determine the block size. NB may be at most NBMAX, where
253 * NBMAX is used to define the local array T.
254 *
255  nb = min( nbmax, ilaenv( 1, 'CUNMRQ', side // trans, m, n,
256  $ k, -1 ) )
257  lwkopt = nw*nb
258  END IF
259  work( 1 ) = lwkopt
260 *
261  IF( lwork.LT.nw .AND. .NOT.lquery ) THEN
262  info = -12
263  END IF
264  END IF
265 *
266  IF( info.NE.0 ) THEN
267  CALL xerbla( 'CUNMRQ', -info )
268  return
269  ELSE IF( lquery ) THEN
270  return
271  END IF
272 *
273 * Quick return if possible
274 *
275  IF( m.EQ.0 .OR. n.EQ.0 ) THEN
276  return
277  END IF
278 *
279  nbmin = 2
280  ldwork = nw
281  IF( nb.GT.1 .AND. nb.LT.k ) THEN
282  iws = nw*nb
283  IF( lwork.LT.iws ) THEN
284  nb = lwork / ldwork
285  nbmin = max( 2, ilaenv( 2, 'CUNMRQ', side // trans, m, n, k,
286  $ -1 ) )
287  END IF
288  ELSE
289  iws = nw
290  END IF
291 *
292  IF( nb.LT.nbmin .OR. nb.GE.k ) THEN
293 *
294 * Use unblocked code
295 *
296  CALL cunmr2( side, trans, m, n, k, a, lda, tau, c, ldc, work,
297  $ iinfo )
298  ELSE
299 *
300 * Use blocked code
301 *
302  IF( ( left .AND. .NOT.notran ) .OR.
303  $ ( .NOT.left .AND. notran ) ) THEN
304  i1 = 1
305  i2 = k
306  i3 = nb
307  ELSE
308  i1 = ( ( k-1 ) / nb )*nb + 1
309  i2 = 1
310  i3 = -nb
311  END IF
312 *
313  IF( left ) THEN
314  ni = n
315  ELSE
316  mi = m
317  END IF
318 *
319  IF( notran ) THEN
320  transt = 'C'
321  ELSE
322  transt = 'N'
323  END IF
324 *
325  DO 10 i = i1, i2, i3
326  ib = min( nb, k-i+1 )
327 *
328 * Form the triangular factor of the block reflector
329 * H = H(i+ib-1) . . . H(i+1) H(i)
330 *
331  CALL clarft( 'Backward', 'Rowwise', nq-k+i+ib-1, ib,
332  $ a( i, 1 ), lda, tau( i ), t, ldt )
333  IF( left ) THEN
334 *
335 * H or H**H is applied to C(1:m-k+i+ib-1,1:n)
336 *
337  mi = m - k + i + ib - 1
338  ELSE
339 *
340 * H or H**H is applied to C(1:m,1:n-k+i+ib-1)
341 *
342  ni = n - k + i + ib - 1
343  END IF
344 *
345 * Apply H or H**H
346 *
347  CALL clarfb( side, transt, 'Backward', 'Rowwise', mi, ni,
348  $ ib, a( i, 1 ), lda, t, ldt, c, ldc, work,
349  $ ldwork )
350  10 continue
351  END IF
352  work( 1 ) = lwkopt
353  return
354 *
355 * End of CUNMRQ
356 *
357  END