LAPACK 3.3.0

cung2l.f

Go to the documentation of this file.
00001       SUBROUTINE CUNG2L( M, N, K, A, LDA, TAU, WORK, INFO )
00002 *
00003 *  -- LAPACK routine (version 3.2) --
00004 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
00005 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
00006 *     November 2006
00007 *
00008 *     .. Scalar Arguments ..
00009       INTEGER            INFO, K, LDA, M, N
00010 *     ..
00011 *     .. Array Arguments ..
00012       COMPLEX            A( LDA, * ), TAU( * ), WORK( * )
00013 *     ..
00014 *
00015 *  Purpose
00016 *  =======
00017 *
00018 *  CUNG2L generates an m by n complex matrix Q with orthonormal columns,
00019 *  which is defined as the last n columns of a product of k elementary
00020 *  reflectors of order m
00021 *
00022 *        Q  =  H(k) . . . H(2) H(1)
00023 *
00024 *  as returned by CGEQLF.
00025 *
00026 *  Arguments
00027 *  =========
00028 *
00029 *  M       (input) INTEGER
00030 *          The number of rows of the matrix Q. M >= 0.
00031 *
00032 *  N       (input) INTEGER
00033 *          The number of columns of the matrix Q. M >= N >= 0.
00034 *
00035 *  K       (input) INTEGER
00036 *          The number of elementary reflectors whose product defines the
00037 *          matrix Q. N >= K >= 0.
00038 *
00039 *  A       (input/output) COMPLEX array, dimension (LDA,N)
00040 *          On entry, the (n-k+i)-th column must contain the vector which
00041 *          defines the elementary reflector H(i), for i = 1,2,...,k, as
00042 *          returned by CGEQLF in the last k columns of its array
00043 *          argument A.
00044 *          On exit, the m-by-n matrix Q.
00045 *
00046 *  LDA     (input) INTEGER
00047 *          The first dimension of the array A. LDA >= max(1,M).
00048 *
00049 *  TAU     (input) COMPLEX array, dimension (K)
00050 *          TAU(i) must contain the scalar factor of the elementary
00051 *          reflector H(i), as returned by CGEQLF.
00052 *
00053 *  WORK    (workspace) COMPLEX array, dimension (N)
00054 *
00055 *  INFO    (output) INTEGER
00056 *          = 0: successful exit
00057 *          < 0: if INFO = -i, the i-th argument has an illegal value
00058 *
00059 *  =====================================================================
00060 *
00061 *     .. Parameters ..
00062       COMPLEX            ONE, ZERO
00063       PARAMETER          ( ONE = ( 1.0E+0, 0.0E+0 ),
00064      $                   ZERO = ( 0.0E+0, 0.0E+0 ) )
00065 *     ..
00066 *     .. Local Scalars ..
00067       INTEGER            I, II, J, L
00068 *     ..
00069 *     .. External Subroutines ..
00070       EXTERNAL           CLARF, CSCAL, XERBLA
00071 *     ..
00072 *     .. Intrinsic Functions ..
00073       INTRINSIC          MAX
00074 *     ..
00075 *     .. Executable Statements ..
00076 *
00077 *     Test the input arguments
00078 *
00079       INFO = 0
00080       IF( M.LT.0 ) THEN
00081          INFO = -1
00082       ELSE IF( N.LT.0 .OR. N.GT.M ) THEN
00083          INFO = -2
00084       ELSE IF( K.LT.0 .OR. K.GT.N ) THEN
00085          INFO = -3
00086       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
00087          INFO = -5
00088       END IF
00089       IF( INFO.NE.0 ) THEN
00090          CALL XERBLA( 'CUNG2L', -INFO )
00091          RETURN
00092       END IF
00093 *
00094 *     Quick return if possible
00095 *
00096       IF( N.LE.0 )
00097      $   RETURN
00098 *
00099 *     Initialise columns 1:n-k to columns of the unit matrix
00100 *
00101       DO 20 J = 1, N - K
00102          DO 10 L = 1, M
00103             A( L, J ) = ZERO
00104    10    CONTINUE
00105          A( M-N+J, J ) = ONE
00106    20 CONTINUE
00107 *
00108       DO 40 I = 1, K
00109          II = N - K + I
00110 *
00111 *        Apply H(i) to A(1:m-k+i,1:n-k+i) from the left
00112 *
00113          A( M-N+II, II ) = ONE
00114          CALL CLARF( 'Left', M-N+II, II-1, A( 1, II ), 1, TAU( I ), A,
00115      $               LDA, WORK )
00116          CALL CSCAL( M-N+II-1, -TAU( I ), A( 1, II ), 1 )
00117          A( M-N+II, II ) = ONE - TAU( I )
00118 *
00119 *        Set A(m-k+i+1:m,n-k+i) to zero
00120 *
00121          DO 30 L = M - N + II + 1, M
00122             A( L, II ) = ZERO
00123    30    CONTINUE
00124    40 CONTINUE
00125       RETURN
00126 *
00127 *     End of CUNG2L
00128 *
00129       END
 All Files Functions