LAPACK  3.4.2
LAPACK: Linear Algebra PACKage
 All Files Functions Groups
ctgsja.f
Go to the documentation of this file.
1 *> \brief \b CTGSJA
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download CTGSJA + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/ctgsja.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/ctgsja.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/ctgsja.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE CTGSJA( JOBU, JOBV, JOBQ, M, P, N, K, L, A, LDA, B,
22 * LDB, TOLA, TOLB, ALPHA, BETA, U, LDU, V, LDV,
23 * Q, LDQ, WORK, NCYCLE, INFO )
24 *
25 * .. Scalar Arguments ..
26 * CHARACTER JOBQ, JOBU, JOBV
27 * INTEGER INFO, K, L, LDA, LDB, LDQ, LDU, LDV, M, N,
28 * $ NCYCLE, P
29 * REAL TOLA, TOLB
30 * ..
31 * .. Array Arguments ..
32 * REAL ALPHA( * ), BETA( * )
33 * COMPLEX A( LDA, * ), B( LDB, * ), Q( LDQ, * ),
34 * $ U( LDU, * ), V( LDV, * ), WORK( * )
35 * ..
36 *
37 *
38 *> \par Purpose:
39 * =============
40 *>
41 *> \verbatim
42 *>
43 *> CTGSJA computes the generalized singular value decomposition (GSVD)
44 *> of two complex upper triangular (or trapezoidal) matrices A and B.
45 *>
46 *> On entry, it is assumed that matrices A and B have the following
47 *> forms, which may be obtained by the preprocessing subroutine CGGSVP
48 *> from a general M-by-N matrix A and P-by-N matrix B:
49 *>
50 *> N-K-L K L
51 *> A = K ( 0 A12 A13 ) if M-K-L >= 0;
52 *> L ( 0 0 A23 )
53 *> M-K-L ( 0 0 0 )
54 *>
55 *> N-K-L K L
56 *> A = K ( 0 A12 A13 ) if M-K-L < 0;
57 *> M-K ( 0 0 A23 )
58 *>
59 *> N-K-L K L
60 *> B = L ( 0 0 B13 )
61 *> P-L ( 0 0 0 )
62 *>
63 *> where the K-by-K matrix A12 and L-by-L matrix B13 are nonsingular
64 *> upper triangular; A23 is L-by-L upper triangular if M-K-L >= 0,
65 *> otherwise A23 is (M-K)-by-L upper trapezoidal.
66 *>
67 *> On exit,
68 *>
69 *> U**H *A*Q = D1*( 0 R ), V**H *B*Q = D2*( 0 R ),
70 *>
71 *> where U, V and Q are unitary matrices.
72 *> R is a nonsingular upper triangular matrix, and D1
73 *> and D2 are ``diagonal'' matrices, which are of the following
74 *> structures:
75 *>
76 *> If M-K-L >= 0,
77 *>
78 *> K L
79 *> D1 = K ( I 0 )
80 *> L ( 0 C )
81 *> M-K-L ( 0 0 )
82 *>
83 *> K L
84 *> D2 = L ( 0 S )
85 *> P-L ( 0 0 )
86 *>
87 *> N-K-L K L
88 *> ( 0 R ) = K ( 0 R11 R12 ) K
89 *> L ( 0 0 R22 ) L
90 *>
91 *> where
92 *>
93 *> C = diag( ALPHA(K+1), ... , ALPHA(K+L) ),
94 *> S = diag( BETA(K+1), ... , BETA(K+L) ),
95 *> C**2 + S**2 = I.
96 *>
97 *> R is stored in A(1:K+L,N-K-L+1:N) on exit.
98 *>
99 *> If M-K-L < 0,
100 *>
101 *> K M-K K+L-M
102 *> D1 = K ( I 0 0 )
103 *> M-K ( 0 C 0 )
104 *>
105 *> K M-K K+L-M
106 *> D2 = M-K ( 0 S 0 )
107 *> K+L-M ( 0 0 I )
108 *> P-L ( 0 0 0 )
109 *>
110 *> N-K-L K M-K K+L-M
111 *> ( 0 R ) = K ( 0 R11 R12 R13 )
112 *> M-K ( 0 0 R22 R23 )
113 *> K+L-M ( 0 0 0 R33 )
114 *>
115 *> where
116 *> C = diag( ALPHA(K+1), ... , ALPHA(M) ),
117 *> S = diag( BETA(K+1), ... , BETA(M) ),
118 *> C**2 + S**2 = I.
119 *>
120 *> R = ( R11 R12 R13 ) is stored in A(1:M, N-K-L+1:N) and R33 is stored
121 *> ( 0 R22 R23 )
122 *> in B(M-K+1:L,N+M-K-L+1:N) on exit.
123 *>
124 *> The computation of the unitary transformation matrices U, V or Q
125 *> is optional. These matrices may either be formed explicitly, or they
126 *> may be postmultiplied into input matrices U1, V1, or Q1.
127 *> \endverbatim
128 *
129 * Arguments:
130 * ==========
131 *
132 *> \param[in] JOBU
133 *> \verbatim
134 *> JOBU is CHARACTER*1
135 *> = 'U': U must contain a unitary matrix U1 on entry, and
136 *> the product U1*U is returned;
137 *> = 'I': U is initialized to the unit matrix, and the
138 *> unitary matrix U is returned;
139 *> = 'N': U is not computed.
140 *> \endverbatim
141 *>
142 *> \param[in] JOBV
143 *> \verbatim
144 *> JOBV is CHARACTER*1
145 *> = 'V': V must contain a unitary matrix V1 on entry, and
146 *> the product V1*V is returned;
147 *> = 'I': V is initialized to the unit matrix, and the
148 *> unitary matrix V is returned;
149 *> = 'N': V is not computed.
150 *> \endverbatim
151 *>
152 *> \param[in] JOBQ
153 *> \verbatim
154 *> JOBQ is CHARACTER*1
155 *> = 'Q': Q must contain a unitary matrix Q1 on entry, and
156 *> the product Q1*Q is returned;
157 *> = 'I': Q is initialized to the unit matrix, and the
158 *> unitary matrix Q is returned;
159 *> = 'N': Q is not computed.
160 *> \endverbatim
161 *>
162 *> \param[in] M
163 *> \verbatim
164 *> M is INTEGER
165 *> The number of rows of the matrix A. M >= 0.
166 *> \endverbatim
167 *>
168 *> \param[in] P
169 *> \verbatim
170 *> P is INTEGER
171 *> The number of rows of the matrix B. P >= 0.
172 *> \endverbatim
173 *>
174 *> \param[in] N
175 *> \verbatim
176 *> N is INTEGER
177 *> The number of columns of the matrices A and B. N >= 0.
178 *> \endverbatim
179 *>
180 *> \param[in] K
181 *> \verbatim
182 *> K is INTEGER
183 *> \endverbatim
184 *>
185 *> \param[in] L
186 *> \verbatim
187 *> L is INTEGER
188 *>
189 *> K and L specify the subblocks in the input matrices A and B:
190 *> A23 = A(K+1:MIN(K+L,M),N-L+1:N) and B13 = B(1:L,,N-L+1:N)
191 *> of A and B, whose GSVD is going to be computed by CTGSJA.
192 *> See Further Details.
193 *> \endverbatim
194 *>
195 *> \param[in,out] A
196 *> \verbatim
197 *> A is COMPLEX array, dimension (LDA,N)
198 *> On entry, the M-by-N matrix A.
199 *> On exit, A(N-K+1:N,1:MIN(K+L,M) ) contains the triangular
200 *> matrix R or part of R. See Purpose for details.
201 *> \endverbatim
202 *>
203 *> \param[in] LDA
204 *> \verbatim
205 *> LDA is INTEGER
206 *> The leading dimension of the array A. LDA >= max(1,M).
207 *> \endverbatim
208 *>
209 *> \param[in,out] B
210 *> \verbatim
211 *> B is COMPLEX array, dimension (LDB,N)
212 *> On entry, the P-by-N matrix B.
213 *> On exit, if necessary, B(M-K+1:L,N+M-K-L+1:N) contains
214 *> a part of R. See Purpose for details.
215 *> \endverbatim
216 *>
217 *> \param[in] LDB
218 *> \verbatim
219 *> LDB is INTEGER
220 *> The leading dimension of the array B. LDB >= max(1,P).
221 *> \endverbatim
222 *>
223 *> \param[in] TOLA
224 *> \verbatim
225 *> TOLA is REAL
226 *> \endverbatim
227 *>
228 *> \param[in] TOLB
229 *> \verbatim
230 *> TOLB is REAL
231 *>
232 *> TOLA and TOLB are the convergence criteria for the Jacobi-
233 *> Kogbetliantz iteration procedure. Generally, they are the
234 *> same as used in the preprocessing step, say
235 *> TOLA = MAX(M,N)*norm(A)*MACHEPS,
236 *> TOLB = MAX(P,N)*norm(B)*MACHEPS.
237 *> \endverbatim
238 *>
239 *> \param[out] ALPHA
240 *> \verbatim
241 *> ALPHA is REAL array, dimension (N)
242 *> \endverbatim
243 *>
244 *> \param[out] BETA
245 *> \verbatim
246 *> BETA is REAL array, dimension (N)
247 *>
248 *> On exit, ALPHA and BETA contain the generalized singular
249 *> value pairs of A and B;
250 *> ALPHA(1:K) = 1,
251 *> BETA(1:K) = 0,
252 *> and if M-K-L >= 0,
253 *> ALPHA(K+1:K+L) = diag(C),
254 *> BETA(K+1:K+L) = diag(S),
255 *> or if M-K-L < 0,
256 *> ALPHA(K+1:M)= C, ALPHA(M+1:K+L)= 0
257 *> BETA(K+1:M) = S, BETA(M+1:K+L) = 1.
258 *> Furthermore, if K+L < N,
259 *> ALPHA(K+L+1:N) = 0
260 *> BETA(K+L+1:N) = 0.
261 *> \endverbatim
262 *>
263 *> \param[in,out] U
264 *> \verbatim
265 *> U is COMPLEX array, dimension (LDU,M)
266 *> On entry, if JOBU = 'U', U must contain a matrix U1 (usually
267 *> the unitary matrix returned by CGGSVP).
268 *> On exit,
269 *> if JOBU = 'I', U contains the unitary matrix U;
270 *> if JOBU = 'U', U contains the product U1*U.
271 *> If JOBU = 'N', U is not referenced.
272 *> \endverbatim
273 *>
274 *> \param[in] LDU
275 *> \verbatim
276 *> LDU is INTEGER
277 *> The leading dimension of the array U. LDU >= max(1,M) if
278 *> JOBU = 'U'; LDU >= 1 otherwise.
279 *> \endverbatim
280 *>
281 *> \param[in,out] V
282 *> \verbatim
283 *> V is COMPLEX array, dimension (LDV,P)
284 *> On entry, if JOBV = 'V', V must contain a matrix V1 (usually
285 *> the unitary matrix returned by CGGSVP).
286 *> On exit,
287 *> if JOBV = 'I', V contains the unitary matrix V;
288 *> if JOBV = 'V', V contains the product V1*V.
289 *> If JOBV = 'N', V is not referenced.
290 *> \endverbatim
291 *>
292 *> \param[in] LDV
293 *> \verbatim
294 *> LDV is INTEGER
295 *> The leading dimension of the array V. LDV >= max(1,P) if
296 *> JOBV = 'V'; LDV >= 1 otherwise.
297 *> \endverbatim
298 *>
299 *> \param[in,out] Q
300 *> \verbatim
301 *> Q is COMPLEX array, dimension (LDQ,N)
302 *> On entry, if JOBQ = 'Q', Q must contain a matrix Q1 (usually
303 *> the unitary matrix returned by CGGSVP).
304 *> On exit,
305 *> if JOBQ = 'I', Q contains the unitary matrix Q;
306 *> if JOBQ = 'Q', Q contains the product Q1*Q.
307 *> If JOBQ = 'N', Q is not referenced.
308 *> \endverbatim
309 *>
310 *> \param[in] LDQ
311 *> \verbatim
312 *> LDQ is INTEGER
313 *> The leading dimension of the array Q. LDQ >= max(1,N) if
314 *> JOBQ = 'Q'; LDQ >= 1 otherwise.
315 *> \endverbatim
316 *>
317 *> \param[out] WORK
318 *> \verbatim
319 *> WORK is COMPLEX array, dimension (2*N)
320 *> \endverbatim
321 *>
322 *> \param[out] NCYCLE
323 *> \verbatim
324 *> NCYCLE is INTEGER
325 *> The number of cycles required for convergence.
326 *> \endverbatim
327 *>
328 *> \param[out] INFO
329 *> \verbatim
330 *> INFO is INTEGER
331 *> = 0: successful exit
332 *> < 0: if INFO = -i, the i-th argument had an illegal value.
333 *> = 1: the procedure does not converge after MAXIT cycles.
334 *> \endverbatim
335 *
336 *> \par Internal Parameters:
337 * =========================
338 *>
339 *> \verbatim
340 *> MAXIT INTEGER
341 *> MAXIT specifies the total loops that the iterative procedure
342 *> may take. If after MAXIT cycles, the routine fails to
343 *> converge, we return INFO = 1.
344 *> \endverbatim
345 *
346 * Authors:
347 * ========
348 *
349 *> \author Univ. of Tennessee
350 *> \author Univ. of California Berkeley
351 *> \author Univ. of Colorado Denver
352 *> \author NAG Ltd.
353 *
354 *> \date November 2011
355 *
356 *> \ingroup complexOTHERcomputational
357 *
358 *> \par Further Details:
359 * =====================
360 *>
361 *> \verbatim
362 *>
363 *> CTGSJA essentially uses a variant of Kogbetliantz algorithm to reduce
364 *> min(L,M-K)-by-L triangular (or trapezoidal) matrix A23 and L-by-L
365 *> matrix B13 to the form:
366 *>
367 *> U1**H *A13*Q1 = C1*R1; V1**H *B13*Q1 = S1*R1,
368 *>
369 *> where U1, V1 and Q1 are unitary matrix.
370 *> C1 and S1 are diagonal matrices satisfying
371 *>
372 *> C1**2 + S1**2 = I,
373 *>
374 *> and R1 is an L-by-L nonsingular upper triangular matrix.
375 *> \endverbatim
376 *>
377 * =====================================================================
378  SUBROUTINE ctgsja( JOBU, JOBV, JOBQ, M, P, N, K, L, A, LDA, B,
379  $ ldb, tola, tolb, alpha, beta, u, ldu, v, ldv,
380  $ q, ldq, work, ncycle, info )
381 *
382 * -- LAPACK computational routine (version 3.4.0) --
383 * -- LAPACK is a software package provided by Univ. of Tennessee, --
384 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
385 * November 2011
386 *
387 * .. Scalar Arguments ..
388  CHARACTER jobq, jobu, jobv
389  INTEGER info, k, l, lda, ldb, ldq, ldu, ldv, m, n,
390  $ ncycle, p
391  REAL tola, tolb
392 * ..
393 * .. Array Arguments ..
394  REAL alpha( * ), beta( * )
395  COMPLEX a( lda, * ), b( ldb, * ), q( ldq, * ),
396  $ u( ldu, * ), v( ldv, * ), work( * )
397 * ..
398 *
399 * =====================================================================
400 *
401 * .. Parameters ..
402  INTEGER maxit
403  parameter( maxit = 40 )
404  REAL zero, one
405  parameter( zero = 0.0e+0, one = 1.0e+0 )
406  COMPLEX czero, cone
407  parameter( czero = ( 0.0e+0, 0.0e+0 ),
408  $ cone = ( 1.0e+0, 0.0e+0 ) )
409 * ..
410 * .. Local Scalars ..
411 *
412  LOGICAL initq, initu, initv, upper, wantq, wantu, wantv
413  INTEGER i, j, kcycle
414  REAL a1, a3, b1, b3, csq, csu, csv, error, gamma,
415  $ rwk, ssmin
416  COMPLEX a2, b2, snq, snu, snv
417 * ..
418 * .. External Functions ..
419  LOGICAL lsame
420  EXTERNAL lsame
421 * ..
422 * .. External Subroutines ..
423  EXTERNAL ccopy, clags2, clapll, claset, crot, csscal,
424  $ slartg, xerbla
425 * ..
426 * .. Intrinsic Functions ..
427  INTRINSIC abs, conjg, max, min, real
428 * ..
429 * .. Executable Statements ..
430 *
431 * Decode and test the input parameters
432 *
433  initu = lsame( jobu, 'I' )
434  wantu = initu .OR. lsame( jobu, 'U' )
435 *
436  initv = lsame( jobv, 'I' )
437  wantv = initv .OR. lsame( jobv, 'V' )
438 *
439  initq = lsame( jobq, 'I' )
440  wantq = initq .OR. lsame( jobq, 'Q' )
441 *
442  info = 0
443  IF( .NOT.( initu .OR. wantu .OR. lsame( jobu, 'N' ) ) ) THEN
444  info = -1
445  ELSE IF( .NOT.( initv .OR. wantv .OR. lsame( jobv, 'N' ) ) ) THEN
446  info = -2
447  ELSE IF( .NOT.( initq .OR. wantq .OR. lsame( jobq, 'N' ) ) ) THEN
448  info = -3
449  ELSE IF( m.LT.0 ) THEN
450  info = -4
451  ELSE IF( p.LT.0 ) THEN
452  info = -5
453  ELSE IF( n.LT.0 ) THEN
454  info = -6
455  ELSE IF( lda.LT.max( 1, m ) ) THEN
456  info = -10
457  ELSE IF( ldb.LT.max( 1, p ) ) THEN
458  info = -12
459  ELSE IF( ldu.LT.1 .OR. ( wantu .AND. ldu.LT.m ) ) THEN
460  info = -18
461  ELSE IF( ldv.LT.1 .OR. ( wantv .AND. ldv.LT.p ) ) THEN
462  info = -20
463  ELSE IF( ldq.LT.1 .OR. ( wantq .AND. ldq.LT.n ) ) THEN
464  info = -22
465  END IF
466  IF( info.NE.0 ) THEN
467  CALL xerbla( 'CTGSJA', -info )
468  return
469  END IF
470 *
471 * Initialize U, V and Q, if necessary
472 *
473  IF( initu )
474  $ CALL claset( 'Full', m, m, czero, cone, u, ldu )
475  IF( initv )
476  $ CALL claset( 'Full', p, p, czero, cone, v, ldv )
477  IF( initq )
478  $ CALL claset( 'Full', n, n, czero, cone, q, ldq )
479 *
480 * Loop until convergence
481 *
482  upper = .false.
483  DO 40 kcycle = 1, maxit
484 *
485  upper = .NOT.upper
486 *
487  DO 20 i = 1, l - 1
488  DO 10 j = i + 1, l
489 *
490  a1 = zero
491  a2 = czero
492  a3 = zero
493  IF( k+i.LE.m )
494  $ a1 = REAL( A( K+I, N-L+I ) )
495  IF( k+j.LE.m )
496  $ a3 = REAL( A( K+J, N-L+J ) )
497 *
498  b1 = REAL( B( I, N-L+I ) )
499  b3 = REAL( B( J, N-L+J ) )
500 *
501  IF( upper ) THEN
502  IF( k+i.LE.m )
503  $ a2 = a( k+i, n-l+j )
504  b2 = b( i, n-l+j )
505  ELSE
506  IF( k+j.LE.m )
507  $ a2 = a( k+j, n-l+i )
508  b2 = b( j, n-l+i )
509  END IF
510 *
511  CALL clags2( upper, a1, a2, a3, b1, b2, b3, csu, snu,
512  $ csv, snv, csq, snq )
513 *
514 * Update (K+I)-th and (K+J)-th rows of matrix A: U**H *A
515 *
516  IF( k+j.LE.m )
517  $ CALL crot( l, a( k+j, n-l+1 ), lda, a( k+i, n-l+1 ),
518  $ lda, csu, conjg( snu ) )
519 *
520 * Update I-th and J-th rows of matrix B: V**H *B
521 *
522  CALL crot( l, b( j, n-l+1 ), ldb, b( i, n-l+1 ), ldb,
523  $ csv, conjg( snv ) )
524 *
525 * Update (N-L+I)-th and (N-L+J)-th columns of matrices
526 * A and B: A*Q and B*Q
527 *
528  CALL crot( min( k+l, m ), a( 1, n-l+j ), 1,
529  $ a( 1, n-l+i ), 1, csq, snq )
530 *
531  CALL crot( l, b( 1, n-l+j ), 1, b( 1, n-l+i ), 1, csq,
532  $ snq )
533 *
534  IF( upper ) THEN
535  IF( k+i.LE.m )
536  $ a( k+i, n-l+j ) = czero
537  b( i, n-l+j ) = czero
538  ELSE
539  IF( k+j.LE.m )
540  $ a( k+j, n-l+i ) = czero
541  b( j, n-l+i ) = czero
542  END IF
543 *
544 * Ensure that the diagonal elements of A and B are real.
545 *
546  IF( k+i.LE.m )
547  $ a( k+i, n-l+i ) = REAL( A( K+I, N-L+I ) )
548  IF( k+j.LE.m )
549  $ a( k+j, n-l+j ) = REAL( A( K+J, N-L+J ) )
550  b( i, n-l+i ) = REAL( B( I, N-L+I ) )
551  b( j, n-l+j ) = REAL( B( J, N-L+J ) )
552 *
553 * Update unitary matrices U, V, Q, if desired.
554 *
555  IF( wantu .AND. k+j.LE.m )
556  $ CALL crot( m, u( 1, k+j ), 1, u( 1, k+i ), 1, csu,
557  $ snu )
558 *
559  IF( wantv )
560  $ CALL crot( p, v( 1, j ), 1, v( 1, i ), 1, csv, snv )
561 *
562  IF( wantq )
563  $ CALL crot( n, q( 1, n-l+j ), 1, q( 1, n-l+i ), 1, csq,
564  $ snq )
565 *
566  10 continue
567  20 continue
568 *
569  IF( .NOT.upper ) THEN
570 *
571 * The matrices A13 and B13 were lower triangular at the start
572 * of the cycle, and are now upper triangular.
573 *
574 * Convergence test: test the parallelism of the corresponding
575 * rows of A and B.
576 *
577  error = zero
578  DO 30 i = 1, min( l, m-k )
579  CALL ccopy( l-i+1, a( k+i, n-l+i ), lda, work, 1 )
580  CALL ccopy( l-i+1, b( i, n-l+i ), ldb, work( l+1 ), 1 )
581  CALL clapll( l-i+1, work, 1, work( l+1 ), 1, ssmin )
582  error = max( error, ssmin )
583  30 continue
584 *
585  IF( abs( error ).LE.min( tola, tolb ) )
586  $ go to 50
587  END IF
588 *
589 * End of cycle loop
590 *
591  40 continue
592 *
593 * The algorithm has not converged after MAXIT cycles.
594 *
595  info = 1
596  go to 100
597 *
598  50 continue
599 *
600 * If ERROR <= MIN(TOLA,TOLB), then the algorithm has converged.
601 * Compute the generalized singular value pairs (ALPHA, BETA), and
602 * set the triangular matrix R to array A.
603 *
604  DO 60 i = 1, k
605  alpha( i ) = one
606  beta( i ) = zero
607  60 continue
608 *
609  DO 70 i = 1, min( l, m-k )
610 *
611  a1 = REAL( A( K+I, N-L+I ) )
612  b1 = REAL( B( I, N-L+I ) )
613 *
614  IF( a1.NE.zero ) THEN
615  gamma = b1 / a1
616 *
617  IF( gamma.LT.zero ) THEN
618  CALL csscal( l-i+1, -one, b( i, n-l+i ), ldb )
619  IF( wantv )
620  $ CALL csscal( p, -one, v( 1, i ), 1 )
621  END IF
622 *
623  CALL slartg( abs( gamma ), one, beta( k+i ), alpha( k+i ),
624  $ rwk )
625 *
626  IF( alpha( k+i ).GE.beta( k+i ) ) THEN
627  CALL csscal( l-i+1, one / alpha( k+i ), a( k+i, n-l+i ),
628  $ lda )
629  ELSE
630  CALL csscal( l-i+1, one / beta( k+i ), b( i, n-l+i ),
631  $ ldb )
632  CALL ccopy( l-i+1, b( i, n-l+i ), ldb, a( k+i, n-l+i ),
633  $ lda )
634  END IF
635 *
636  ELSE
637  alpha( k+i ) = zero
638  beta( k+i ) = one
639  CALL ccopy( l-i+1, b( i, n-l+i ), ldb, a( k+i, n-l+i ),
640  $ lda )
641  END IF
642  70 continue
643 *
644 * Post-assignment
645 *
646  DO 80 i = m + 1, k + l
647  alpha( i ) = zero
648  beta( i ) = one
649  80 continue
650 *
651  IF( k+l.LT.n ) THEN
652  DO 90 i = k + l + 1, n
653  alpha( i ) = zero
654  beta( i ) = zero
655  90 continue
656  END IF
657 *
658  100 continue
659  ncycle = kcycle
660 *
661  return
662 *
663 * End of CTGSJA
664 *
665  END