001:       SUBROUTINE SORMRQ( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
002:      $                   WORK, LWORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
006: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
007: *     November 2006
008: *
009: *     .. Scalar Arguments ..
010:       CHARACTER          SIDE, TRANS
011:       INTEGER            INFO, K, LDA, LDC, LWORK, M, N
012: *     ..
013: *     .. Array Arguments ..
014:       REAL               A( LDA, * ), C( LDC, * ), TAU( * ),
015:      $                   WORK( * )
016: *     ..
017: *
018: *  Purpose
019: *  =======
020: *
021: *  SORMRQ overwrites the general real M-by-N matrix C with
022: *
023: *                  SIDE = 'L'     SIDE = 'R'
024: *  TRANS = 'N':      Q * C          C * Q
025: *  TRANS = 'T':      Q**T * C       C * Q**T
026: *
027: *  where Q is a real orthogonal matrix defined as the product of k
028: *  elementary reflectors
029: *
030: *        Q = H(1) H(2) . . . H(k)
031: *
032: *  as returned by SGERQF. Q is of order M if SIDE = 'L' and of order N
033: *  if SIDE = 'R'.
034: *
035: *  Arguments
036: *  =========
037: *
038: *  SIDE    (input) CHARACTER*1
039: *          = 'L': apply Q or Q**T from the Left;
040: *          = 'R': apply Q or Q**T from the Right.
041: *
042: *  TRANS   (input) CHARACTER*1
043: *          = 'N':  No transpose, apply Q;
044: *          = 'T':  Transpose, apply Q**T.
045: *
046: *  M       (input) INTEGER
047: *          The number of rows of the matrix C. M >= 0.
048: *
049: *  N       (input) INTEGER
050: *          The number of columns of the matrix C. N >= 0.
051: *
052: *  K       (input) INTEGER
053: *          The number of elementary reflectors whose product defines
054: *          the matrix Q.
055: *          If SIDE = 'L', M >= K >= 0;
056: *          if SIDE = 'R', N >= K >= 0.
057: *
058: *  A       (input) REAL array, dimension
059: *                               (LDA,M) if SIDE = 'L',
060: *                               (LDA,N) if SIDE = 'R'
061: *          The i-th row must contain the vector which defines the
062: *          elementary reflector H(i), for i = 1,2,...,k, as returned by
063: *          SGERQF in the last k rows of its array argument A.
064: *          A is modified by the routine but restored on exit.
065: *
066: *  LDA     (input) INTEGER
067: *          The leading dimension of the array A. LDA >= max(1,K).
068: *
069: *  TAU     (input) REAL array, dimension (K)
070: *          TAU(i) must contain the scalar factor of the elementary
071: *          reflector H(i), as returned by SGERQF.
072: *
073: *  C       (input/output) REAL array, dimension (LDC,N)
074: *          On entry, the M-by-N matrix C.
075: *          On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q.
076: *
077: *  LDC     (input) INTEGER
078: *          The leading dimension of the array C. LDC >= max(1,M).
079: *
080: *  WORK    (workspace/output) REAL array, dimension (MAX(1,LWORK))
081: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
082: *
083: *  LWORK   (input) INTEGER
084: *          The dimension of the array WORK.
085: *          If SIDE = 'L', LWORK >= max(1,N);
086: *          if SIDE = 'R', LWORK >= max(1,M).
087: *          For optimum performance LWORK >= N*NB if SIDE = 'L', and
088: *          LWORK >= M*NB if SIDE = 'R', where NB is the optimal
089: *          blocksize.
090: *
091: *          If LWORK = -1, then a workspace query is assumed; the routine
092: *          only calculates the optimal size of the WORK array, returns
093: *          this value as the first entry of the WORK array, and no error
094: *          message related to LWORK is issued by XERBLA.
095: *
096: *  INFO    (output) INTEGER
097: *          = 0:  successful exit
098: *          < 0:  if INFO = -i, the i-th argument had an illegal value
099: *
100: *  =====================================================================
101: *
102: *     .. Parameters ..
103:       INTEGER            NBMAX, LDT
104:       PARAMETER          ( NBMAX = 64, LDT = NBMAX+1 )
105: *     ..
106: *     .. Local Scalars ..
107:       LOGICAL            LEFT, LQUERY, NOTRAN
108:       CHARACTER          TRANST
109:       INTEGER            I, I1, I2, I3, IB, IINFO, IWS, LDWORK, LWKOPT,
110:      $                   MI, NB, NBMIN, NI, NQ, NW
111: *     ..
112: *     .. Local Arrays ..
113:       REAL               T( LDT, NBMAX )
114: *     ..
115: *     .. External Functions ..
116:       LOGICAL            LSAME
117:       INTEGER            ILAENV
118:       EXTERNAL           LSAME, ILAENV
119: *     ..
120: *     .. External Subroutines ..
121:       EXTERNAL           SLARFB, SLARFT, SORMR2, XERBLA
122: *     ..
123: *     .. Intrinsic Functions ..
124:       INTRINSIC          MAX, MIN
125: *     ..
126: *     .. Executable Statements ..
127: *
128: *     Test the input arguments
129: *
130:       INFO = 0
131:       LEFT = LSAME( SIDE, 'L' )
132:       NOTRAN = LSAME( TRANS, 'N' )
133:       LQUERY = ( LWORK.EQ.-1 )
134: *
135: *     NQ is the order of Q and NW is the minimum dimension of WORK
136: *
137:       IF( LEFT ) THEN
138:          NQ = M
139:          NW = MAX( 1, N )
140:       ELSE
141:          NQ = N
142:          NW = MAX( 1, M )
143:       END IF
144:       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
145:          INFO = -1
146:       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) ) THEN
147:          INFO = -2
148:       ELSE IF( M.LT.0 ) THEN
149:          INFO = -3
150:       ELSE IF( N.LT.0 ) THEN
151:          INFO = -4
152:       ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
153:          INFO = -5
154:       ELSE IF( LDA.LT.MAX( 1, K ) ) THEN
155:          INFO = -7
156:       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
157:          INFO = -10
158:       END IF
159: *
160:       IF( INFO.EQ.0 ) THEN
161:          IF( M.EQ.0 .OR. N.EQ.0 ) THEN
162:             LWKOPT = 1
163:          ELSE
164: *
165: *           Determine the block size.  NB may be at most NBMAX, where
166: *           NBMAX is used to define the local array T.
167: *
168:             NB = MIN( NBMAX, ILAENV( 1, 'SORMRQ', SIDE // TRANS, M, N,
169:      $                               K, -1 ) )
170:             LWKOPT = NW*NB
171:          END IF
172:          WORK( 1 ) = LWKOPT
173: *
174:          IF( LWORK.LT.NW .AND. .NOT.LQUERY ) THEN
175:             INFO = -12
176:          END IF
177:       END IF
178: *
179:       IF( INFO.NE.0 ) THEN
180:          CALL XERBLA( 'SORMRQ', -INFO )
181:          RETURN
182:       ELSE IF( LQUERY ) THEN
183:          RETURN
184:       END IF
185: *
186: *     Quick return if possible
187: *
188:       IF( M.EQ.0 .OR. N.EQ.0 ) THEN
189:          RETURN
190:       END IF
191: *
192:       NBMIN = 2
193:       LDWORK = NW
194:       IF( NB.GT.1 .AND. NB.LT.K ) THEN
195:          IWS = NW*NB
196:          IF( LWORK.LT.IWS ) THEN
197:             NB = LWORK / LDWORK
198:             NBMIN = MAX( 2, ILAENV( 2, 'SORMRQ', SIDE // TRANS, M, N, K,
199:      $              -1 ) )
200:          END IF
201:       ELSE
202:          IWS = NW
203:       END IF
204: *
205:       IF( NB.LT.NBMIN .OR. NB.GE.K ) THEN
206: *
207: *        Use unblocked code
208: *
209:          CALL SORMR2( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK,
210:      $                IINFO )
211:       ELSE
212: *
213: *        Use blocked code
214: *
215:          IF( ( LEFT .AND. .NOT.NOTRAN ) .OR.
216:      $       ( .NOT.LEFT .AND. NOTRAN ) ) THEN
217:             I1 = 1
218:             I2 = K
219:             I3 = NB
220:          ELSE
221:             I1 = ( ( K-1 ) / NB )*NB + 1
222:             I2 = 1
223:             I3 = -NB
224:          END IF
225: *
226:          IF( LEFT ) THEN
227:             NI = N
228:          ELSE
229:             MI = M
230:          END IF
231: *
232:          IF( NOTRAN ) THEN
233:             TRANST = 'T'
234:          ELSE
235:             TRANST = 'N'
236:          END IF
237: *
238:          DO 10 I = I1, I2, I3
239:             IB = MIN( NB, K-I+1 )
240: *
241: *           Form the triangular factor of the block reflector
242: *           H = H(i+ib-1) . . . H(i+1) H(i)
243: *
244:             CALL SLARFT( 'Backward', 'Rowwise', NQ-K+I+IB-1, IB,
245:      $                   A( I, 1 ), LDA, TAU( I ), T, LDT )
246:             IF( LEFT ) THEN
247: *
248: *              H or H' is applied to C(1:m-k+i+ib-1,1:n)
249: *
250:                MI = M - K + I + IB - 1
251:             ELSE
252: *
253: *              H or H' is applied to C(1:m,1:n-k+i+ib-1)
254: *
255:                NI = N - K + I + IB - 1
256:             END IF
257: *
258: *           Apply H or H'
259: *
260:             CALL SLARFB( SIDE, TRANST, 'Backward', 'Rowwise', MI, NI,
261:      $                   IB, A( I, 1 ), LDA, T, LDT, C, LDC, WORK,
262:      $                   LDWORK )
263:    10    CONTINUE
264:       END IF
265:       WORK( 1 ) = LWKOPT
266:       RETURN
267: *
268: *     End of SORMRQ
269: *
270:       END
271: