001:       SUBROUTINE ZTREXC( COMPQ, N, T, LDT, Q, LDQ, IFST, ILST, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          COMPQ
010:       INTEGER            IFST, ILST, INFO, LDQ, LDT, N
011: *     ..
012: *     .. Array Arguments ..
013:       COMPLEX*16         Q( LDQ, * ), T( LDT, * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  ZTREXC reorders the Schur factorization of a complex matrix
020: *  A = Q*T*Q**H, so that the diagonal element of T with row index IFST
021: *  is moved to row ILST.
022: *
023: *  The Schur form T is reordered by a unitary similarity transformation
024: *  Z**H*T*Z, and optionally the matrix Q of Schur vectors is updated by
025: *  postmultplying it with Z.
026: *
027: *  Arguments
028: *  =========
029: *
030: *  COMPQ   (input) CHARACTER*1
031: *          = 'V':  update the matrix Q of Schur vectors;
032: *          = 'N':  do not update Q.
033: *
034: *  N       (input) INTEGER
035: *          The order of the matrix T. N >= 0.
036: *
037: *  T       (input/output) COMPLEX*16 array, dimension (LDT,N)
038: *          On entry, the upper triangular matrix T.
039: *          On exit, the reordered upper triangular matrix.
040: *
041: *  LDT     (input) INTEGER
042: *          The leading dimension of the array T. LDT >= max(1,N).
043: *
044: *  Q       (input/output) COMPLEX*16 array, dimension (LDQ,N)
045: *          On entry, if COMPQ = 'V', the matrix Q of Schur vectors.
046: *          On exit, if COMPQ = 'V', Q has been postmultiplied by the
047: *          unitary transformation matrix Z which reorders T.
048: *          If COMPQ = 'N', Q is not referenced.
049: *
050: *  LDQ     (input) INTEGER
051: *          The leading dimension of the array Q.  LDQ >= max(1,N).
052: *
053: *  IFST    (input) INTEGER
054: *  ILST    (input) INTEGER
055: *          Specify the reordering of the diagonal elements of T:
056: *          The element with row index IFST is moved to row ILST by a
057: *          sequence of transpositions between adjacent elements.
058: *          1 <= IFST <= N; 1 <= ILST <= N.
059: *
060: *  INFO    (output) INTEGER
061: *          = 0:  successful exit
062: *          < 0:  if INFO = -i, the i-th argument had an illegal value
063: *
064: *  =====================================================================
065: *
066: *     .. Local Scalars ..
067:       LOGICAL            WANTQ
068:       INTEGER            K, M1, M2, M3
069:       DOUBLE PRECISION   CS
070:       COMPLEX*16         SN, T11, T22, TEMP
071: *     ..
072: *     .. External Functions ..
073:       LOGICAL            LSAME
074:       EXTERNAL           LSAME
075: *     ..
076: *     .. External Subroutines ..
077:       EXTERNAL           XERBLA, ZLARTG, ZROT
078: *     ..
079: *     .. Intrinsic Functions ..
080:       INTRINSIC          DCONJG, MAX
081: *     ..
082: *     .. Executable Statements ..
083: *
084: *     Decode and test the input parameters.
085: *
086:       INFO = 0
087:       WANTQ = LSAME( COMPQ, 'V' )
088:       IF( .NOT.LSAME( COMPQ, 'N' ) .AND. .NOT.WANTQ ) THEN
089:          INFO = -1
090:       ELSE IF( N.LT.0 ) THEN
091:          INFO = -2
092:       ELSE IF( LDT.LT.MAX( 1, N ) ) THEN
093:          INFO = -4
094:       ELSE IF( LDQ.LT.1 .OR. ( WANTQ .AND. LDQ.LT.MAX( 1, N ) ) ) THEN
095:          INFO = -6
096:       ELSE IF( IFST.LT.1 .OR. IFST.GT.N ) THEN
097:          INFO = -7
098:       ELSE IF( ILST.LT.1 .OR. ILST.GT.N ) THEN
099:          INFO = -8
100:       END IF
101:       IF( INFO.NE.0 ) THEN
102:          CALL XERBLA( 'ZTREXC', -INFO )
103:          RETURN
104:       END IF
105: *
106: *     Quick return if possible
107: *
108:       IF( N.EQ.1 .OR. IFST.EQ.ILST )
109:      $   RETURN
110: *
111:       IF( IFST.LT.ILST ) THEN
112: *
113: *        Move the IFST-th diagonal element forward down the diagonal.
114: *
115:          M1 = 0
116:          M2 = -1
117:          M3 = 1
118:       ELSE
119: *
120: *        Move the IFST-th diagonal element backward up the diagonal.
121: *
122:          M1 = -1
123:          M2 = 0
124:          M3 = -1
125:       END IF
126: *
127:       DO 10 K = IFST + M1, ILST + M2, M3
128: *
129: *        Interchange the k-th and (k+1)-th diagonal elements.
130: *
131:          T11 = T( K, K )
132:          T22 = T( K+1, K+1 )
133: *
134: *        Determine the transformation to perform the interchange.
135: *
136:          CALL ZLARTG( T( K, K+1 ), T22-T11, CS, SN, TEMP )
137: *
138: *        Apply transformation to the matrix T.
139: *
140:          IF( K+2.LE.N )
141:      $      CALL ZROT( N-K-1, T( K, K+2 ), LDT, T( K+1, K+2 ), LDT, CS,
142:      $                 SN )
143:          CALL ZROT( K-1, T( 1, K ), 1, T( 1, K+1 ), 1, CS,
144:      $              DCONJG( SN ) )
145: *
146:          T( K, K ) = T22
147:          T( K+1, K+1 ) = T11
148: *
149:          IF( WANTQ ) THEN
150: *
151: *           Accumulate transformation in the matrix Q.
152: *
153:             CALL ZROT( N, Q( 1, K ), 1, Q( 1, K+1 ), 1, CS,
154:      $                 DCONJG( SN ) )
155:          END IF
156: *
157:    10 CONTINUE
158: *
159:       RETURN
160: *
161: *     End of ZTREXC
162: *
163:       END
164: