001:       SUBROUTINE SGERQF( M, N, A, LDA, TAU, WORK, LWORK, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       INTEGER            INFO, LDA, LWORK, M, N
010: *     ..
011: *     .. Array Arguments ..
012:       REAL               A( LDA, * ), TAU( * ), WORK( * )
013: *     ..
014: *
015: *  Purpose
016: *  =======
017: *
018: *  SGERQF computes an RQ factorization of a real M-by-N matrix A:
019: *  A = R * Q.
020: *
021: *  Arguments
022: *  =========
023: *
024: *  M       (input) INTEGER
025: *          The number of rows of the matrix A.  M >= 0.
026: *
027: *  N       (input) INTEGER
028: *          The number of columns of the matrix A.  N >= 0.
029: *
030: *  A       (input/output) REAL array, dimension (LDA,N)
031: *          On entry, the M-by-N matrix A.
032: *          On exit,
033: *          if m <= n, the upper triangle of the subarray
034: *          A(1:m,n-m+1:n) contains the M-by-M upper triangular matrix R;
035: *          if m >= n, the elements on and above the (m-n)-th subdiagonal
036: *          contain the M-by-N upper trapezoidal matrix R;
037: *          the remaining elements, with the array TAU, represent the
038: *          orthogonal matrix Q as a product of min(m,n) elementary
039: *          reflectors (see Further Details).
040: *
041: *  LDA     (input) INTEGER
042: *          The leading dimension of the array A.  LDA >= max(1,M).
043: *
044: *  TAU     (output) REAL array, dimension (min(M,N))
045: *          The scalar factors of the elementary reflectors (see Further
046: *          Details).
047: *
048: *  WORK    (workspace/output) REAL array, dimension (MAX(1,LWORK))
049: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
050: *
051: *  LWORK   (input) INTEGER
052: *          The dimension of the array WORK.  LWORK >= max(1,M).
053: *          For optimum performance LWORK >= M*NB, where NB is
054: *          the optimal blocksize.
055: *
056: *          If LWORK = -1, then a workspace query is assumed; the routine
057: *          only calculates the optimal size of the WORK array, returns
058: *          this value as the first entry of the WORK array, and no error
059: *          message related to LWORK is issued by XERBLA.
060: *
061: *  INFO    (output) INTEGER
062: *          = 0:  successful exit
063: *          < 0:  if INFO = -i, the i-th argument had an illegal value
064: *
065: *  Further Details
066: *  ===============
067: *
068: *  The matrix Q is represented as a product of elementary reflectors
069: *
070: *     Q = H(1) H(2) . . . H(k), where k = min(m,n).
071: *
072: *  Each H(i) has the form
073: *
074: *     H(i) = I - tau * v * v'
075: *
076: *  where tau is a real scalar, and v is a real vector with
077: *  v(n-k+i+1:n) = 0 and v(n-k+i) = 1; v(1:n-k+i-1) is stored on exit in
078: *  A(m-k+i,1:n-k+i-1), and tau in TAU(i).
079: *
080: *  =====================================================================
081: *
082: *     .. Local Scalars ..
083:       LOGICAL            LQUERY
084:       INTEGER            I, IB, IINFO, IWS, K, KI, KK, LDWORK, LWKOPT,
085:      $                   MU, NB, NBMIN, NU, NX
086: *     ..
087: *     .. External Subroutines ..
088:       EXTERNAL           SGERQ2, SLARFB, SLARFT, XERBLA
089: *     ..
090: *     .. Intrinsic Functions ..
091:       INTRINSIC          MAX, MIN
092: *     ..
093: *     .. External Functions ..
094:       INTEGER            ILAENV
095:       EXTERNAL           ILAENV
096: *     ..
097: *     .. Executable Statements ..
098: *
099: *     Test the input arguments
100: *
101:       INFO = 0
102:       LQUERY = ( LWORK.EQ.-1 )
103:       IF( M.LT.0 ) THEN
104:          INFO = -1
105:       ELSE IF( N.LT.0 ) THEN
106:          INFO = -2
107:       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
108:          INFO = -4
109:       ELSE IF( LWORK.LT.MAX( 1, M ) .AND. .NOT.LQUERY ) THEN
110:          INFO = -7
111:       END IF
112: *
113:       IF( INFO.EQ.0 ) THEN
114:          K = MIN( M, N )
115:          IF( K.EQ.0 ) THEN
116:             LWKOPT = 1
117:          ELSE
118:             NB = ILAENV( 1, 'SGERQF', ' ', M, N, -1, -1 )
119:             LWKOPT = M*NB
120:             WORK( 1 ) = LWKOPT
121:          END IF
122:          WORK( 1 ) = LWKOPT
123: *
124:          IF( LWORK.LT.MAX( 1, M ) .AND. .NOT.LQUERY ) THEN
125:             INFO = -7
126:          END IF
127:       END IF
128: *
129:       IF( INFO.NE.0 ) THEN
130:          CALL XERBLA( 'SGERQF', -INFO )
131:          RETURN
132:       ELSE IF( LQUERY ) THEN
133:          RETURN
134:       END IF
135: *
136: *     Quick return if possible
137: *
138:       IF( K.EQ.0 ) THEN
139:          RETURN
140:       END IF
141: *
142:       NBMIN = 2
143:       NX = 1
144:       IWS = M
145:       IF( NB.GT.1 .AND. NB.LT.K ) THEN
146: *
147: *        Determine when to cross over from blocked to unblocked code.
148: *
149:          NX = MAX( 0, ILAENV( 3, 'SGERQF', ' ', M, N, -1, -1 ) )
150:          IF( NX.LT.K ) THEN
151: *
152: *           Determine if workspace is large enough for blocked code.
153: *
154:             LDWORK = M
155:             IWS = LDWORK*NB
156:             IF( LWORK.LT.IWS ) THEN
157: *
158: *              Not enough workspace to use optimal NB:  reduce NB and
159: *              determine the minimum value of NB.
160: *
161:                NB = LWORK / LDWORK
162:                NBMIN = MAX( 2, ILAENV( 2, 'SGERQF', ' ', M, N, -1,
163:      $                 -1 ) )
164:             END IF
165:          END IF
166:       END IF
167: *
168:       IF( NB.GE.NBMIN .AND. NB.LT.K .AND. NX.LT.K ) THEN
169: *
170: *        Use blocked code initially.
171: *        The last kk rows are handled by the block method.
172: *
173:          KI = ( ( K-NX-1 ) / NB )*NB
174:          KK = MIN( K, KI+NB )
175: *
176:          DO 10 I = K - KK + KI + 1, K - KK + 1, -NB
177:             IB = MIN( K-I+1, NB )
178: *
179: *           Compute the RQ factorization of the current block
180: *           A(m-k+i:m-k+i+ib-1,1:n-k+i+ib-1)
181: *
182:             CALL SGERQ2( IB, N-K+I+IB-1, A( M-K+I, 1 ), LDA, TAU( I ),
183:      $                   WORK, IINFO )
184:             IF( M-K+I.GT.1 ) THEN
185: *
186: *              Form the triangular factor of the block reflector
187: *              H = H(i+ib-1) . . . H(i+1) H(i)
188: *
189:                CALL SLARFT( 'Backward', 'Rowwise', N-K+I+IB-1, IB,
190:      $                      A( M-K+I, 1 ), LDA, TAU( I ), WORK, LDWORK )
191: *
192: *              Apply H to A(1:m-k+i-1,1:n-k+i+ib-1) from the right
193: *
194:                CALL SLARFB( 'Right', 'No transpose', 'Backward',
195:      $                      'Rowwise', M-K+I-1, N-K+I+IB-1, IB,
196:      $                      A( M-K+I, 1 ), LDA, WORK, LDWORK, A, LDA,
197:      $                      WORK( IB+1 ), LDWORK )
198:             END IF
199:    10    CONTINUE
200:          MU = M - K + I + NB - 1
201:          NU = N - K + I + NB - 1
202:       ELSE
203:          MU = M
204:          NU = N
205:       END IF
206: *
207: *     Use unblocked code to factor the last or only block
208: *
209:       IF( MU.GT.0 .AND. NU.GT.0 )
210:      $   CALL SGERQ2( MU, NU, A, LDA, TAU, WORK, IINFO )
211: *
212:       WORK( 1 ) = IWS
213:       RETURN
214: *
215: *     End of SGERQF
216: *
217:       END
218: