LAPACK 3.3.1 Linear Algebra PACKage

# zqrt01p.f

Go to the documentation of this file.
```00001       SUBROUTINE ZQRT01P( M, N, A, AF, Q, R, LDA, TAU, WORK, LWORK,
00002      \$                   RWORK, RESULT )
00003 *
00004 *  -- LAPACK test routine (version 3.1) --
00005 *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
00006 *     June 2010
00007 *
00008 *     .. Scalar Arguments ..
00009       INTEGER            LDA, LWORK, M, N
00010 *     ..
00011 *     .. Array Arguments ..
00012       DOUBLE PRECISION   RESULT( * ), RWORK( * )
00013       COMPLEX*16         A( LDA, * ), AF( LDA, * ), Q( LDA, * ),
00014      \$                   R( LDA, * ), TAU( * ), WORK( LWORK )
00015 *     ..
00016 *
00017 *  Purpose
00018 *  =======
00019 *
00020 *  ZQRT01P tests ZGEQRFP, which computes the QR factorization of an m-by-n
00021 *  matrix A, and partially tests ZUNGQR which forms the m-by-m
00022 *  orthogonal matrix Q.
00023 *
00024 *  ZQRT01P compares R with Q'*A, and checks that Q is orthogonal.
00025 *
00026 *  Arguments
00027 *  =========
00028 *
00029 *  M       (input) INTEGER
00030 *          The number of rows of the matrix A.  M >= 0.
00031 *
00032 *  N       (input) INTEGER
00033 *          The number of columns of the matrix A.  N >= 0.
00034 *
00035 *  A       (input) COMPLEX*16 array, dimension (LDA,N)
00036 *          The m-by-n matrix A.
00037 *
00038 *  AF      (output) COMPLEX*16 array, dimension (LDA,N)
00039 *          Details of the QR factorization of A, as returned by ZGEQRFP.
00040 *          See ZGEQRFP for further details.
00041 *
00042 *  Q       (output) COMPLEX*16 array, dimension (LDA,M)
00043 *          The m-by-m orthogonal matrix Q.
00044 *
00045 *  R       (workspace) COMPLEX*16 array, dimension (LDA,max(M,N))
00046 *
00047 *  LDA     (input) INTEGER
00048 *          The leading dimension of the arrays A, AF, Q and R.
00049 *          LDA >= max(M,N).
00050 *
00051 *  TAU     (output) COMPLEX*16 array, dimension (min(M,N))
00052 *          The scalar factors of the elementary reflectors, as returned
00053 *          by ZGEQRFP.
00054 *
00055 *  WORK    (workspace) COMPLEX*16 array, dimension (LWORK)
00056 *
00057 *  LWORK   (input) INTEGER
00058 *          The dimension of the array WORK.
00059 *
00060 *  RWORK   (workspace) DOUBLE PRECISION array, dimension (M)
00061 *
00062 *  RESULT  (output) DOUBLE PRECISION array, dimension (2)
00063 *          The test ratios:
00064 *          RESULT(1) = norm( R - Q'*A ) / ( M * norm(A) * EPS )
00065 *          RESULT(2) = norm( I - Q'*Q ) / ( M * EPS )
00066 *
00067 *  =====================================================================
00068 *
00069 *     .. Parameters ..
00070       DOUBLE PRECISION   ZERO, ONE
00071       PARAMETER          ( ZERO = 0.0D+0, ONE = 1.0D+0 )
00072       COMPLEX*16         ROGUE
00073       PARAMETER          ( ROGUE = ( -1.0D+10, -1.0D+10 ) )
00074 *     ..
00075 *     .. Local Scalars ..
00076       INTEGER            INFO, MINMN
00077       DOUBLE PRECISION   ANORM, EPS, RESID
00078 *     ..
00079 *     .. External Functions ..
00080       DOUBLE PRECISION   DLAMCH, ZLANGE, ZLANSY
00081       EXTERNAL           DLAMCH, ZLANGE, ZLANSY
00082 *     ..
00083 *     .. External Subroutines ..
00084       EXTERNAL           ZGEMM, ZGEQRFP, ZHERK, ZLACPY, ZLASET, ZUNGQR
00085 *     ..
00086 *     .. Intrinsic Functions ..
00087       INTRINSIC          DBLE, DCMPLX, MAX, MIN
00088 *     ..
00089 *     .. Scalars in Common ..
00090       CHARACTER*32       SRNAMT
00091 *     ..
00092 *     .. Common blocks ..
00093       COMMON             / SRNAMC / SRNAMT
00094 *     ..
00095 *     .. Executable Statements ..
00096 *
00097       MINMN = MIN( M, N )
00098       EPS = DLAMCH( 'Epsilon' )
00099 *
00100 *     Copy the matrix A to the array AF.
00101 *
00102       CALL ZLACPY( 'Full', M, N, A, LDA, AF, LDA )
00103 *
00104 *     Factorize the matrix A in the array AF.
00105 *
00106       SRNAMT = 'ZGEQRFP'
00107       CALL ZGEQRFP( M, N, AF, LDA, TAU, WORK, LWORK, INFO )
00108 *
00109 *     Copy details of Q
00110 *
00111       CALL ZLASET( 'Full', M, M, ROGUE, ROGUE, Q, LDA )
00112       CALL ZLACPY( 'Lower', M-1, N, AF( 2, 1 ), LDA, Q( 2, 1 ), LDA )
00113 *
00114 *     Generate the m-by-m matrix Q
00115 *
00116       SRNAMT = 'ZUNGQR'
00117       CALL ZUNGQR( M, M, MINMN, Q, LDA, TAU, WORK, LWORK, INFO )
00118 *
00119 *     Copy R
00120 *
00121       CALL ZLASET( 'Full', M, N, DCMPLX( ZERO ), DCMPLX( ZERO ), R,
00122      \$             LDA )
00123       CALL ZLACPY( 'Upper', M, N, AF, LDA, R, LDA )
00124 *
00125 *     Compute R - Q'*A
00126 *
00127       CALL ZGEMM( 'Conjugate transpose', 'No transpose', M, N, M,
00128      \$            DCMPLX( -ONE ), Q, LDA, A, LDA, DCMPLX( ONE ), R,
00129      \$            LDA )
00130 *
00131 *     Compute norm( R - Q'*A ) / ( M * norm(A) * EPS ) .
00132 *
00133       ANORM = ZLANGE( '1', M, N, A, LDA, RWORK )
00134       RESID = ZLANGE( '1', M, N, R, LDA, RWORK )
00135       IF( ANORM.GT.ZERO ) THEN
00136          RESULT( 1 ) = ( ( RESID / DBLE( MAX( 1, M ) ) ) / ANORM ) / EPS
00137       ELSE
00138          RESULT( 1 ) = ZERO
00139       END IF
00140 *
00141 *     Compute I - Q'*Q
00142 *
00143       CALL ZLASET( 'Full', M, M, DCMPLX( ZERO ), DCMPLX( ONE ), R, LDA )
00144       CALL ZHERK( 'Upper', 'Conjugate transpose', M, M, -ONE, Q, LDA,
00145      \$            ONE, R, LDA )
00146 *
00147 *     Compute norm( I - Q'*Q ) / ( M * EPS ) .
00148 *
00149       RESID = ZLANSY( '1', 'Upper', M, R, LDA, RWORK )
00150 *
00151       RESULT( 2 ) = ( RESID / DBLE( MAX( 1, M ) ) ) / EPS
00152 *
00153       RETURN
00154 *
00155 *     End of ZQRT01P
00156 *
00157       END
```