001:       REAL             FUNCTION SLANSP( NORM, UPLO, N, AP, WORK )
002: *
003: *  -- LAPACK auxiliary routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          NORM, UPLO
010:       INTEGER            N
011: *     ..
012: *     .. Array Arguments ..
013:       REAL               AP( * ), WORK( * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  SLANSP  returns the value of the one norm,  or the Frobenius norm, or
020: *  the  infinity norm,  or the  element of  largest absolute value  of a
021: *  real symmetric matrix A,  supplied in packed form.
022: *
023: *  Description
024: *  ===========
025: *
026: *  SLANSP returns the value
027: *
028: *     SLANSP = ( max(abs(A(i,j))), NORM = 'M' or 'm'
029: *              (
030: *              ( norm1(A),         NORM = '1', 'O' or 'o'
031: *              (
032: *              ( normI(A),         NORM = 'I' or 'i'
033: *              (
034: *              ( normF(A),         NORM = 'F', 'f', 'E' or 'e'
035: *
036: *  where  norm1  denotes the  one norm of a matrix (maximum column sum),
037: *  normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
038: *  normF  denotes the  Frobenius norm of a matrix (square root of sum of
039: *  squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
040: *
041: *  Arguments
042: *  =========
043: *
044: *  NORM    (input) CHARACTER*1
045: *          Specifies the value to be returned in SLANSP as described
046: *          above.
047: *
048: *  UPLO    (input) CHARACTER*1
049: *          Specifies whether the upper or lower triangular part of the
050: *          symmetric matrix A is supplied.
051: *          = 'U':  Upper triangular part of A is supplied
052: *          = 'L':  Lower triangular part of A is supplied
053: *
054: *  N       (input) INTEGER
055: *          The order of the matrix A.  N >= 0.  When N = 0, SLANSP is
056: *          set to zero.
057: *
058: *  AP      (input) REAL array, dimension (N*(N+1)/2)
059: *          The upper or lower triangle of the symmetric matrix A, packed
060: *          columnwise in a linear array.  The j-th column of A is stored
061: *          in the array AP as follows:
062: *          if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
063: *          if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n.
064: *
065: *  WORK    (workspace) REAL array, dimension (MAX(1,LWORK)),
066: *          where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
067: *          WORK is not referenced.
068: *
069: * =====================================================================
070: *
071: *     .. Parameters ..
072:       REAL               ONE, ZERO
073:       PARAMETER          ( ONE = 1.0E+0, ZERO = 0.0E+0 )
074: *     ..
075: *     .. Local Scalars ..
076:       INTEGER            I, J, K
077:       REAL               ABSA, SCALE, SUM, VALUE
078: *     ..
079: *     .. External Subroutines ..
080:       EXTERNAL           SLASSQ
081: *     ..
082: *     .. External Functions ..
083:       LOGICAL            LSAME
084:       EXTERNAL           LSAME
085: *     ..
086: *     .. Intrinsic Functions ..
087:       INTRINSIC          ABS, MAX, SQRT
088: *     ..
089: *     .. Executable Statements ..
090: *
091:       IF( N.EQ.0 ) THEN
092:          VALUE = ZERO
093:       ELSE IF( LSAME( NORM, 'M' ) ) THEN
094: *
095: *        Find max(abs(A(i,j))).
096: *
097:          VALUE = ZERO
098:          IF( LSAME( UPLO, 'U' ) ) THEN
099:             K = 1
100:             DO 20 J = 1, N
101:                DO 10 I = K, K + J - 1
102:                   VALUE = MAX( VALUE, ABS( AP( I ) ) )
103:    10          CONTINUE
104:                K = K + J
105:    20       CONTINUE
106:          ELSE
107:             K = 1
108:             DO 40 J = 1, N
109:                DO 30 I = K, K + N - J
110:                   VALUE = MAX( VALUE, ABS( AP( I ) ) )
111:    30          CONTINUE
112:                K = K + N - J + 1
113:    40       CONTINUE
114:          END IF
115:       ELSE IF( ( LSAME( NORM, 'I' ) ) .OR. ( LSAME( NORM, 'O' ) ) .OR.
116:      $         ( NORM.EQ.'1' ) ) THEN
117: *
118: *        Find normI(A) ( = norm1(A), since A is symmetric).
119: *
120:          VALUE = ZERO
121:          K = 1
122:          IF( LSAME( UPLO, 'U' ) ) THEN
123:             DO 60 J = 1, N
124:                SUM = ZERO
125:                DO 50 I = 1, J - 1
126:                   ABSA = ABS( AP( K ) )
127:                   SUM = SUM + ABSA
128:                   WORK( I ) = WORK( I ) + ABSA
129:                   K = K + 1
130:    50          CONTINUE
131:                WORK( J ) = SUM + ABS( AP( K ) )
132:                K = K + 1
133:    60       CONTINUE
134:             DO 70 I = 1, N
135:                VALUE = MAX( VALUE, WORK( I ) )
136:    70       CONTINUE
137:          ELSE
138:             DO 80 I = 1, N
139:                WORK( I ) = ZERO
140:    80       CONTINUE
141:             DO 100 J = 1, N
142:                SUM = WORK( J ) + ABS( AP( K ) )
143:                K = K + 1
144:                DO 90 I = J + 1, N
145:                   ABSA = ABS( AP( K ) )
146:                   SUM = SUM + ABSA
147:                   WORK( I ) = WORK( I ) + ABSA
148:                   K = K + 1
149:    90          CONTINUE
150:                VALUE = MAX( VALUE, SUM )
151:   100       CONTINUE
152:          END IF
153:       ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
154: *
155: *        Find normF(A).
156: *
157:          SCALE = ZERO
158:          SUM = ONE
159:          K = 2
160:          IF( LSAME( UPLO, 'U' ) ) THEN
161:             DO 110 J = 2, N
162:                CALL SLASSQ( J-1, AP( K ), 1, SCALE, SUM )
163:                K = K + J
164:   110       CONTINUE
165:          ELSE
166:             DO 120 J = 1, N - 1
167:                CALL SLASSQ( N-J, AP( K ), 1, SCALE, SUM )
168:                K = K + N - J + 1
169:   120       CONTINUE
170:          END IF
171:          SUM = 2*SUM
172:          K = 1
173:          DO 130 I = 1, N
174:             IF( AP( K ).NE.ZERO ) THEN
175:                ABSA = ABS( AP( K ) )
176:                IF( SCALE.LT.ABSA ) THEN
177:                   SUM = ONE + SUM*( SCALE / ABSA )**2
178:                   SCALE = ABSA
179:                ELSE
180:                   SUM = SUM + ( ABSA / SCALE )**2
181:                END IF
182:             END IF
183:             IF( LSAME( UPLO, 'U' ) ) THEN
184:                K = K + I + 1
185:             ELSE
186:                K = K + N - I + 1
187:             END IF
188:   130    CONTINUE
189:          VALUE = SCALE*SQRT( SUM )
190:       END IF
191: *
192:       SLANSP = VALUE
193:       RETURN
194: *
195: *     End of SLANSP
196: *
197:       END
198: