001:       SUBROUTINE CUNGHR( N, ILO, IHI, A, LDA, TAU, WORK, LWORK, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       INTEGER            IHI, ILO, INFO, LDA, LWORK, N
010: *     ..
011: *     .. Array Arguments ..
012:       COMPLEX            A( LDA, * ), TAU( * ), WORK( * )
013: *     ..
014: *
015: *  Purpose
016: *  =======
017: *
018: *  CUNGHR generates a complex unitary matrix Q which is defined as the
019: *  product of IHI-ILO elementary reflectors of order N, as returned by
020: *  CGEHRD:
021: *
022: *  Q = H(ilo) H(ilo+1) . . . H(ihi-1).
023: *
024: *  Arguments
025: *  =========
026: *
027: *  N       (input) INTEGER
028: *          The order of the matrix Q. N >= 0.
029: *
030: *  ILO     (input) INTEGER
031: *  IHI     (input) INTEGER
032: *          ILO and IHI must have the same values as in the previous call
033: *          of CGEHRD. Q is equal to the unit matrix except in the
034: *          submatrix Q(ilo+1:ihi,ilo+1:ihi).
035: *          1 <= ILO <= IHI <= N, if N > 0; ILO=1 and IHI=0, if N=0.
036: *
037: *  A       (input/output) COMPLEX array, dimension (LDA,N)
038: *          On entry, the vectors which define the elementary reflectors,
039: *          as returned by CGEHRD.
040: *          On exit, the N-by-N unitary matrix Q.
041: *
042: *  LDA     (input) INTEGER
043: *          The leading dimension of the array A. LDA >= max(1,N).
044: *
045: *  TAU     (input) COMPLEX array, dimension (N-1)
046: *          TAU(i) must contain the scalar factor of the elementary
047: *          reflector H(i), as returned by CGEHRD.
048: *
049: *  WORK    (workspace/output) COMPLEX array, dimension (MAX(1,LWORK))
050: *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
051: *
052: *  LWORK   (input) INTEGER
053: *          The dimension of the array WORK. LWORK >= IHI-ILO.
054: *          For optimum performance LWORK >= (IHI-ILO)*NB, where NB is
055: *          the optimal blocksize.
056: *
057: *          If LWORK = -1, then a workspace query is assumed; the routine
058: *          only calculates the optimal size of the WORK array, returns
059: *          this value as the first entry of the WORK array, and no error
060: *          message related to LWORK is issued by XERBLA.
061: *
062: *  INFO    (output) INTEGER
063: *          = 0:  successful exit
064: *          < 0:  if INFO = -i, the i-th argument had an illegal value
065: *
066: *  =====================================================================
067: *
068: *     .. Parameters ..
069:       COMPLEX            ZERO, ONE
070:       PARAMETER          ( ZERO = ( 0.0E+0, 0.0E+0 ),
071:      $                   ONE = ( 1.0E+0, 0.0E+0 ) )
072: *     ..
073: *     .. Local Scalars ..
074:       LOGICAL            LQUERY
075:       INTEGER            I, IINFO, J, LWKOPT, NB, NH
076: *     ..
077: *     .. External Subroutines ..
078:       EXTERNAL           CUNGQR, XERBLA
079: *     ..
080: *     .. External Functions ..
081:       INTEGER            ILAENV
082:       EXTERNAL           ILAENV
083: *     ..
084: *     .. Intrinsic Functions ..
085:       INTRINSIC          MAX, MIN
086: *     ..
087: *     .. Executable Statements ..
088: *
089: *     Test the input arguments
090: *
091:       INFO = 0
092:       NH = IHI - ILO
093:       LQUERY = ( LWORK.EQ.-1 )
094:       IF( N.LT.0 ) THEN
095:          INFO = -1
096:       ELSE IF( ILO.LT.1 .OR. ILO.GT.MAX( 1, N ) ) THEN
097:          INFO = -2
098:       ELSE IF( IHI.LT.MIN( ILO, N ) .OR. IHI.GT.N ) THEN
099:          INFO = -3
100:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
101:          INFO = -5
102:       ELSE IF( LWORK.LT.MAX( 1, NH ) .AND. .NOT.LQUERY ) THEN
103:          INFO = -8
104:       END IF
105: *
106:       IF( INFO.EQ.0 ) THEN
107:          NB = ILAENV( 1, 'CUNGQR', ' ', NH, NH, NH, -1 )
108:          LWKOPT = MAX( 1, NH )*NB
109:          WORK( 1 ) = LWKOPT
110:       END IF
111: *
112:       IF( INFO.NE.0 ) THEN
113:          CALL XERBLA( 'CUNGHR', -INFO )
114:          RETURN
115:       ELSE IF( LQUERY ) THEN
116:          RETURN
117:       END IF
118: *
119: *     Quick return if possible
120: *
121:       IF( N.EQ.0 ) THEN
122:          WORK( 1 ) = 1
123:          RETURN
124:       END IF
125: *
126: *     Shift the vectors which define the elementary reflectors one
127: *     column to the right, and set the first ilo and the last n-ihi
128: *     rows and columns to those of the unit matrix
129: *
130:       DO 40 J = IHI, ILO + 1, -1
131:          DO 10 I = 1, J - 1
132:             A( I, J ) = ZERO
133:    10    CONTINUE
134:          DO 20 I = J + 1, IHI
135:             A( I, J ) = A( I, J-1 )
136:    20    CONTINUE
137:          DO 30 I = IHI + 1, N
138:             A( I, J ) = ZERO
139:    30    CONTINUE
140:    40 CONTINUE
141:       DO 60 J = 1, ILO
142:          DO 50 I = 1, N
143:             A( I, J ) = ZERO
144:    50    CONTINUE
145:          A( J, J ) = ONE
146:    60 CONTINUE
147:       DO 80 J = IHI + 1, N
148:          DO 70 I = 1, N
149:             A( I, J ) = ZERO
150:    70    CONTINUE
151:          A( J, J ) = ONE
152:    80 CONTINUE
153: *
154:       IF( NH.GT.0 ) THEN
155: *
156: *        Generate Q(ilo+1:ihi,ilo+1:ihi)
157: *
158:          CALL CUNGQR( NH, NH, NH, A( ILO+1, ILO+1 ), LDA, TAU( ILO ),
159:      $                WORK, LWORK, IINFO )
160:       END IF
161:       WORK( 1 ) = LWKOPT
162:       RETURN
163: *
164: *     End of CUNGHR
165: *
166:       END
167: