001:       SUBROUTINE SOPGTR( UPLO, N, AP, TAU, Q, LDQ, WORK, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          UPLO
010:       INTEGER            INFO, LDQ, N
011: *     ..
012: *     .. Array Arguments ..
013:       REAL               AP( * ), Q( LDQ, * ), TAU( * ), WORK( * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  SOPGTR generates a real orthogonal matrix Q which is defined as the
020: *  product of n-1 elementary reflectors H(i) of order n, as returned by
021: *  SSPTRD using packed storage:
022: *
023: *  if UPLO = 'U', Q = H(n-1) . . . H(2) H(1),
024: *
025: *  if UPLO = 'L', Q = H(1) H(2) . . . H(n-1).
026: *
027: *  Arguments
028: *  =========
029: *
030: *  UPLO    (input) CHARACTER*1
031: *          = 'U': Upper triangular packed storage used in previous
032: *                 call to SSPTRD;
033: *          = 'L': Lower triangular packed storage used in previous
034: *                 call to SSPTRD.
035: *
036: *  N       (input) INTEGER
037: *          The order of the matrix Q. N >= 0.
038: *
039: *  AP      (input) REAL array, dimension (N*(N+1)/2)
040: *          The vectors which define the elementary reflectors, as
041: *          returned by SSPTRD.
042: *
043: *  TAU     (input) REAL array, dimension (N-1)
044: *          TAU(i) must contain the scalar factor of the elementary
045: *          reflector H(i), as returned by SSPTRD.
046: *
047: *  Q       (output) REAL array, dimension (LDQ,N)
048: *          The N-by-N orthogonal matrix Q.
049: *
050: *  LDQ     (input) INTEGER
051: *          The leading dimension of the array Q. LDQ >= max(1,N).
052: *
053: *  WORK    (workspace) REAL array, dimension (N-1)
054: *
055: *  INFO    (output) INTEGER
056: *          = 0:  successful exit
057: *          < 0:  if INFO = -i, the i-th argument had an illegal value
058: *
059: *  =====================================================================
060: *
061: *     .. Parameters ..
062:       REAL               ZERO, ONE
063:       PARAMETER          ( ZERO = 0.0E+0, ONE = 1.0E+0 )
064: *     ..
065: *     .. Local Scalars ..
066:       LOGICAL            UPPER
067:       INTEGER            I, IINFO, IJ, J
068: *     ..
069: *     .. External Functions ..
070:       LOGICAL            LSAME
071:       EXTERNAL           LSAME
072: *     ..
073: *     .. External Subroutines ..
074:       EXTERNAL           SORG2L, SORG2R, XERBLA
075: *     ..
076: *     .. Intrinsic Functions ..
077:       INTRINSIC          MAX
078: *     ..
079: *     .. Executable Statements ..
080: *
081: *     Test the input arguments
082: *
083:       INFO = 0
084:       UPPER = LSAME( UPLO, 'U' )
085:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
086:          INFO = -1
087:       ELSE IF( N.LT.0 ) THEN
088:          INFO = -2
089:       ELSE IF( LDQ.LT.MAX( 1, N ) ) THEN
090:          INFO = -6
091:       END IF
092:       IF( INFO.NE.0 ) THEN
093:          CALL XERBLA( 'SOPGTR', -INFO )
094:          RETURN
095:       END IF
096: *
097: *     Quick return if possible
098: *
099:       IF( N.EQ.0 )
100:      $   RETURN
101: *
102:       IF( UPPER ) THEN
103: *
104: *        Q was determined by a call to SSPTRD with UPLO = 'U'
105: *
106: *        Unpack the vectors which define the elementary reflectors and
107: *        set the last row and column of Q equal to those of the unit
108: *        matrix
109: *
110:          IJ = 2
111:          DO 20 J = 1, N - 1
112:             DO 10 I = 1, J - 1
113:                Q( I, J ) = AP( IJ )
114:                IJ = IJ + 1
115:    10       CONTINUE
116:             IJ = IJ + 2
117:             Q( N, J ) = ZERO
118:    20    CONTINUE
119:          DO 30 I = 1, N - 1
120:             Q( I, N ) = ZERO
121:    30    CONTINUE
122:          Q( N, N ) = ONE
123: *
124: *        Generate Q(1:n-1,1:n-1)
125: *
126:          CALL SORG2L( N-1, N-1, N-1, Q, LDQ, TAU, WORK, IINFO )
127: *
128:       ELSE
129: *
130: *        Q was determined by a call to SSPTRD with UPLO = 'L'.
131: *
132: *        Unpack the vectors which define the elementary reflectors and
133: *        set the first row and column of Q equal to those of the unit
134: *        matrix
135: *
136:          Q( 1, 1 ) = ONE
137:          DO 40 I = 2, N
138:             Q( I, 1 ) = ZERO
139:    40    CONTINUE
140:          IJ = 3
141:          DO 60 J = 2, N
142:             Q( 1, J ) = ZERO
143:             DO 50 I = J + 1, N
144:                Q( I, J ) = AP( IJ )
145:                IJ = IJ + 1
146:    50       CONTINUE
147:             IJ = IJ + 2
148:    60    CONTINUE
149:          IF( N.GT.1 ) THEN
150: *
151: *           Generate Q(2:n,2:n)
152: *
153:             CALL SORG2R( N-1, N-1, N-1, Q( 2, 2 ), LDQ, TAU, WORK,
154:      $                   IINFO )
155:          END IF
156:       END IF
157:       RETURN
158: *
159: *     End of SOPGTR
160: *
161:       END
162: