001:       SUBROUTINE SSYEV( JOBZ, UPLO, N, A, LDA, W, WORK, LWORK, INFO )
002: *
003: *  -- LAPACK driver routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          JOBZ, UPLO
010:       INTEGER            INFO, LDA, LWORK, N
011: *     ..
012: *     .. Array Arguments ..
013:       REAL               A( LDA, * ), W( * ), WORK( * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  SSYEV computes all eigenvalues and, optionally, eigenvectors of a
020: *  real symmetric matrix A.
021: *
022: *  Arguments
023: *  =========
024: *
025: *  JOBZ    (input) CHARACTER*1
026: *          = 'N':  Compute eigenvalues only;
027: *          = 'V':  Compute eigenvalues and eigenvectors.
028: *
029: *  UPLO    (input) CHARACTER*1
030: *          = 'U':  Upper triangle of A is stored;
031: *          = 'L':  Lower triangle of A is stored.
032: *
033: *  N       (input) INTEGER
034: *          The order of the matrix A.  N >= 0.
035: *
036: *  A       (input/output) REAL array, dimension (LDA, N)
037: *          On entry, the symmetric matrix A.  If UPLO = 'U', the
038: *          leading N-by-N upper triangular part of A contains the
039: *          upper triangular part of the matrix A.  If UPLO = 'L',
040: *          the leading N-by-N lower triangular part of A contains
041: *          the lower triangular part of the matrix A.
042: *          On exit, if JOBZ = 'V', then if INFO = 0, A contains the
043: *          orthonormal eigenvectors of the matrix A.
044: *          If JOBZ = 'N', then on exit the lower triangle (if UPLO='L')
045: *          or the upper triangle (if UPLO='U') of A, including the
046: *          diagonal, is destroyed.
047: *
048: *  LDA     (input) INTEGER
049: *          The leading dimension of the array A.  LDA >= max(1,N).
050: *
051: *  W       (output) REAL array, dimension (N)
052: *          If INFO = 0, the eigenvalues in ascending order.
053: *
054: *  WORK    (workspace/output) REAL array, dimension (MAX(1,LWORK))
055: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
056: *
057: *  LWORK   (input) INTEGER
058: *          The length of the array WORK.  LWORK >= max(1,3*N-1).
059: *          For optimal efficiency, LWORK >= (NB+2)*N,
060: *          where NB is the blocksize for SSYTRD returned by ILAENV.
061: *
062: *          If LWORK = -1, then a workspace query is assumed; the routine
063: *          only calculates the optimal size of the WORK array, returns
064: *          this value as the first entry of the WORK array, and no error
065: *          message related to LWORK is issued by XERBLA.
066: *
067: *  INFO    (output) INTEGER
068: *          = 0:  successful exit
069: *          < 0:  if INFO = -i, the i-th argument had an illegal value
070: *          > 0:  if INFO = i, the algorithm failed to converge; i
071: *                off-diagonal elements of an intermediate tridiagonal
072: *                form did not converge to zero.
073: *
074: *  =====================================================================
075: *
076: *     .. Parameters ..
077:       REAL               ZERO, ONE
078:       PARAMETER          ( ZERO = 0.0E0, ONE = 1.0E0 )
079: *     ..
080: *     .. Local Scalars ..
081:       LOGICAL            LOWER, LQUERY, WANTZ
082:       INTEGER            IINFO, IMAX, INDE, INDTAU, INDWRK, ISCALE,
083:      $                   LLWORK, LWKOPT, NB
084:       REAL               ANRM, BIGNUM, EPS, RMAX, RMIN, SAFMIN, SIGMA,
085:      $                   SMLNUM
086: *     ..
087: *     .. External Functions ..
088:       LOGICAL            LSAME
089:       INTEGER            ILAENV
090:       REAL               SLAMCH, SLANSY
091:       EXTERNAL           ILAENV, LSAME, SLAMCH, SLANSY
092: *     ..
093: *     .. External Subroutines ..
094:       EXTERNAL           SLASCL, SORGTR, SSCAL, SSTEQR, SSTERF, SSYTRD,
095:      $                   XERBLA
096: *     ..
097: *     .. Intrinsic Functions ..
098:       INTRINSIC          MAX, SQRT
099: *     ..
100: *     .. Executable Statements ..
101: *
102: *     Test the input parameters.
103: *
104:       WANTZ = LSAME( JOBZ, 'V' )
105:       LOWER = LSAME( UPLO, 'L' )
106:       LQUERY = ( LWORK.EQ.-1 )
107: *
108:       INFO = 0
109:       IF( .NOT.( WANTZ .OR. LSAME( JOBZ, 'N' ) ) ) THEN
110:          INFO = -1
111:       ELSE IF( .NOT.( LOWER .OR. LSAME( UPLO, 'U' ) ) ) THEN
112:          INFO = -2
113:       ELSE IF( N.LT.0 ) THEN
114:          INFO = -3
115:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
116:          INFO = -5
117:       END IF
118: *
119:       IF( INFO.EQ.0 ) THEN
120:          NB = ILAENV( 1, 'SSYTRD', UPLO, N, -1, -1, -1 )
121:          LWKOPT = MAX( 1, ( NB+2 )*N )
122:          WORK( 1 ) = LWKOPT
123: *
124:          IF( LWORK.LT.MAX( 1, 3*N-1 ) .AND. .NOT.LQUERY )
125:      $      INFO = -8
126:       END IF
127: *
128:       IF( INFO.NE.0 ) THEN
129:          CALL XERBLA( 'SSYEV ', -INFO )
130:          RETURN
131:       ELSE IF( LQUERY ) THEN
132:          RETURN
133:       END IF
134: *
135: *     Quick return if possible
136: *
137:       IF( N.EQ.0 ) THEN
138:          RETURN
139:       END IF
140: *
141:       IF( N.EQ.1 ) THEN
142:          W( 1 ) = A( 1, 1 )
143:          WORK( 1 ) = 2
144:          IF( WANTZ )
145:      $      A( 1, 1 ) = ONE
146:          RETURN
147:       END IF
148: *
149: *     Get machine constants.
150: *
151:       SAFMIN = SLAMCH( 'Safe minimum' )
152:       EPS = SLAMCH( 'Precision' )
153:       SMLNUM = SAFMIN / EPS
154:       BIGNUM = ONE / SMLNUM
155:       RMIN = SQRT( SMLNUM )
156:       RMAX = SQRT( BIGNUM )
157: *
158: *     Scale matrix to allowable range, if necessary.
159: *
160:       ANRM = SLANSY( 'M', UPLO, N, A, LDA, WORK )
161:       ISCALE = 0
162:       IF( ANRM.GT.ZERO .AND. ANRM.LT.RMIN ) THEN
163:          ISCALE = 1
164:          SIGMA = RMIN / ANRM
165:       ELSE IF( ANRM.GT.RMAX ) THEN
166:          ISCALE = 1
167:          SIGMA = RMAX / ANRM
168:       END IF
169:       IF( ISCALE.EQ.1 )
170:      $   CALL SLASCL( UPLO, 0, 0, ONE, SIGMA, N, N, A, LDA, INFO )
171: *
172: *     Call SSYTRD to reduce symmetric matrix to tridiagonal form.
173: *
174:       INDE = 1
175:       INDTAU = INDE + N
176:       INDWRK = INDTAU + N
177:       LLWORK = LWORK - INDWRK + 1
178:       CALL SSYTRD( UPLO, N, A, LDA, W, WORK( INDE ), WORK( INDTAU ),
179:      $             WORK( INDWRK ), LLWORK, IINFO )
180: *
181: *     For eigenvalues only, call SSTERF.  For eigenvectors, first call
182: *     SORGTR to generate the orthogonal matrix, then call SSTEQR.
183: *
184:       IF( .NOT.WANTZ ) THEN
185:          CALL SSTERF( N, W, WORK( INDE ), INFO )
186:       ELSE
187:          CALL SORGTR( UPLO, N, A, LDA, WORK( INDTAU ), WORK( INDWRK ),
188:      $                LLWORK, IINFO )
189:          CALL SSTEQR( JOBZ, N, W, WORK( INDE ), A, LDA, WORK( INDTAU ),
190:      $                INFO )
191:       END IF
192: *
193: *     If matrix was scaled, then rescale eigenvalues appropriately.
194: *
195:       IF( ISCALE.EQ.1 ) THEN
196:          IF( INFO.EQ.0 ) THEN
197:             IMAX = N
198:          ELSE
199:             IMAX = INFO - 1
200:          END IF
201:          CALL SSCAL( IMAX, ONE / SIGMA, W, 1 )
202:       END IF
203: *
204: *     Set WORK(1) to optimal workspace size.
205: *
206:       WORK( 1 ) = LWKOPT
207: *
208:       RETURN
209: *
210: *     End of SSYEV
211: *
212:       END
213: