LAPACK  3.4.2
LAPACK: Linear Algebra PACKage
 All Files Functions Groups
cunmql.f
Go to the documentation of this file.
1 *> \brief \b CUNMQL
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download CUNMQL + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cunmql.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cunmql.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cunmql.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE CUNMQL( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
22 * WORK, LWORK, INFO )
23 *
24 * .. Scalar Arguments ..
25 * CHARACTER SIDE, TRANS
26 * INTEGER INFO, K, LDA, LDC, LWORK, M, N
27 * ..
28 * .. Array Arguments ..
29 * COMPLEX A( LDA, * ), C( LDC, * ), TAU( * ),
30 * $ WORK( * )
31 * ..
32 *
33 *
34 *> \par Purpose:
35 * =============
36 *>
37 *> \verbatim
38 *>
39 *> CUNMQL overwrites the general complex M-by-N matrix C with
40 *>
41 *> SIDE = 'L' SIDE = 'R'
42 *> TRANS = 'N': Q * C C * Q
43 *> TRANS = 'C': Q**H * C C * Q**H
44 *>
45 *> where Q is a complex unitary matrix defined as the product of k
46 *> elementary reflectors
47 *>
48 *> Q = H(k) . . . H(2) H(1)
49 *>
50 *> as returned by CGEQLF. Q is of order M if SIDE = 'L' and of order N
51 *> if SIDE = 'R'.
52 *> \endverbatim
53 *
54 * Arguments:
55 * ==========
56 *
57 *> \param[in] SIDE
58 *> \verbatim
59 *> SIDE is CHARACTER*1
60 *> = 'L': apply Q or Q**H from the Left;
61 *> = 'R': apply Q or Q**H from the Right.
62 *> \endverbatim
63 *>
64 *> \param[in] TRANS
65 *> \verbatim
66 *> TRANS is CHARACTER*1
67 *> = 'N': No transpose, apply Q;
68 *> = 'C': Transpose, apply Q**H.
69 *> \endverbatim
70 *>
71 *> \param[in] M
72 *> \verbatim
73 *> M is INTEGER
74 *> The number of rows of the matrix C. M >= 0.
75 *> \endverbatim
76 *>
77 *> \param[in] N
78 *> \verbatim
79 *> N is INTEGER
80 *> The number of columns of the matrix C. N >= 0.
81 *> \endverbatim
82 *>
83 *> \param[in] K
84 *> \verbatim
85 *> K is INTEGER
86 *> The number of elementary reflectors whose product defines
87 *> the matrix Q.
88 *> If SIDE = 'L', M >= K >= 0;
89 *> if SIDE = 'R', N >= K >= 0.
90 *> \endverbatim
91 *>
92 *> \param[in] A
93 *> \verbatim
94 *> A is COMPLEX array, dimension (LDA,K)
95 *> The i-th column must contain the vector which defines the
96 *> elementary reflector H(i), for i = 1,2,...,k, as returned by
97 *> CGEQLF in the last k columns of its array argument A.
98 *> \endverbatim
99 *>
100 *> \param[in] LDA
101 *> \verbatim
102 *> LDA is INTEGER
103 *> The leading dimension of the array A.
104 *> If SIDE = 'L', LDA >= max(1,M);
105 *> if SIDE = 'R', LDA >= max(1,N).
106 *> \endverbatim
107 *>
108 *> \param[in] TAU
109 *> \verbatim
110 *> TAU is COMPLEX array, dimension (K)
111 *> TAU(i) must contain the scalar factor of the elementary
112 *> reflector H(i), as returned by CGEQLF.
113 *> \endverbatim
114 *>
115 *> \param[in,out] C
116 *> \verbatim
117 *> C is COMPLEX array, dimension (LDC,N)
118 *> On entry, the M-by-N matrix C.
119 *> On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
120 *> \endverbatim
121 *>
122 *> \param[in] LDC
123 *> \verbatim
124 *> LDC is INTEGER
125 *> The leading dimension of the array C. LDC >= max(1,M).
126 *> \endverbatim
127 *>
128 *> \param[out] WORK
129 *> \verbatim
130 *> WORK is COMPLEX array, dimension (MAX(1,LWORK))
131 *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
132 *> \endverbatim
133 *>
134 *> \param[in] LWORK
135 *> \verbatim
136 *> LWORK is INTEGER
137 *> The dimension of the array WORK.
138 *> If SIDE = 'L', LWORK >= max(1,N);
139 *> if SIDE = 'R', LWORK >= max(1,M).
140 *> For optimum performance LWORK >= N*NB if SIDE = 'L', and
141 *> LWORK >= M*NB if SIDE = 'R', where NB is the optimal
142 *> blocksize.
143 *>
144 *> If LWORK = -1, then a workspace query is assumed; the routine
145 *> only calculates the optimal size of the WORK array, returns
146 *> this value as the first entry of the WORK array, and no error
147 *> message related to LWORK is issued by XERBLA.
148 *> \endverbatim
149 *>
150 *> \param[out] INFO
151 *> \verbatim
152 *> INFO is INTEGER
153 *> = 0: successful exit
154 *> < 0: if INFO = -i, the i-th argument had an illegal value
155 *> \endverbatim
156 *
157 * Authors:
158 * ========
159 *
160 *> \author Univ. of Tennessee
161 *> \author Univ. of California Berkeley
162 *> \author Univ. of Colorado Denver
163 *> \author NAG Ltd.
164 *
165 *> \date November 2011
166 *
167 *> \ingroup complexOTHERcomputational
168 *
169 * =====================================================================
170  SUBROUTINE cunmql( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
171  $ work, lwork, info )
172 *
173 * -- LAPACK computational routine (version 3.4.0) --
174 * -- LAPACK is a software package provided by Univ. of Tennessee, --
175 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
176 * November 2011
177 *
178 * .. Scalar Arguments ..
179  CHARACTER side, trans
180  INTEGER info, k, lda, ldc, lwork, m, n
181 * ..
182 * .. Array Arguments ..
183  COMPLEX a( lda, * ), c( ldc, * ), tau( * ),
184  $ work( * )
185 * ..
186 *
187 * =====================================================================
188 *
189 * .. Parameters ..
190  INTEGER nbmax, ldt
191  parameter( nbmax = 64, ldt = nbmax+1 )
192 * ..
193 * .. Local Scalars ..
194  LOGICAL left, lquery, notran
195  INTEGER i, i1, i2, i3, ib, iinfo, iws, ldwork, lwkopt,
196  $ mi, nb, nbmin, ni, nq, nw
197 * ..
198 * .. Local Arrays ..
199  COMPLEX t( ldt, nbmax )
200 * ..
201 * .. External Functions ..
202  LOGICAL lsame
203  INTEGER ilaenv
204  EXTERNAL lsame, ilaenv
205 * ..
206 * .. External Subroutines ..
207  EXTERNAL clarfb, clarft, cunm2l, xerbla
208 * ..
209 * .. Intrinsic Functions ..
210  INTRINSIC max, min
211 * ..
212 * .. Executable Statements ..
213 *
214 * Test the input arguments
215 *
216  info = 0
217  left = lsame( side, 'L' )
218  notran = lsame( trans, 'N' )
219  lquery = ( lwork.EQ.-1 )
220 *
221 * NQ is the order of Q and NW is the minimum dimension of WORK
222 *
223  IF( left ) THEN
224  nq = m
225  nw = max( 1, n )
226  ELSE
227  nq = n
228  nw = max( 1, m )
229  END IF
230  IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
231  info = -1
232  ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'C' ) ) THEN
233  info = -2
234  ELSE IF( m.LT.0 ) THEN
235  info = -3
236  ELSE IF( n.LT.0 ) THEN
237  info = -4
238  ELSE IF( k.LT.0 .OR. k.GT.nq ) THEN
239  info = -5
240  ELSE IF( lda.LT.max( 1, nq ) ) THEN
241  info = -7
242  ELSE IF( ldc.LT.max( 1, m ) ) THEN
243  info = -10
244  END IF
245 *
246  IF( info.EQ.0 ) THEN
247  IF( m.EQ.0 .OR. n.EQ.0 ) THEN
248  lwkopt = 1
249  ELSE
250 *
251 * Determine the block size. NB may be at most NBMAX, where
252 * NBMAX is used to define the local array T.
253 *
254  nb = min( nbmax, ilaenv( 1, 'CUNMQL', side // trans, m, n,
255  $ k, -1 ) )
256  lwkopt = nw*nb
257  END IF
258  work( 1 ) = lwkopt
259 *
260  IF( lwork.LT.nw .AND. .NOT.lquery ) THEN
261  info = -12
262  END IF
263  END IF
264 *
265  IF( info.NE.0 ) THEN
266  CALL xerbla( 'CUNMQL', -info )
267  return
268  ELSE IF( lquery ) THEN
269  return
270  END IF
271 *
272 * Quick return if possible
273 *
274  IF( m.EQ.0 .OR. n.EQ.0 ) THEN
275  return
276  END IF
277 *
278  nbmin = 2
279  ldwork = nw
280  IF( nb.GT.1 .AND. nb.LT.k ) THEN
281  iws = nw*nb
282  IF( lwork.LT.iws ) THEN
283  nb = lwork / ldwork
284  nbmin = max( 2, ilaenv( 2, 'CUNMQL', side // trans, m, n, k,
285  $ -1 ) )
286  END IF
287  ELSE
288  iws = nw
289  END IF
290 *
291  IF( nb.LT.nbmin .OR. nb.GE.k ) THEN
292 *
293 * Use unblocked code
294 *
295  CALL cunm2l( side, trans, m, n, k, a, lda, tau, c, ldc, work,
296  $ iinfo )
297  ELSE
298 *
299 * Use blocked code
300 *
301  IF( ( left .AND. notran ) .OR.
302  $ ( .NOT.left .AND. .NOT.notran ) ) THEN
303  i1 = 1
304  i2 = k
305  i3 = nb
306  ELSE
307  i1 = ( ( k-1 ) / nb )*nb + 1
308  i2 = 1
309  i3 = -nb
310  END IF
311 *
312  IF( left ) THEN
313  ni = n
314  ELSE
315  mi = m
316  END IF
317 *
318  DO 10 i = i1, i2, i3
319  ib = min( nb, k-i+1 )
320 *
321 * Form the triangular factor of the block reflector
322 * H = H(i+ib-1) . . . H(i+1) H(i)
323 *
324  CALL clarft( 'Backward', 'Columnwise', nq-k+i+ib-1, ib,
325  $ a( 1, i ), lda, tau( i ), t, ldt )
326  IF( left ) THEN
327 *
328 * H or H**H is applied to C(1:m-k+i+ib-1,1:n)
329 *
330  mi = m - k + i + ib - 1
331  ELSE
332 *
333 * H or H**H is applied to C(1:m,1:n-k+i+ib-1)
334 *
335  ni = n - k + i + ib - 1
336  END IF
337 *
338 * Apply H or H**H
339 *
340  CALL clarfb( side, trans, 'Backward', 'Columnwise', mi, ni,
341  $ ib, a( 1, i ), lda, t, ldt, c, ldc, work,
342  $ ldwork )
343  10 continue
344  END IF
345  work( 1 ) = lwkopt
346  return
347 *
348 * End of CUNMQL
349 *
350  END