001:       DOUBLE PRECISION FUNCTION DLA_PORCOND( UPLO, N, A, LDA, AF, LDAF,
002:      $                                       CMODE, C, INFO, WORK,
003:      $                                       IWORK )
004: *
005: *     -- LAPACK routine (version 3.2.1)                                 --
006: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
007: *     -- Jason Riedy of Univ. of California Berkeley.                 --
008: *     -- April 2009                                                   --
009: *
010: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
011: *     -- Univ. of California Berkeley and NAG Ltd.                    --
012: *
013:       IMPLICIT NONE
014: *     ..
015: *     .. Scalar Arguments ..
016:       CHARACTER          UPLO
017:       INTEGER            N, LDA, LDAF, INFO, CMODE
018:       DOUBLE PRECISION   A( LDA, * ), AF( LDAF, * ), WORK( * ),
019:      $                   C( * )
020: *     ..
021: *     .. Array Arguments ..
022:       INTEGER            IWORK( * )
023: *     ..
024: *
025: *  Purpose
026: *  =======
027: *
028: *     DLA_PORCOND Estimates the Skeel condition number of  op(A) * op2(C)
029: *     where op2 is determined by CMODE as follows
030: *     CMODE =  1    op2(C) = C
031: *     CMODE =  0    op2(C) = I
032: *     CMODE = -1    op2(C) = inv(C)
033: *     The Skeel condition number  cond(A) = norminf( |inv(A)||A| )
034: *     is computed by computing scaling factors R such that
035: *     diag(R)*A*op2(C) is row equilibrated and computing the standard
036: *     infinity-norm condition number.
037: *
038: *  Arguments
039: *  ==========
040: *
041: *     UPLO    (input) CHARACTER*1
042: *       = 'U':  Upper triangle of A is stored;
043: *       = 'L':  Lower triangle of A is stored.
044: *
045: *     N       (input) INTEGER
046: *     The number of linear equations, i.e., the order of the
047: *     matrix A.  N >= 0.
048: *
049: *     A       (input) REAL array, dimension (LDA,N)
050: *     On entry, the N-by-N matrix A.
051: *
052: *     LDA     (input) INTEGER
053: *     The leading dimension of the array A.  LDA >= max(1,N).
054: *
055: *     AF      (input) DOUBLE PRECISION array, dimension (LDAF,N)
056: *     The triangular factor U or L from the Cholesky factorization
057: *     A = U**T*U or A = L*L**T, as computed by DPOTRF.
058: *
059: *     LDAF    (input) INTEGER
060: *     The leading dimension of the array AF.  LDAF >= max(1,N).
061: *
062: *     CMODE   (input) INTEGER
063: *     Determines op2(C) in the formula op(A) * op2(C) as follows:
064: *     CMODE =  1    op2(C) = C
065: *     CMODE =  0    op2(C) = I
066: *     CMODE = -1    op2(C) = inv(C)
067: *
068: *     C       (input) DOUBLE PRECISION array, dimension (N)
069: *     The vector C in the formula op(A) * op2(C).
070: *
071: *     INFO    (output) INTEGER
072: *       = 0:  Successful exit.
073: *     i > 0:  The ith argument is invalid.
074: *
075: *     WORK    (input) DOUBLE PRECISION array, dimension (3*N).
076: *     Workspace.
077: *
078: *     IWORK   (input) INTEGER array, dimension (N).
079: *     Workspace.
080: *
081: *  =====================================================================
082: *
083: *     .. Local Scalars ..
084:       INTEGER            KASE, I, J
085:       DOUBLE PRECISION   AINVNM, TMP
086:       LOGICAL            UP
087: *     ..
088: *     .. Array Arguments ..
089:       INTEGER            ISAVE( 3 )
090: *     ..
091: *     .. External Functions ..
092:       LOGICAL            LSAME
093:       INTEGER            IDAMAX
094:       EXTERNAL           LSAME, IDAMAX
095: *     ..
096: *     .. External Subroutines ..
097:       EXTERNAL           DLACN2, DPOTRS, XERBLA
098: *     ..
099: *     .. Intrinsic Functions ..
100:       INTRINSIC          ABS, MAX
101: *     ..
102: *     .. Executable Statements ..
103: *
104:       DLA_PORCOND = 0.0D+0
105: *
106:       INFO = 0
107:       IF( N.LT.0 ) THEN
108:          INFO = -2
109:       END IF
110:       IF( INFO.NE.0 ) THEN
111:          CALL XERBLA( 'DLA_PORCOND', -INFO )
112:          RETURN
113:       END IF
114: 
115:       IF( N.EQ.0 ) THEN
116:          DLA_PORCOND = 1.0D+0
117:          RETURN
118:       END IF
119:       UP = .FALSE.
120:       IF ( LSAME( UPLO, 'U' ) ) UP = .TRUE.
121: *
122: *     Compute the equilibration matrix R such that
123: *     inv(R)*A*C has unit 1-norm.
124: *
125:       IF ( UP ) THEN
126:          DO I = 1, N
127:             TMP = 0.0D+0
128:             IF ( CMODE .EQ. 1 ) THEN
129:                DO J = 1, I
130:                   TMP = TMP + ABS( A( J, I ) * C( J ) )
131:                END DO
132:                DO J = I+1, N
133:                   TMP = TMP + ABS( A( I, J ) * C( J ) )
134:                END DO
135:             ELSE IF ( CMODE .EQ. 0 ) THEN
136:                DO J = 1, I
137:                   TMP = TMP + ABS( A( J, I ) )
138:                END DO
139:                DO J = I+1, N
140:                   TMP = TMP + ABS( A( I, J ) )
141:                END DO
142:             ELSE
143:                DO J = 1, I
144:                   TMP = TMP + ABS( A( J ,I ) / C( J ) )
145:                END DO
146:                DO J = I+1, N
147:                   TMP = TMP + ABS( A( I, J ) / C( J ) )
148:                END DO
149:             END IF
150:             WORK( 2*N+I ) = TMP
151:          END DO
152:       ELSE
153:          DO I = 1, N
154:             TMP = 0.0D+0
155:             IF ( CMODE .EQ. 1 ) THEN
156:                DO J = 1, I
157:                   TMP = TMP + ABS( A( I, J ) * C( J ) )
158:                END DO
159:                DO J = I+1, N
160:                   TMP = TMP + ABS( A( J, I ) * C( J ) )
161:                END DO
162:             ELSE IF ( CMODE .EQ. 0 ) THEN
163:                DO J = 1, I
164:                   TMP = TMP + ABS( A( I, J ) )
165:                END DO
166:                DO J = I+1, N
167:                   TMP = TMP + ABS( A( J, I ) )
168:                END DO
169:             ELSE
170:                DO J = 1, I
171:                   TMP = TMP + ABS( A( I, J ) / C( J ) )
172:                END DO
173:                DO J = I+1, N
174:                   TMP = TMP + ABS( A( J, I ) / C( J ) )
175:                END DO
176:             END IF
177:             WORK( 2*N+I ) = TMP
178:          END DO
179:       ENDIF
180: *
181: *     Estimate the norm of inv(op(A)).
182: *
183:       AINVNM = 0.0D+0
184: 
185:       KASE = 0
186:    10 CONTINUE
187:       CALL DLACN2( N, WORK( N+1 ), WORK, IWORK, AINVNM, KASE, ISAVE )
188:       IF( KASE.NE.0 ) THEN
189:          IF( KASE.EQ.2 ) THEN
190: *
191: *           Multiply by R.
192: *
193:             DO I = 1, N
194:                WORK( I ) = WORK( I ) * WORK( 2*N+I )
195:             END DO
196: 
197:             IF (UP) THEN
198:                CALL DPOTRS( 'Upper', N, 1, AF, LDAF, WORK, N, INFO )
199:             ELSE
200:                CALL DPOTRS( 'Lower', N, 1, AF, LDAF, WORK, N, INFO )
201:             ENDIF
202: *
203: *           Multiply by inv(C).
204: *
205:             IF ( CMODE .EQ. 1 ) THEN
206:                DO I = 1, N
207:                   WORK( I ) = WORK( I ) / C( I )
208:                END DO
209:             ELSE IF ( CMODE .EQ. -1 ) THEN
210:                DO I = 1, N
211:                   WORK( I ) = WORK( I ) * C( I )
212:                END DO
213:             END IF
214:          ELSE
215: *
216: *           Multiply by inv(C').
217: *
218:             IF ( CMODE .EQ. 1 ) THEN
219:                DO I = 1, N
220:                   WORK( I ) = WORK( I ) / C( I )
221:                END DO
222:             ELSE IF ( CMODE .EQ. -1 ) THEN
223:                DO I = 1, N
224:                   WORK( I ) = WORK( I ) * C( I )
225:                END DO
226:             END IF
227: 
228:             IF ( UP ) THEN
229:                CALL DPOTRS( 'Upper', N, 1, AF, LDAF, WORK, N, INFO )
230:             ELSE
231:                CALL DPOTRS( 'Lower', N, 1, AF, LDAF, WORK, N, INFO )
232:             ENDIF
233: *
234: *           Multiply by R.
235: *
236:             DO I = 1, N
237:                WORK( I ) = WORK( I ) * WORK( 2*N+I )
238:             END DO
239:          END IF
240:          GO TO 10
241:       END IF
242: *
243: *     Compute the estimate of the reciprocal condition number.
244: *
245:       IF( AINVNM .NE. 0.0D+0 )
246:      $   DLA_PORCOND = ( 1.0D+0 / AINVNM )
247: *
248:       RETURN
249: *
250:       END
251: