001:       REAL FUNCTION SLA_GBRCOND( TRANS, N, KL, KU, AB, LDAB, AFB, LDAFB,
002:      $                           IPIV, CMODE, C, INFO, WORK, IWORK )
003: *
004: *     -- LAPACK routine (version 3.2.1)                               --
005: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
006: *     -- Jason Riedy of Univ. of California Berkeley.                 --
007: *     -- April 2009                                                   --
008: *
009: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
010: *     -- Univ. of California Berkeley and NAG Ltd.                    --
011: *
012:       IMPLICIT NONE
013: *     ..
014: *     .. Scalar Arguments ..
015:       CHARACTER          TRANS
016:       INTEGER            N, LDAB, LDAFB, INFO, KL, KU, CMODE
017: *     ..
018: *     .. Array Arguments ..
019:       INTEGER            IWORK( * ), IPIV( * )
020:       REAL               AB( LDAB, * ), AFB( LDAFB, * ), WORK( * ),
021:      $                   C( * )
022: *    ..
023: *
024: *  Purpose
025: *  =======
026: *
027: *     SLA_GERCOND Estimates the Skeel condition number of  op(A) * op2(C)
028: *     where op2 is determined by CMODE as follows
029: *     CMODE =  1    op2(C) = C
030: *     CMODE =  0    op2(C) = I
031: *     CMODE = -1    op2(C) = inv(C)
032: *     The Skeel condition number  cond(A) = norminf( |inv(A)||A| )
033: *     is computed by computing scaling factors R such that
034: *     diag(R)*A*op2(C) is row equilibrated and computing the standard
035: *     infinity-norm condition number.
036: *
037: *  Arguments
038: *  ==========
039: *
040: *     TRANS   (input) CHARACTER*1
041: *     Specifies the form of the system of equations:
042: *       = 'N':  A * X = B     (No transpose)
043: *       = 'T':  A**T * X = B  (Transpose)
044: *       = 'C':  A**H * X = B  (Conjugate Transpose = Transpose)
045: *
046: *     N       (input) INTEGER
047: *     The number of linear equations, i.e., the order of the
048: *     matrix A.  N >= 0.
049: *
050: *     KL      (input) INTEGER
051: *     The number of subdiagonals within the band of A.  KL >= 0.
052: *
053: *     KU      (input) INTEGER
054: *     The number of superdiagonals within the band of A.  KU >= 0.
055: *
056: *     AB      (input) REAL array, dimension (LDAB,N)
057: *     On entry, the matrix A in band storage, in rows 1 to KL+KU+1.
058: *     The j-th column of A is stored in the j-th column of the
059: *     array AB as follows:
060: *     AB(KU+1+i-j,j) = A(i,j) for max(1,j-KU)<=i<=min(N,j+kl)
061: *
062: *     LDAB    (input) INTEGER
063: *     The leading dimension of the array AB.  LDAB >= KL+KU+1.
064: *
065: *     AFB     (input) REAL array, dimension (LDAFB,N)
066: *     Details of the LU factorization of the band matrix A, as
067: *     computed by SGBTRF.  U is stored as an upper triangular
068: *     band matrix with KL+KU superdiagonals in rows 1 to KL+KU+1,
069: *     and the multipliers used during the factorization are stored
070: *     in rows KL+KU+2 to 2*KL+KU+1.
071: *
072: *     LDAFB   (input) INTEGER
073: *     The leading dimension of the array AFB.  LDAFB >= 2*KL+KU+1.
074: *
075: *     IPIV    (input) INTEGER array, dimension (N)
076: *     The pivot indices from the factorization A = P*L*U
077: *     as computed by SGBTRF; row i of the matrix was interchanged
078: *     with row IPIV(i).
079: *
080: *     CMODE   (input) INTEGER
081: *     Determines op2(C) in the formula op(A) * op2(C) as follows:
082: *     CMODE =  1    op2(C) = C
083: *     CMODE =  0    op2(C) = I
084: *     CMODE = -1    op2(C) = inv(C)
085: *
086: *     C       (input) REAL array, dimension (N)
087: *     The vector C in the formula op(A) * op2(C).
088: *
089: *     INFO    (output) INTEGER
090: *       = 0:  Successful exit.
091: *     i > 0:  The ith argument is invalid.
092: *
093: *     WORK    (input) REAL array, dimension (5*N).
094: *     Workspace.
095: *
096: *     IWORK   (input) INTEGER array, dimension (N).
097: *     Workspace.
098: *
099: *  =====================================================================
100: *
101: *     .. Local Scalars ..
102:       LOGICAL            NOTRANS
103:       INTEGER            KASE, I, J, KD, KE
104:       REAL               AINVNM, TMP
105: *     ..
106: *     .. Local Arrays ..
107:       INTEGER            ISAVE( 3 )
108: *     ..
109: *     .. External Functions ..
110:       LOGICAL            LSAME
111:       EXTERNAL           LSAME
112: *     ..
113: *     .. External Subroutines ..
114:       EXTERNAL           SLACN2, SGBTRS, XERBLA
115: *     ..
116: *     .. Intrinsic Functions ..
117:       INTRINSIC          ABS, MAX
118: *     ..
119: *     .. Executable Statements ..
120: *
121:       SLA_GBRCOND = 0.0
122: *
123:       INFO = 0
124:       NOTRANS = LSAME( TRANS, 'N' )
125:       IF ( .NOT. NOTRANS .AND. .NOT. LSAME(TRANS, 'T')
126:      $     .AND. .NOT. LSAME(TRANS, 'C') ) THEN
127:          INFO = -1
128:       ELSE IF( N.LT.0 ) THEN
129:          INFO = -2
130:       ELSE IF( KL.LT.0 .OR. KL.GT.N-1 ) THEN
131:          INFO = -3
132:       ELSE IF( KU.LT.0 .OR. KU.GT.N-1 ) THEN
133:          INFO = -4
134:       ELSE IF( LDAB.LT.KL+KU+1 ) THEN
135:          INFO = -6
136:       ELSE IF( LDAFB.LT.2*KL+KU+1 ) THEN
137:          INFO = -8
138:       END IF
139:       IF( INFO.NE.0 ) THEN
140:          CALL XERBLA( 'SLA_GBRCOND', -INFO )
141:          RETURN
142:       END IF
143:       IF( N.EQ.0 ) THEN
144:          SLA_GBRCOND = 1.0
145:          RETURN
146:       END IF
147: *
148: *     Compute the equilibration matrix R such that
149: *     inv(R)*A*C has unit 1-norm.
150: *
151:       KD = KU + 1
152:       KE = KL + 1
153:       IF ( NOTRANS ) THEN
154:          DO I = 1, N
155:             TMP = 0.0
156:                IF ( CMODE .EQ. 1 ) THEN
157:                DO J = MAX( I-KL, 1 ), MIN( I+KU, N )
158:                   TMP = TMP + ABS( AB( KD+I-J, J ) * C( J ) )
159:                END DO
160:                ELSE IF ( CMODE .EQ. 0 ) THEN
161:                   DO J = MAX( I-KL, 1 ), MIN( I+KU, N )
162:                      TMP = TMP + ABS( AB( KD+I-J, J ) )
163:                   END DO
164:                ELSE
165:                   DO J = MAX( I-KL, 1 ), MIN( I+KU, N )
166:                      TMP = TMP + ABS( AB( KD+I-J, J ) / C( J ) )
167:                   END DO
168:                END IF
169:             WORK( 2*N+I ) = TMP
170:          END DO
171:       ELSE
172:          DO I = 1, N
173:             TMP = 0.0
174:             IF ( CMODE .EQ. 1 ) THEN
175:                DO J = MAX( I-KL, 1 ), MIN( I+KU, N )
176:                   TMP = TMP + ABS( AB( KE-I+J, I ) * C( J ) )
177:                END DO
178:             ELSE IF ( CMODE .EQ. 0 ) THEN
179:                DO J = MAX( I-KL, 1 ), MIN( I+KU, N )
180:                   TMP = TMP + ABS( AB( KE-I+J, I ) )
181:                END DO
182:             ELSE
183:                DO J = MAX( I-KL, 1 ), MIN( I+KU, N )
184:                   TMP = TMP + ABS( AB( KE-I+J, I ) / C( J ) )
185:                END DO
186:             END IF
187:             WORK( 2*N+I ) = TMP
188:          END DO
189:       END IF
190: *
191: *     Estimate the norm of inv(op(A)).
192: *
193:       AINVNM = 0.0
194: 
195:       KASE = 0
196:    10 CONTINUE
197:       CALL SLACN2( N, WORK( N+1 ), WORK, IWORK, AINVNM, KASE, ISAVE )
198:       IF( KASE.NE.0 ) THEN
199:          IF( KASE.EQ.2 ) THEN
200: *
201: *           Multiply by R.
202: *
203:             DO I = 1, N
204:                WORK( I ) = WORK( I ) * WORK( 2*N+I )
205:             END DO
206: 
207:             IF ( NOTRANS ) THEN
208:                CALL SGBTRS( 'No transpose', N, KL, KU, 1, AFB, LDAFB,
209:      $              IPIV, WORK, N, INFO )
210:             ELSE
211:                CALL SGBTRS( 'Transpose', N, KL, KU, 1, AFB, LDAFB, IPIV,
212:      $              WORK, N, INFO )
213:             END IF
214: *
215: *           Multiply by inv(C).
216: *
217:             IF ( CMODE .EQ. 1 ) THEN
218:                DO I = 1, N
219:                   WORK( I ) = WORK( I ) / C( I )
220:                END DO
221:             ELSE IF ( CMODE .EQ. -1 ) THEN
222:                DO I = 1, N
223:                   WORK( I ) = WORK( I ) * C( I )
224:                END DO
225:             END IF
226:          ELSE
227: *
228: *           Multiply by inv(C').
229: *
230:             IF ( CMODE .EQ. 1 ) THEN
231:                DO I = 1, N
232:                   WORK( I ) = WORK( I ) / C( I )
233:                END DO
234:             ELSE IF ( CMODE .EQ. -1 ) THEN
235:                DO I = 1, N
236:                   WORK( I ) = WORK( I ) * C( I )
237:                END DO
238:             END IF
239: 
240:             IF ( NOTRANS ) THEN
241:                CALL SGBTRS( 'Transpose', N, KL, KU, 1, AFB, LDAFB, IPIV,
242:      $              WORK, N, INFO )
243:             ELSE
244:                CALL SGBTRS( 'No transpose', N, KL, KU, 1, AFB, LDAFB,
245:      $              IPIV, WORK, N, INFO )
246:             END IF
247: *
248: *           Multiply by R.
249: *
250:             DO I = 1, N
251:                WORK( I ) = WORK( I ) * WORK( 2*N+I )
252:             END DO
253:          END IF
254:          GO TO 10
255:       END IF
256: *
257: *     Compute the estimate of the reciprocal condition number.
258: *
259:       IF( AINVNM .NE. 0.0 )
260:      $   SLA_GBRCOND = ( 1.0 / AINVNM )
261: *
262:       RETURN
263: *
264:       END
265: