001:       SUBROUTINE DORG2R( M, N, K, A, LDA, TAU, WORK, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       INTEGER            INFO, K, LDA, M, N
010: *     ..
011: *     .. Array Arguments ..
012:       DOUBLE PRECISION   A( LDA, * ), TAU( * ), WORK( * )
013: *     ..
014: *
015: *  Purpose
016: *  =======
017: *
018: *  DORG2R generates an m by n real matrix Q with orthonormal columns,
019: *  which is defined as the first n columns of a product of k elementary
020: *  reflectors of order m
021: *
022: *        Q  =  H(1) H(2) . . . H(k)
023: *
024: *  as returned by DGEQRF.
025: *
026: *  Arguments
027: *  =========
028: *
029: *  M       (input) INTEGER
030: *          The number of rows of the matrix Q. M >= 0.
031: *
032: *  N       (input) INTEGER
033: *          The number of columns of the matrix Q. M >= N >= 0.
034: *
035: *  K       (input) INTEGER
036: *          The number of elementary reflectors whose product defines the
037: *          matrix Q. N >= K >= 0.
038: *
039: *  A       (input/output) DOUBLE PRECISION array, dimension (LDA,N)
040: *          On entry, the i-th column must contain the vector which
041: *          defines the elementary reflector H(i), for i = 1,2,...,k, as
042: *          returned by DGEQRF in the first k columns of its array
043: *          argument A.
044: *          On exit, the m-by-n matrix Q.
045: *
046: *  LDA     (input) INTEGER
047: *          The first dimension of the array A. LDA >= max(1,M).
048: *
049: *  TAU     (input) DOUBLE PRECISION array, dimension (K)
050: *          TAU(i) must contain the scalar factor of the elementary
051: *          reflector H(i), as returned by DGEQRF.
052: *
053: *  WORK    (workspace) DOUBLE PRECISION array, dimension (N)
054: *
055: *  INFO    (output) INTEGER
056: *          = 0: successful exit
057: *          < 0: if INFO = -i, the i-th argument has an illegal value
058: *
059: *  =====================================================================
060: *
061: *     .. Parameters ..
062:       DOUBLE PRECISION   ONE, ZERO
063:       PARAMETER          ( ONE = 1.0D+0, ZERO = 0.0D+0 )
064: *     ..
065: *     .. Local Scalars ..
066:       INTEGER            I, J, L
067: *     ..
068: *     .. External Subroutines ..
069:       EXTERNAL           DLARF, DSCAL, XERBLA
070: *     ..
071: *     .. Intrinsic Functions ..
072:       INTRINSIC          MAX
073: *     ..
074: *     .. Executable Statements ..
075: *
076: *     Test the input arguments
077: *
078:       INFO = 0
079:       IF( M.LT.0 ) THEN
080:          INFO = -1
081:       ELSE IF( N.LT.0 .OR. N.GT.M ) THEN
082:          INFO = -2
083:       ELSE IF( K.LT.0 .OR. K.GT.N ) THEN
084:          INFO = -3
085:       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
086:          INFO = -5
087:       END IF
088:       IF( INFO.NE.0 ) THEN
089:          CALL XERBLA( 'DORG2R', -INFO )
090:          RETURN
091:       END IF
092: *
093: *     Quick return if possible
094: *
095:       IF( N.LE.0 )
096:      $   RETURN
097: *
098: *     Initialise columns k+1:n to columns of the unit matrix
099: *
100:       DO 20 J = K + 1, N
101:          DO 10 L = 1, M
102:             A( L, J ) = ZERO
103:    10    CONTINUE
104:          A( J, J ) = ONE
105:    20 CONTINUE
106: *
107:       DO 40 I = K, 1, -1
108: *
109: *        Apply H(i) to A(i:m,i:n) from the left
110: *
111:          IF( I.LT.N ) THEN
112:             A( I, I ) = ONE
113:             CALL DLARF( 'Left', M-I+1, N-I, A( I, I ), 1, TAU( I ),
114:      $                  A( I, I+1 ), LDA, WORK )
115:          END IF
116:          IF( I.LT.M )
117:      $      CALL DSCAL( M-I, -TAU( I ), A( I+1, I ), 1 )
118:          A( I, I ) = ONE - TAU( I )
119: *
120: *        Set A(1:i-1,i) to zero
121: *
122:          DO 30 L = 1, I - 1
123:             A( L, I ) = ZERO
124:    30    CONTINUE
125:    40 CONTINUE
126:       RETURN
127: *
128: *     End of DORG2R
129: *
130:       END
131: