001:       SUBROUTINE ZLAQHP( UPLO, N, AP, S, SCOND, AMAX, EQUED )
002: *
003: *  -- LAPACK auxiliary routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          EQUED, UPLO
010:       INTEGER            N
011:       DOUBLE PRECISION   AMAX, SCOND
012: *     ..
013: *     .. Array Arguments ..
014:       DOUBLE PRECISION   S( * )
015:       COMPLEX*16         AP( * )
016: *     ..
017: *
018: *  Purpose
019: *  =======
020: *
021: *  ZLAQHP equilibrates a Hermitian matrix A using the scaling factors
022: *  in the vector S.
023: *
024: *  Arguments
025: *  =========
026: *
027: *  UPLO    (input) CHARACTER*1
028: *          Specifies whether the upper or lower triangular part of the
029: *          Hermitian matrix A is stored.
030: *          = 'U':  Upper triangular
031: *          = 'L':  Lower triangular
032: *
033: *  N       (input) INTEGER
034: *          The order of the matrix A.  N >= 0.
035: *
036: *  AP      (input/output) COMPLEX*16 array, dimension (N*(N+1)/2)
037: *          On entry, the upper or lower triangle of the Hermitian matrix
038: *          A, packed columnwise in a linear array.  The j-th column of A
039: *          is stored in the array AP as follows:
040: *          if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
041: *          if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n.
042: *
043: *          On exit, the equilibrated matrix:  diag(S) * A * diag(S), in
044: *          the same storage format as A.
045: *
046: *  S       (input) DOUBLE PRECISION array, dimension (N)
047: *          The scale factors for A.
048: *
049: *  SCOND   (input) DOUBLE PRECISION
050: *          Ratio of the smallest S(i) to the largest S(i).
051: *
052: *  AMAX    (input) DOUBLE PRECISION
053: *          Absolute value of largest matrix entry.
054: *
055: *  EQUED   (output) CHARACTER*1
056: *          Specifies whether or not equilibration was done.
057: *          = 'N':  No equilibration.
058: *          = 'Y':  Equilibration was done, i.e., A has been replaced by
059: *                  diag(S) * A * diag(S).
060: *
061: *  Internal Parameters
062: *  ===================
063: *
064: *  THRESH is a threshold value used to decide if scaling should be done
065: *  based on the ratio of the scaling factors.  If SCOND < THRESH,
066: *  scaling is done.
067: *
068: *  LARGE and SMALL are threshold values used to decide if scaling should
069: *  be done based on the absolute size of the largest matrix element.
070: *  If AMAX > LARGE or AMAX < SMALL, scaling is done.
071: *
072: *  =====================================================================
073: *
074: *     .. Parameters ..
075:       DOUBLE PRECISION   ONE, THRESH
076:       PARAMETER          ( ONE = 1.0D+0, THRESH = 0.1D+0 )
077: *     ..
078: *     .. Local Scalars ..
079:       INTEGER            I, J, JC
080:       DOUBLE PRECISION   CJ, LARGE, SMALL
081: *     ..
082: *     .. External Functions ..
083:       LOGICAL            LSAME
084:       DOUBLE PRECISION   DLAMCH
085:       EXTERNAL           LSAME, DLAMCH
086: *     ..
087: *     .. Intrinsic Functions ..
088:       INTRINSIC          DBLE
089: *     ..
090: *     .. Executable Statements ..
091: *
092: *     Quick return if possible
093: *
094:       IF( N.LE.0 ) THEN
095:          EQUED = 'N'
096:          RETURN
097:       END IF
098: *
099: *     Initialize LARGE and SMALL.
100: *
101:       SMALL = DLAMCH( 'Safe minimum' ) / DLAMCH( 'Precision' )
102:       LARGE = ONE / SMALL
103: *
104:       IF( SCOND.GE.THRESH .AND. AMAX.GE.SMALL .AND. AMAX.LE.LARGE ) THEN
105: *
106: *        No equilibration
107: *
108:          EQUED = 'N'
109:       ELSE
110: *
111: *        Replace A by diag(S) * A * diag(S).
112: *
113:          IF( LSAME( UPLO, 'U' ) ) THEN
114: *
115: *           Upper triangle of A is stored.
116: *
117:             JC = 1
118:             DO 20 J = 1, N
119:                CJ = S( J )
120:                DO 10 I = 1, J - 1
121:                   AP( JC+I-1 ) = CJ*S( I )*AP( JC+I-1 )
122:    10          CONTINUE
123:                AP( JC+J-1 ) = CJ*CJ*DBLE( AP( JC+J-1 ) )
124:                JC = JC + J
125:    20       CONTINUE
126:          ELSE
127: *
128: *           Lower triangle of A is stored.
129: *
130:             JC = 1
131:             DO 40 J = 1, N
132:                CJ = S( J )
133:                AP( JC ) = CJ*CJ*DBLE( AP( JC ) )
134:                DO 30 I = J + 1, N
135:                   AP( JC+I-J ) = CJ*S( I )*AP( JC+I-J )
136:    30          CONTINUE
137:                JC = JC + N - J + 1
138:    40       CONTINUE
139:          END IF
140:          EQUED = 'Y'
141:       END IF
142: *
143:       RETURN
144: *
145: *     End of ZLAQHP
146: *
147:       END
148: