001:       SUBROUTINE ZUNGTR( UPLO, N, A, LDA, TAU, WORK, LWORK, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          UPLO
010:       INTEGER            INFO, LDA, LWORK, N
011: *     ..
012: *     .. Array Arguments ..
013:       COMPLEX*16         A( LDA, * ), TAU( * ), WORK( * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  ZUNGTR generates a complex unitary matrix Q which is defined as the
020: *  product of n-1 elementary reflectors of order N, as returned by
021: *  ZHETRD:
022: *
023: *  if UPLO = 'U', Q = H(n-1) . . . H(2) H(1),
024: *
025: *  if UPLO = 'L', Q = H(1) H(2) . . . H(n-1).
026: *
027: *  Arguments
028: *  =========
029: *
030: *  UPLO    (input) CHARACTER*1
031: *          = 'U': Upper triangle of A contains elementary reflectors
032: *                 from ZHETRD;
033: *          = 'L': Lower triangle of A contains elementary reflectors
034: *                 from ZHETRD.
035: *
036: *  N       (input) INTEGER
037: *          The order of the matrix Q. N >= 0.
038: *
039: *  A       (input/output) COMPLEX*16 array, dimension (LDA,N)
040: *          On entry, the vectors which define the elementary reflectors,
041: *          as returned by ZHETRD.
042: *          On exit, the N-by-N unitary matrix Q.
043: *
044: *  LDA     (input) INTEGER
045: *          The leading dimension of the array A. LDA >= N.
046: *
047: *  TAU     (input) COMPLEX*16 array, dimension (N-1)
048: *          TAU(i) must contain the scalar factor of the elementary
049: *          reflector H(i), as returned by ZHETRD.
050: *
051: *  WORK    (workspace/output) COMPLEX*16 array, dimension (MAX(1,LWORK))
052: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
053: *
054: *  LWORK   (input) INTEGER
055: *          The dimension of the array WORK. LWORK >= N-1.
056: *          For optimum performance LWORK >= (N-1)*NB, where NB is
057: *          the optimal blocksize.
058: *
059: *          If LWORK = -1, then a workspace query is assumed; the routine
060: *          only calculates the optimal size of the WORK array, returns
061: *          this value as the first entry of the WORK array, and no error
062: *          message related to LWORK is issued by XERBLA.
063: *
064: *  INFO    (output) INTEGER
065: *          = 0:  successful exit
066: *          < 0:  if INFO = -i, the i-th argument had an illegal value
067: *
068: *  =====================================================================
069: *
070: *     .. Parameters ..
071:       COMPLEX*16         ZERO, ONE
072:       PARAMETER          ( ZERO = ( 0.0D+0, 0.0D+0 ),
073:      $                   ONE = ( 1.0D+0, 0.0D+0 ) )
074: *     ..
075: *     .. Local Scalars ..
076:       LOGICAL            LQUERY, UPPER
077:       INTEGER            I, IINFO, J, LWKOPT, NB
078: *     ..
079: *     .. External Functions ..
080:       LOGICAL            LSAME
081:       INTEGER            ILAENV
082:       EXTERNAL           LSAME, ILAENV
083: *     ..
084: *     .. External Subroutines ..
085:       EXTERNAL           XERBLA, ZUNGQL, ZUNGQR
086: *     ..
087: *     .. Intrinsic Functions ..
088:       INTRINSIC          MAX
089: *     ..
090: *     .. Executable Statements ..
091: *
092: *     Test the input arguments
093: *
094:       INFO = 0
095:       LQUERY = ( LWORK.EQ.-1 )
096:       UPPER = LSAME( UPLO, 'U' )
097:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
098:          INFO = -1
099:       ELSE IF( N.LT.0 ) THEN
100:          INFO = -2
101:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
102:          INFO = -4
103:       ELSE IF( LWORK.LT.MAX( 1, N-1 ) .AND. .NOT.LQUERY ) THEN
104:          INFO = -7
105:       END IF
106: *
107:       IF( INFO.EQ.0 ) THEN
108:          IF( UPPER ) THEN
109:             NB = ILAENV( 1, 'ZUNGQL', ' ', N-1, N-1, N-1, -1 )
110:          ELSE
111:             NB = ILAENV( 1, 'ZUNGQR', ' ', N-1, N-1, N-1, -1 )
112:          END IF
113:          LWKOPT = MAX( 1, N-1 )*NB
114:          WORK( 1 ) = LWKOPT
115:       END IF
116: *
117:       IF( INFO.NE.0 ) THEN
118:          CALL XERBLA( 'ZUNGTR', -INFO )
119:          RETURN
120:       ELSE IF( LQUERY ) THEN
121:          RETURN
122:       END IF
123: *
124: *     Quick return if possible
125: *
126:       IF( N.EQ.0 ) THEN
127:          WORK( 1 ) = 1
128:          RETURN
129:       END IF
130: *
131:       IF( UPPER ) THEN
132: *
133: *        Q was determined by a call to ZHETRD with UPLO = 'U'
134: *
135: *        Shift the vectors which define the elementary reflectors one
136: *        column to the left, and set the last row and column of Q to
137: *        those of the unit matrix
138: *
139:          DO 20 J = 1, N - 1
140:             DO 10 I = 1, J - 1
141:                A( I, J ) = A( I, J+1 )
142:    10       CONTINUE
143:             A( N, J ) = ZERO
144:    20    CONTINUE
145:          DO 30 I = 1, N - 1
146:             A( I, N ) = ZERO
147:    30    CONTINUE
148:          A( N, N ) = ONE
149: *
150: *        Generate Q(1:n-1,1:n-1)
151: *
152:          CALL ZUNGQL( N-1, N-1, N-1, A, LDA, TAU, WORK, LWORK, IINFO )
153: *
154:       ELSE
155: *
156: *        Q was determined by a call to ZHETRD with UPLO = 'L'.
157: *
158: *        Shift the vectors which define the elementary reflectors one
159: *        column to the right, and set the first row and column of Q to
160: *        those of the unit matrix
161: *
162:          DO 50 J = N, 2, -1
163:             A( 1, J ) = ZERO
164:             DO 40 I = J + 1, N
165:                A( I, J ) = A( I, J-1 )
166:    40       CONTINUE
167:    50    CONTINUE
168:          A( 1, 1 ) = ONE
169:          DO 60 I = 2, N
170:             A( I, 1 ) = ZERO
171:    60    CONTINUE
172:          IF( N.GT.1 ) THEN
173: *
174: *           Generate Q(2:n,2:n)
175: *
176:             CALL ZUNGQR( N-1, N-1, N-1, A( 2, 2 ), LDA, TAU, WORK,
177:      $                   LWORK, IINFO )
178:          END IF
179:       END IF
180:       WORK( 1 ) = LWKOPT
181:       RETURN
182: *
183: *     End of ZUNGTR
184: *
185:       END
186: