ctzt02.f

Go to the documentation of this file.

*> \brief \b CTZT02
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*  Definition:
*  ===========
*
*       REAL             FUNCTION CTZT02( M, N, AF, LDA, TAU, WORK,
*                        LWORK )
* 
*       .. Scalar Arguments ..
*       INTEGER            LDA, LWORK, M, N
*       ..
*       .. Array Arguments ..
*       COMPLEX            AF( LDA, * ), TAU( * ), WORK( LWORK )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CTZT02 returns
*>      || I - Q'*Q || / ( M * eps)
*> where the matrix Q is defined by the Householder transformations
*> generated by CTZRQF.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix AF.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrix AF.
*> \endverbatim
*>
*> \param[in] AF
*> \verbatim
*>          AF is COMPLEX array, dimension (LDA,N)
*>          The output of CTZRQF.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array AF.
*> \endverbatim
*>
*> \param[in] TAU
*> \verbatim
*>          TAU is COMPLEX array, dimension (M)
*>          Details of the Householder transformations as returned by
*>          CTZRQF.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          length of WORK array. Must be >= N*N+N
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup complex_lin
*
*  =====================================================================
      REAL             FUNCTION ctzt02( M, N, AF, LDA, TAU, WORK,
     $                 lwork )
*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            lda, lwork, m, n
*     ..
*     .. Array Arguments ..
      COMPLEX            af( lda, * ), tau( * ), work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter( zero = 0.0e0, one = 1.0e0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i
*     ..
*     .. Local Arrays ..
      REAL               rwork( 1 )
*     ..
*     .. External Functions ..
      REAL               clange, slamch
      EXTERNAL           clange, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           clatzm, claset, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, conjg, max, real
*     ..
*     .. Executable Statements ..
*
      ctzt02 = zero
*
      IF( lwork.LT.n*n+n ) THEN
         CALL xerbla( 'CTZT02', 7 )
         return
      END IF
*
*     Quick return if possible
*
      IF( m.LE.0 .OR. n.LE.0 )
     $   return
*
*     Q := I
*
      CALL claset( 'Full', n, n, cmplx( zero ), cmplx( one ), work, n )
*
*     Q := P(1) * ... * P(m) * Q
*
      DO 10 i = m, 1, -1
         CALL clatzm( 'Left', n-m+1, n, af( i, m+1 ), lda, tau( i ),
     $                work( i ), work( m+1 ), n, work( n*n+1 ) )
   10 continue
*
*     Q := P(m)' * ... * P(1)' * Q
*
      DO 20 i = 1, m
         CALL clatzm( 'Left', n-m+1, n, af( i, m+1 ), lda,
     $                conjg( tau( i ) ), work( i ), work( m+1 ), n,
     $                work( n*n+1 ) )
   20 continue
*
*     Q := Q - I
*
      DO 30 i = 1, n
         work( ( i-1 )*n+i ) = work( ( i-1 )*n+i ) - one
   30 continue
*
      ctzt02 = clange( 'One-norm', n, n, work, n, rwork ) /
     $         ( slamch( 'Epsilon' )*REAL( MAX( M, N ) ) )
      return
*
*     End of CTZT02
*
      END