01:       SUBROUTINE DCOPY(N,DX,INCX,DY,INCY)
02: *     .. Scalar Arguments ..
03:       INTEGER INCX,INCY,N
04: *     ..
05: *     .. Array Arguments ..
06:       DOUBLE PRECISION DX(*),DY(*)
07: *     ..
08: *
09: *  Purpose
10: *  =======
11: *
12: *     DCOPY copies a vector, x, to a vector, y.
13: *     uses unrolled loops for increments equal to one.
14: *
15: *  Further Details
16: *  ===============
17: *
18: *     jack dongarra, linpack, 3/11/78.
19: *     modified 12/3/93, array(1) declarations changed to array(*)
20: *
21: *  =====================================================================
22: *
23: *     .. Local Scalars ..
24:       INTEGER I,IX,IY,M,MP1
25: *     ..
26: *     .. Intrinsic Functions ..
27:       INTRINSIC MOD
28: *     ..
29:       IF (N.LE.0) RETURN
30:       IF (INCX.EQ.1 .AND. INCY.EQ.1) GO TO 20
31: *
32: *        code for unequal increments or equal increments
33: *          not equal to 1
34: *
35:       IX = 1
36:       IY = 1
37:       IF (INCX.LT.0) IX = (-N+1)*INCX + 1
38:       IF (INCY.LT.0) IY = (-N+1)*INCY + 1
39:       DO 10 I = 1,N
40:           DY(IY) = DX(IX)
41:           IX = IX + INCX
42:           IY = IY + INCY
43:    10 CONTINUE
44:       RETURN
45: *
46: *        code for both increments equal to 1
47: *
48: *
49: *        clean-up loop
50: *
51:    20 M = MOD(N,7)
52:       IF (M.EQ.0) GO TO 40
53:       DO 30 I = 1,M
54:           DY(I) = DX(I)
55:    30 CONTINUE
56:       IF (N.LT.7) RETURN
57:    40 MP1 = M + 1
58:       DO 50 I = MP1,N,7
59:           DY(I) = DX(I)
60:           DY(I+1) = DX(I+1)
61:           DY(I+2) = DX(I+2)
62:           DY(I+3) = DX(I+3)
63:           DY(I+4) = DX(I+4)
64:           DY(I+5) = DX(I+5)
65:           DY(I+6) = DX(I+6)
66:    50 CONTINUE
67:       RETURN
68:       END
69: