001:       SUBROUTINE CUNMR2( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
002:      $                   WORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
006: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
007: *     November 2006
008: *
009: *     .. Scalar Arguments ..
010:       CHARACTER          SIDE, TRANS
011:       INTEGER            INFO, K, LDA, LDC, M, N
012: *     ..
013: *     .. Array Arguments ..
014:       COMPLEX            A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
015: *     ..
016: *
017: *  Purpose
018: *  =======
019: *
020: *  CUNMR2 overwrites the general complex m-by-n matrix C with
021: *
022: *        Q * C  if SIDE = 'L' and TRANS = 'N', or
023: *
024: *        Q'* C  if SIDE = 'L' and TRANS = 'C', or
025: *
026: *        C * Q  if SIDE = 'R' and TRANS = 'N', or
027: *
028: *        C * Q' if SIDE = 'R' and TRANS = 'C',
029: *
030: *  where Q is a complex unitary matrix defined as the product of k
031: *  elementary reflectors
032: *
033: *        Q = H(1)' H(2)' . . . H(k)'
034: *
035: *  as returned by CGERQF. Q is of order m if SIDE = 'L' and of order n
036: *  if SIDE = 'R'.
037: *
038: *  Arguments
039: *  =========
040: *
041: *  SIDE    (input) CHARACTER*1
042: *          = 'L': apply Q or Q' from the Left
043: *          = 'R': apply Q or Q' from the Right
044: *
045: *  TRANS   (input) CHARACTER*1
046: *          = 'N': apply Q  (No transpose)
047: *          = 'C': apply Q' (Conjugate transpose)
048: *
049: *  M       (input) INTEGER
050: *          The number of rows of the matrix C. M >= 0.
051: *
052: *  N       (input) INTEGER
053: *          The number of columns of the matrix C. N >= 0.
054: *
055: *  K       (input) INTEGER
056: *          The number of elementary reflectors whose product defines
057: *          the matrix Q.
058: *          If SIDE = 'L', M >= K >= 0;
059: *          if SIDE = 'R', N >= K >= 0.
060: *
061: *  A       (input) COMPLEX array, dimension
062: *                               (LDA,M) if SIDE = 'L',
063: *                               (LDA,N) if SIDE = 'R'
064: *          The i-th row must contain the vector which defines the
065: *          elementary reflector H(i), for i = 1,2,...,k, as returned by
066: *          CGERQF in the last k rows of its array argument A.
067: *          A is modified by the routine but restored on exit.
068: *
069: *  LDA     (input) INTEGER
070: *          The leading dimension of the array A. LDA >= max(1,K).
071: *
072: *  TAU     (input) COMPLEX array, dimension (K)
073: *          TAU(i) must contain the scalar factor of the elementary
074: *          reflector H(i), as returned by CGERQF.
075: *
076: *  C       (input/output) COMPLEX array, dimension (LDC,N)
077: *          On entry, the m-by-n matrix C.
078: *          On exit, C is overwritten by Q*C or Q'*C or C*Q' or C*Q.
079: *
080: *  LDC     (input) INTEGER
081: *          The leading dimension of the array C. LDC >= max(1,M).
082: *
083: *  WORK    (workspace) COMPLEX array, dimension
084: *                                   (N) if SIDE = 'L',
085: *                                   (M) if SIDE = 'R'
086: *
087: *  INFO    (output) INTEGER
088: *          = 0: successful exit
089: *          < 0: if INFO = -i, the i-th argument had an illegal value
090: *
091: *  =====================================================================
092: *
093: *     .. Parameters ..
094:       COMPLEX            ONE
095:       PARAMETER          ( ONE = ( 1.0E+0, 0.0E+0 ) )
096: *     ..
097: *     .. Local Scalars ..
098:       LOGICAL            LEFT, NOTRAN
099:       INTEGER            I, I1, I2, I3, MI, NI, NQ
100:       COMPLEX            AII, TAUI
101: *     ..
102: *     .. External Functions ..
103:       LOGICAL            LSAME
104:       EXTERNAL           LSAME
105: *     ..
106: *     .. External Subroutines ..
107:       EXTERNAL           CLACGV, CLARF, XERBLA
108: *     ..
109: *     .. Intrinsic Functions ..
110:       INTRINSIC          CONJG, MAX
111: *     ..
112: *     .. Executable Statements ..
113: *
114: *     Test the input arguments
115: *
116:       INFO = 0
117:       LEFT = LSAME( SIDE, 'L' )
118:       NOTRAN = LSAME( TRANS, 'N' )
119: *
120: *     NQ is the order of Q
121: *
122:       IF( LEFT ) THEN
123:          NQ = M
124:       ELSE
125:          NQ = N
126:       END IF
127:       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
128:          INFO = -1
129:       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'C' ) ) THEN
130:          INFO = -2
131:       ELSE IF( M.LT.0 ) THEN
132:          INFO = -3
133:       ELSE IF( N.LT.0 ) THEN
134:          INFO = -4
135:       ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
136:          INFO = -5
137:       ELSE IF( LDA.LT.MAX( 1, K ) ) THEN
138:          INFO = -7
139:       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
140:          INFO = -10
141:       END IF
142:       IF( INFO.NE.0 ) THEN
143:          CALL XERBLA( 'CUNMR2', -INFO )
144:          RETURN
145:       END IF
146: *
147: *     Quick return if possible
148: *
149:       IF( M.EQ.0 .OR. N.EQ.0 .OR. K.EQ.0 )
150:      $   RETURN
151: *
152:       IF( ( LEFT .AND. .NOT.NOTRAN .OR. .NOT.LEFT .AND. NOTRAN ) ) THEN
153:          I1 = 1
154:          I2 = K
155:          I3 = 1
156:       ELSE
157:          I1 = K
158:          I2 = 1
159:          I3 = -1
160:       END IF
161: *
162:       IF( LEFT ) THEN
163:          NI = N
164:       ELSE
165:          MI = M
166:       END IF
167: *
168:       DO 10 I = I1, I2, I3
169:          IF( LEFT ) THEN
170: *
171: *           H(i) or H(i)' is applied to C(1:m-k+i,1:n)
172: *
173:             MI = M - K + I
174:          ELSE
175: *
176: *           H(i) or H(i)' is applied to C(1:m,1:n-k+i)
177: *
178:             NI = N - K + I
179:          END IF
180: *
181: *        Apply H(i) or H(i)'
182: *
183:          IF( NOTRAN ) THEN
184:             TAUI = CONJG( TAU( I ) )
185:          ELSE
186:             TAUI = TAU( I )
187:          END IF
188:          CALL CLACGV( NQ-K+I-1, A( I, 1 ), LDA )
189:          AII = A( I, NQ-K+I )
190:          A( I, NQ-K+I ) = ONE
191:          CALL CLARF( SIDE, MI, NI, A( I, 1 ), LDA, TAUI, C, LDC, WORK )
192:          A( I, NQ-K+I ) = AII
193:          CALL CLACGV( NQ-K+I-1, A( I, 1 ), LDA )
194:    10 CONTINUE
195:       RETURN
196: *
197: *     End of CUNMR2
198: *
199:       END
200: