001:       REAL             FUNCTION CLANSP( NORM, UPLO, N, AP, WORK )
002: *
003: *  -- LAPACK auxiliary routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          NORM, UPLO
010:       INTEGER            N
011: *     ..
012: *     .. Array Arguments ..
013:       REAL               WORK( * )
014:       COMPLEX            AP( * )
015: *     ..
016: *
017: *  Purpose
018: *  =======
019: *
020: *  CLANSP  returns the value of the one norm,  or the Frobenius norm, or
021: *  the  infinity norm,  or the  element of  largest absolute value  of a
022: *  complex symmetric matrix A,  supplied in packed form.
023: *
024: *  Description
025: *  ===========
026: *
027: *  CLANSP returns the value
028: *
029: *     CLANSP = ( max(abs(A(i,j))), NORM = 'M' or 'm'
030: *              (
031: *              ( norm1(A),         NORM = '1', 'O' or 'o'
032: *              (
033: *              ( normI(A),         NORM = 'I' or 'i'
034: *              (
035: *              ( normF(A),         NORM = 'F', 'f', 'E' or 'e'
036: *
037: *  where  norm1  denotes the  one norm of a matrix (maximum column sum),
038: *  normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
039: *  normF  denotes the  Frobenius norm of a matrix (square root of sum of
040: *  squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
041: *
042: *  Arguments
043: *  =========
044: *
045: *  NORM    (input) CHARACTER*1
046: *          Specifies the value to be returned in CLANSP as described
047: *          above.
048: *
049: *  UPLO    (input) CHARACTER*1
050: *          Specifies whether the upper or lower triangular part of the
051: *          symmetric matrix A is supplied.
052: *          = 'U':  Upper triangular part of A is supplied
053: *          = 'L':  Lower triangular part of A is supplied
054: *
055: *  N       (input) INTEGER
056: *          The order of the matrix A.  N >= 0.  When N = 0, CLANSP is
057: *          set to zero.
058: *
059: *  AP      (input) COMPLEX array, dimension (N*(N+1)/2)
060: *          The upper or lower triangle of the symmetric matrix A, packed
061: *          columnwise in a linear array.  The j-th column of A is stored
062: *          in the array AP as follows:
063: *          if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
064: *          if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n.
065: *
066: *  WORK    (workspace) REAL array, dimension (MAX(1,LWORK)),
067: *          where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
068: *          WORK is not referenced.
069: *
070: * =====================================================================
071: *
072: *     .. Parameters ..
073:       REAL               ONE, ZERO
074:       PARAMETER          ( ONE = 1.0E+0, ZERO = 0.0E+0 )
075: *     ..
076: *     .. Local Scalars ..
077:       INTEGER            I, J, K
078:       REAL               ABSA, SCALE, SUM, VALUE
079: *     ..
080: *     .. External Functions ..
081:       LOGICAL            LSAME
082:       EXTERNAL           LSAME
083: *     ..
084: *     .. External Subroutines ..
085:       EXTERNAL           CLASSQ
086: *     ..
087: *     .. Intrinsic Functions ..
088:       INTRINSIC          ABS, AIMAG, MAX, REAL, SQRT
089: *     ..
090: *     .. Executable Statements ..
091: *
092:       IF( N.EQ.0 ) THEN
093:          VALUE = ZERO
094:       ELSE IF( LSAME( NORM, 'M' ) ) THEN
095: *
096: *        Find max(abs(A(i,j))).
097: *
098:          VALUE = ZERO
099:          IF( LSAME( UPLO, 'U' ) ) THEN
100:             K = 1
101:             DO 20 J = 1, N
102:                DO 10 I = K, K + J - 1
103:                   VALUE = MAX( VALUE, ABS( AP( I ) ) )
104:    10          CONTINUE
105:                K = K + J
106:    20       CONTINUE
107:          ELSE
108:             K = 1
109:             DO 40 J = 1, N
110:                DO 30 I = K, K + N - J
111:                   VALUE = MAX( VALUE, ABS( AP( I ) ) )
112:    30          CONTINUE
113:                K = K + N - J + 1
114:    40       CONTINUE
115:          END IF
116:       ELSE IF( ( LSAME( NORM, 'I' ) ) .OR. ( LSAME( NORM, 'O' ) ) .OR.
117:      $         ( NORM.EQ.'1' ) ) THEN
118: *
119: *        Find normI(A) ( = norm1(A), since A is symmetric).
120: *
121:          VALUE = ZERO
122:          K = 1
123:          IF( LSAME( UPLO, 'U' ) ) THEN
124:             DO 60 J = 1, N
125:                SUM = ZERO
126:                DO 50 I = 1, J - 1
127:                   ABSA = ABS( AP( K ) )
128:                   SUM = SUM + ABSA
129:                   WORK( I ) = WORK( I ) + ABSA
130:                   K = K + 1
131:    50          CONTINUE
132:                WORK( J ) = SUM + ABS( AP( K ) )
133:                K = K + 1
134:    60       CONTINUE
135:             DO 70 I = 1, N
136:                VALUE = MAX( VALUE, WORK( I ) )
137:    70       CONTINUE
138:          ELSE
139:             DO 80 I = 1, N
140:                WORK( I ) = ZERO
141:    80       CONTINUE
142:             DO 100 J = 1, N
143:                SUM = WORK( J ) + ABS( AP( K ) )
144:                K = K + 1
145:                DO 90 I = J + 1, N
146:                   ABSA = ABS( AP( K ) )
147:                   SUM = SUM + ABSA
148:                   WORK( I ) = WORK( I ) + ABSA
149:                   K = K + 1
150:    90          CONTINUE
151:                VALUE = MAX( VALUE, SUM )
152:   100       CONTINUE
153:          END IF
154:       ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
155: *
156: *        Find normF(A).
157: *
158:          SCALE = ZERO
159:          SUM = ONE
160:          K = 2
161:          IF( LSAME( UPLO, 'U' ) ) THEN
162:             DO 110 J = 2, N
163:                CALL CLASSQ( J-1, AP( K ), 1, SCALE, SUM )
164:                K = K + J
165:   110       CONTINUE
166:          ELSE
167:             DO 120 J = 1, N - 1
168:                CALL CLASSQ( N-J, AP( K ), 1, SCALE, SUM )
169:                K = K + N - J + 1
170:   120       CONTINUE
171:          END IF
172:          SUM = 2*SUM
173:          K = 1
174:          DO 130 I = 1, N
175:             IF( REAL( AP( K ) ).NE.ZERO ) THEN
176:                ABSA = ABS( REAL( AP( K ) ) )
177:                IF( SCALE.LT.ABSA ) THEN
178:                   SUM = ONE + SUM*( SCALE / ABSA )**2
179:                   SCALE = ABSA
180:                ELSE
181:                   SUM = SUM + ( ABSA / SCALE )**2
182:                END IF
183:             END IF
184:             IF( AIMAG( AP( K ) ).NE.ZERO ) THEN
185:                ABSA = ABS( AIMAG( AP( K ) ) )
186:                IF( SCALE.LT.ABSA ) THEN
187:                   SUM = ONE + SUM*( SCALE / ABSA )**2
188:                   SCALE = ABSA
189:                ELSE
190:                   SUM = SUM + ( ABSA / SCALE )**2
191:                END IF
192:             END IF
193:             IF( LSAME( UPLO, 'U' ) ) THEN
194:                K = K + I + 1
195:             ELSE
196:                K = K + N - I + 1
197:             END IF
198:   130    CONTINUE
199:          VALUE = SCALE*SQRT( SUM )
200:       END IF
201: *
202:       CLANSP = VALUE
203:       RETURN
204: *
205: *     End of CLANSP
206: *
207:       END
208: