LAPACK  3.4.2
LAPACK: Linear Algebra PACKage
 All Files Functions Groups
dspgvd.f
Go to the documentation of this file.
1 *> \brief \b DSPGST
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download DSPGVD + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dspgvd.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dspgvd.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dspgvd.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE DSPGVD( ITYPE, JOBZ, UPLO, N, AP, BP, W, Z, LDZ, WORK,
22 * LWORK, IWORK, LIWORK, INFO )
23 *
24 * .. Scalar Arguments ..
25 * CHARACTER JOBZ, UPLO
26 * INTEGER INFO, ITYPE, LDZ, LIWORK, LWORK, N
27 * ..
28 * .. Array Arguments ..
29 * INTEGER IWORK( * )
30 * DOUBLE PRECISION AP( * ), BP( * ), W( * ), WORK( * ),
31 * $ Z( LDZ, * )
32 * ..
33 *
34 *
35 *> \par Purpose:
36 * =============
37 *>
38 *> \verbatim
39 *>
40 *> DSPGVD computes all the eigenvalues, and optionally, the eigenvectors
41 *> of a real generalized symmetric-definite eigenproblem, of the form
42 *> A*x=(lambda)*B*x, A*Bx=(lambda)*x, or B*A*x=(lambda)*x. Here A and
43 *> B are assumed to be symmetric, stored in packed format, and B is also
44 *> positive definite.
45 *> If eigenvectors are desired, it uses a divide and conquer algorithm.
46 *>
47 *> The divide and conquer algorithm makes very mild assumptions about
48 *> floating point arithmetic. It will work on machines with a guard
49 *> digit in add/subtract, or on those binary machines without guard
50 *> digits which subtract like the Cray X-MP, Cray Y-MP, Cray C-90, or
51 *> Cray-2. It could conceivably fail on hexadecimal or decimal machines
52 *> without guard digits, but we know of none.
53 *> \endverbatim
54 *
55 * Arguments:
56 * ==========
57 *
58 *> \param[in] ITYPE
59 *> \verbatim
60 *> ITYPE is INTEGER
61 *> Specifies the problem type to be solved:
62 *> = 1: A*x = (lambda)*B*x
63 *> = 2: A*B*x = (lambda)*x
64 *> = 3: B*A*x = (lambda)*x
65 *> \endverbatim
66 *>
67 *> \param[in] JOBZ
68 *> \verbatim
69 *> JOBZ is CHARACTER*1
70 *> = 'N': Compute eigenvalues only;
71 *> = 'V': Compute eigenvalues and eigenvectors.
72 *> \endverbatim
73 *>
74 *> \param[in] UPLO
75 *> \verbatim
76 *> UPLO is CHARACTER*1
77 *> = 'U': Upper triangles of A and B are stored;
78 *> = 'L': Lower triangles of A and B are stored.
79 *> \endverbatim
80 *>
81 *> \param[in] N
82 *> \verbatim
83 *> N is INTEGER
84 *> The order of the matrices A and B. N >= 0.
85 *> \endverbatim
86 *>
87 *> \param[in,out] AP
88 *> \verbatim
89 *> AP is DOUBLE PRECISION array, dimension (N*(N+1)/2)
90 *> On entry, the upper or lower triangle of the symmetric matrix
91 *> A, packed columnwise in a linear array. The j-th column of A
92 *> is stored in the array AP as follows:
93 *> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
94 *> if UPLO = 'L', AP(i + (j-1)*(2*n-j)/2) = A(i,j) for j<=i<=n.
95 *>
96 *> On exit, the contents of AP are destroyed.
97 *> \endverbatim
98 *>
99 *> \param[in,out] BP
100 *> \verbatim
101 *> BP is DOUBLE PRECISION array, dimension (N*(N+1)/2)
102 *> On entry, the upper or lower triangle of the symmetric matrix
103 *> B, packed columnwise in a linear array. The j-th column of B
104 *> is stored in the array BP as follows:
105 *> if UPLO = 'U', BP(i + (j-1)*j/2) = B(i,j) for 1<=i<=j;
106 *> if UPLO = 'L', BP(i + (j-1)*(2*n-j)/2) = B(i,j) for j<=i<=n.
107 *>
108 *> On exit, the triangular factor U or L from the Cholesky
109 *> factorization B = U**T*U or B = L*L**T, in the same storage
110 *> format as B.
111 *> \endverbatim
112 *>
113 *> \param[out] W
114 *> \verbatim
115 *> W is DOUBLE PRECISION array, dimension (N)
116 *> If INFO = 0, the eigenvalues in ascending order.
117 *> \endverbatim
118 *>
119 *> \param[out] Z
120 *> \verbatim
121 *> Z is DOUBLE PRECISION array, dimension (LDZ, N)
122 *> If JOBZ = 'V', then if INFO = 0, Z contains the matrix Z of
123 *> eigenvectors. The eigenvectors are normalized as follows:
124 *> if ITYPE = 1 or 2, Z**T*B*Z = I;
125 *> if ITYPE = 3, Z**T*inv(B)*Z = I.
126 *> If JOBZ = 'N', then Z is not referenced.
127 *> \endverbatim
128 *>
129 *> \param[in] LDZ
130 *> \verbatim
131 *> LDZ is INTEGER
132 *> The leading dimension of the array Z. LDZ >= 1, and if
133 *> JOBZ = 'V', LDZ >= max(1,N).
134 *> \endverbatim
135 *>
136 *> \param[out] WORK
137 *> \verbatim
138 *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK))
139 *> On exit, if INFO = 0, WORK(1) returns the required LWORK.
140 *> \endverbatim
141 *>
142 *> \param[in] LWORK
143 *> \verbatim
144 *> LWORK is INTEGER
145 *> The dimension of the array WORK.
146 *> If N <= 1, LWORK >= 1.
147 *> If JOBZ = 'N' and N > 1, LWORK >= 2*N.
148 *> If JOBZ = 'V' and N > 1, LWORK >= 1 + 6*N + 2*N**2.
149 *>
150 *> If LWORK = -1, then a workspace query is assumed; the routine
151 *> only calculates the required sizes of the WORK and IWORK
152 *> arrays, returns these values as the first entries of the WORK
153 *> and IWORK arrays, and no error message related to LWORK or
154 *> LIWORK is issued by XERBLA.
155 *> \endverbatim
156 *>
157 *> \param[out] IWORK
158 *> \verbatim
159 *> IWORK is INTEGER array, dimension (MAX(1,LIWORK))
160 *> On exit, if INFO = 0, IWORK(1) returns the required LIWORK.
161 *> \endverbatim
162 *>
163 *> \param[in] LIWORK
164 *> \verbatim
165 *> LIWORK is INTEGER
166 *> The dimension of the array IWORK.
167 *> If JOBZ = 'N' or N <= 1, LIWORK >= 1.
168 *> If JOBZ = 'V' and N > 1, LIWORK >= 3 + 5*N.
169 *>
170 *> If LIWORK = -1, then a workspace query is assumed; the
171 *> routine only calculates the required sizes of the WORK and
172 *> IWORK arrays, returns these values as the first entries of
173 *> the WORK and IWORK arrays, and no error message related to
174 *> LWORK or LIWORK is issued by XERBLA.
175 *> \endverbatim
176 *>
177 *> \param[out] INFO
178 *> \verbatim
179 *> INFO is INTEGER
180 *> = 0: successful exit
181 *> < 0: if INFO = -i, the i-th argument had an illegal value
182 *> > 0: DPPTRF or DSPEVD returned an error code:
183 *> <= N: if INFO = i, DSPEVD failed to converge;
184 *> i off-diagonal elements of an intermediate
185 *> tridiagonal form did not converge to zero;
186 *> > N: if INFO = N + i, for 1 <= i <= N, then the leading
187 *> minor of order i of B is not positive definite.
188 *> The factorization of B could not be completed and
189 *> no eigenvalues or eigenvectors were computed.
190 *> \endverbatim
191 *
192 * Authors:
193 * ========
194 *
195 *> \author Univ. of Tennessee
196 *> \author Univ. of California Berkeley
197 *> \author Univ. of Colorado Denver
198 *> \author NAG Ltd.
199 *
200 *> \date November 2011
201 *
202 *> \ingroup doubleOTHEReigen
203 *
204 *> \par Contributors:
205 * ==================
206 *>
207 *> Mark Fahey, Department of Mathematics, Univ. of Kentucky, USA
208 *
209 * =====================================================================
210  SUBROUTINE dspgvd( ITYPE, JOBZ, UPLO, N, AP, BP, W, Z, LDZ, WORK,
211  $ lwork, iwork, liwork, info )
212 *
213 * -- LAPACK driver routine (version 3.4.0) --
214 * -- LAPACK is a software package provided by Univ. of Tennessee, --
215 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
216 * November 2011
217 *
218 * .. Scalar Arguments ..
219  CHARACTER jobz, uplo
220  INTEGER info, itype, ldz, liwork, lwork, n
221 * ..
222 * .. Array Arguments ..
223  INTEGER iwork( * )
224  DOUBLE PRECISION ap( * ), bp( * ), w( * ), work( * ),
225  $ z( ldz, * )
226 * ..
227 *
228 * =====================================================================
229 *
230 * .. Local Scalars ..
231  LOGICAL lquery, upper, wantz
232  CHARACTER trans
233  INTEGER j, liwmin, lwmin, neig
234 * ..
235 * .. External Functions ..
236  LOGICAL lsame
237  EXTERNAL lsame
238 * ..
239 * .. External Subroutines ..
240  EXTERNAL dpptrf, dspevd, dspgst, dtpmv, dtpsv, xerbla
241 * ..
242 * .. Intrinsic Functions ..
243  INTRINSIC dble, max
244 * ..
245 * .. Executable Statements ..
246 *
247 * Test the input parameters.
248 *
249  wantz = lsame( jobz, 'V' )
250  upper = lsame( uplo, 'U' )
251  lquery = ( lwork.EQ.-1 .OR. liwork.EQ.-1 )
252 *
253  info = 0
254  IF( itype.LT.1 .OR. itype.GT.3 ) THEN
255  info = -1
256  ELSE IF( .NOT.( wantz .OR. lsame( jobz, 'N' ) ) ) THEN
257  info = -2
258  ELSE IF( .NOT.( upper .OR. lsame( uplo, 'L' ) ) ) THEN
259  info = -3
260  ELSE IF( n.LT.0 ) THEN
261  info = -4
262  ELSE IF( ldz.LT.1 .OR. ( wantz .AND. ldz.LT.n ) ) THEN
263  info = -9
264  END IF
265 *
266  IF( info.EQ.0 ) THEN
267  IF( n.LE.1 ) THEN
268  liwmin = 1
269  lwmin = 1
270  ELSE
271  IF( wantz ) THEN
272  liwmin = 3 + 5*n
273  lwmin = 1 + 6*n + 2*n**2
274  ELSE
275  liwmin = 1
276  lwmin = 2*n
277  END IF
278  END IF
279  work( 1 ) = lwmin
280  iwork( 1 ) = liwmin
281  IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
282  info = -11
283  ELSE IF( liwork.LT.liwmin .AND. .NOT.lquery ) THEN
284  info = -13
285  END IF
286  END IF
287 *
288  IF( info.NE.0 ) THEN
289  CALL xerbla( 'DSPGVD', -info )
290  return
291  ELSE IF( lquery ) THEN
292  return
293  END IF
294 *
295 * Quick return if possible
296 *
297  IF( n.EQ.0 )
298  $ return
299 *
300 * Form a Cholesky factorization of BP.
301 *
302  CALL dpptrf( uplo, n, bp, info )
303  IF( info.NE.0 ) THEN
304  info = n + info
305  return
306  END IF
307 *
308 * Transform problem to standard eigenvalue problem and solve.
309 *
310  CALL dspgst( itype, uplo, n, ap, bp, info )
311  CALL dspevd( jobz, uplo, n, ap, w, z, ldz, work, lwork, iwork,
312  $ liwork, info )
313  lwmin = max( dble( lwmin ), dble( work( 1 ) ) )
314  liwmin = max( dble( liwmin ), dble( iwork( 1 ) ) )
315 *
316  IF( wantz ) THEN
317 *
318 * Backtransform eigenvectors to the original problem.
319 *
320  neig = n
321  IF( info.GT.0 )
322  $ neig = info - 1
323  IF( itype.EQ.1 .OR. itype.EQ.2 ) THEN
324 *
325 * For A*x=(lambda)*B*x and A*B*x=(lambda)*x;
326 * backtransform eigenvectors: x = inv(L)**T *y or inv(U)*y
327 *
328  IF( upper ) THEN
329  trans = 'N'
330  ELSE
331  trans = 'T'
332  END IF
333 *
334  DO 10 j = 1, neig
335  CALL dtpsv( uplo, trans, 'Non-unit', n, bp, z( 1, j ),
336  $ 1 )
337  10 continue
338 *
339  ELSE IF( itype.EQ.3 ) THEN
340 *
341 * For B*A*x=(lambda)*x;
342 * backtransform eigenvectors: x = L*y or U**T *y
343 *
344  IF( upper ) THEN
345  trans = 'T'
346  ELSE
347  trans = 'N'
348  END IF
349 *
350  DO 20 j = 1, neig
351  CALL dtpmv( uplo, trans, 'Non-unit', n, bp, z( 1, j ),
352  $ 1 )
353  20 continue
354  END IF
355  END IF
356 *
357  work( 1 ) = lwmin
358  iwork( 1 ) = liwmin
359 *
360  return
361 *
362 * End of DSPGVD
363 *
364  END