001:       SUBROUTINE DPOTRF( UPLO, N, A, LDA, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          UPLO
010:       INTEGER            INFO, LDA, N
011: *     ..
012: *     .. Array Arguments ..
013:       DOUBLE PRECISION   A( LDA, * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  DPOTRF computes the Cholesky factorization of a real symmetric
020: *  positive definite matrix A.
021: *
022: *  The factorization has the form
023: *     A = U**T * U,  if UPLO = 'U', or
024: *     A = L  * L**T,  if UPLO = 'L',
025: *  where U is an upper triangular matrix and L is lower triangular.
026: *
027: *  This is the block version of the algorithm, calling Level 3 BLAS.
028: *
029: *  Arguments
030: *  =========
031: *
032: *  UPLO    (input) CHARACTER*1
033: *          = 'U':  Upper triangle of A is stored;
034: *          = 'L':  Lower triangle of A is stored.
035: *
036: *  N       (input) INTEGER
037: *          The order of the matrix A.  N >= 0.
038: *
039: *  A       (input/output) DOUBLE PRECISION array, dimension (LDA,N)
040: *          On entry, the symmetric matrix A.  If UPLO = 'U', the leading
041: *          N-by-N upper triangular part of A contains the upper
042: *          triangular part of the matrix A, and the strictly lower
043: *          triangular part of A is not referenced.  If UPLO = 'L', the
044: *          leading N-by-N lower triangular part of A contains the lower
045: *          triangular part of the matrix A, and the strictly upper
046: *          triangular part of A is not referenced.
047: *
048: *          On exit, if INFO = 0, the factor U or L from the Cholesky
049: *          factorization A = U**T*U or A = L*L**T.
050: *
051: *  LDA     (input) INTEGER
052: *          The leading dimension of the array A.  LDA >= max(1,N).
053: *
054: *  INFO    (output) INTEGER
055: *          = 0:  successful exit
056: *          < 0:  if INFO = -i, the i-th argument had an illegal value
057: *          > 0:  if INFO = i, the leading minor of order i is not
058: *                positive definite, and the factorization could not be
059: *                completed.
060: *
061: *  =====================================================================
062: *
063: *     .. Parameters ..
064:       DOUBLE PRECISION   ONE
065:       PARAMETER          ( ONE = 1.0D+0 )
066: *     ..
067: *     .. Local Scalars ..
068:       LOGICAL            UPPER
069:       INTEGER            J, JB, NB
070: *     ..
071: *     .. External Functions ..
072:       LOGICAL            LSAME
073:       INTEGER            ILAENV
074:       EXTERNAL           LSAME, ILAENV
075: *     ..
076: *     .. External Subroutines ..
077:       EXTERNAL           DGEMM, DPOTF2, DSYRK, DTRSM, XERBLA
078: *     ..
079: *     .. Intrinsic Functions ..
080:       INTRINSIC          MAX, MIN
081: *     ..
082: *     .. Executable Statements ..
083: *
084: *     Test the input parameters.
085: *
086:       INFO = 0
087:       UPPER = LSAME( UPLO, 'U' )
088:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
089:          INFO = -1
090:       ELSE IF( N.LT.0 ) THEN
091:          INFO = -2
092:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
093:          INFO = -4
094:       END IF
095:       IF( INFO.NE.0 ) THEN
096:          CALL XERBLA( 'DPOTRF', -INFO )
097:          RETURN
098:       END IF
099: *
100: *     Quick return if possible
101: *
102:       IF( N.EQ.0 )
103:      $   RETURN
104: *
105: *     Determine the block size for this environment.
106: *
107:       NB = ILAENV( 1, 'DPOTRF', UPLO, N, -1, -1, -1 )
108:       IF( NB.LE.1 .OR. NB.GE.N ) THEN
109: *
110: *        Use unblocked code.
111: *
112:          CALL DPOTF2( UPLO, N, A, LDA, INFO )
113:       ELSE
114: *
115: *        Use blocked code.
116: *
117:          IF( UPPER ) THEN
118: *
119: *           Compute the Cholesky factorization A = U'*U.
120: *
121:             DO 10 J = 1, N, NB
122: *
123: *              Update and factorize the current diagonal block and test
124: *              for non-positive-definiteness.
125: *
126:                JB = MIN( NB, N-J+1 )
127:                CALL DSYRK( 'Upper', 'Transpose', JB, J-1, -ONE,
128:      $                     A( 1, J ), LDA, ONE, A( J, J ), LDA )
129:                CALL DPOTF2( 'Upper', JB, A( J, J ), LDA, INFO )
130:                IF( INFO.NE.0 )
131:      $            GO TO 30
132:                IF( J+JB.LE.N ) THEN
133: *
134: *                 Compute the current block row.
135: *
136:                   CALL DGEMM( 'Transpose', 'No transpose', JB, N-J-JB+1,
137:      $                        J-1, -ONE, A( 1, J ), LDA, A( 1, J+JB ),
138:      $                        LDA, ONE, A( J, J+JB ), LDA )
139:                   CALL DTRSM( 'Left', 'Upper', 'Transpose', 'Non-unit',
140:      $                        JB, N-J-JB+1, ONE, A( J, J ), LDA,
141:      $                        A( J, J+JB ), LDA )
142:                END IF
143:    10       CONTINUE
144: *
145:          ELSE
146: *
147: *           Compute the Cholesky factorization A = L*L'.
148: *
149:             DO 20 J = 1, N, NB
150: *
151: *              Update and factorize the current diagonal block and test
152: *              for non-positive-definiteness.
153: *
154:                JB = MIN( NB, N-J+1 )
155:                CALL DSYRK( 'Lower', 'No transpose', JB, J-1, -ONE,
156:      $                     A( J, 1 ), LDA, ONE, A( J, J ), LDA )
157:                CALL DPOTF2( 'Lower', JB, A( J, J ), LDA, INFO )
158:                IF( INFO.NE.0 )
159:      $            GO TO 30
160:                IF( J+JB.LE.N ) THEN
161: *
162: *                 Compute the current block column.
163: *
164:                   CALL DGEMM( 'No transpose', 'Transpose', N-J-JB+1, JB,
165:      $                        J-1, -ONE, A( J+JB, 1 ), LDA, A( J, 1 ),
166:      $                        LDA, ONE, A( J+JB, J ), LDA )
167:                   CALL DTRSM( 'Right', 'Lower', 'Transpose', 'Non-unit',
168:      $                        N-J-JB+1, JB, ONE, A( J, J ), LDA,
169:      $                        A( J+JB, J ), LDA )
170:                END IF
171:    20       CONTINUE
172:          END IF
173:       END IF
174:       GO TO 40
175: *
176:    30 CONTINUE
177:       INFO = INFO + J - 1
178: *
179:    40 CONTINUE
180:       RETURN
181: *
182: *     End of DPOTRF
183: *
184:       END
185: