001:       SUBROUTINE CLA_HEAMV( UPLO, N, ALPHA, A, LDA, X, INCX, BETA, Y,
002:      $                      INCY )
003: *
004: *     -- LAPACK routine (version 3.2.1)                                 --
005: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
006: *     -- Jason Riedy of Univ. of California Berkeley.                 --
007: *     -- April 2009                                                   --
008: *
009: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
010: *     -- Univ. of California Berkeley and NAG Ltd.                    --
011: *
012:       IMPLICIT NONE
013: *     ..
014: *     .. Scalar Arguments ..
015:       REAL               ALPHA, BETA
016:       INTEGER            INCX, INCY, LDA, N, UPLO
017: *     ..
018: *     .. Array Arguments ..
019:       COMPLEX            A( LDA, * ), X( * )
020:       REAL               Y( * )
021: *     ..
022: *
023: *  Purpose
024: *  =======
025: *
026: *  CLA_SYAMV  performs the matrix-vector operation
027: *
028: *          y := alpha*abs(A)*abs(x) + beta*abs(y),
029: *
030: *  where alpha and beta are scalars, x and y are vectors and A is an
031: *  n by n symmetric matrix.
032: *
033: *  This function is primarily used in calculating error bounds.
034: *  To protect against underflow during evaluation, components in
035: *  the resulting vector are perturbed away from zero by (N+1)
036: *  times the underflow threshold.  To prevent unnecessarily large
037: *  errors for block-structure embedded in general matrices,
038: *  "symbolically" zero components are not perturbed.  A zero
039: *  entry is considered "symbolic" if all multiplications involved
040: *  in computing that entry have at least one zero multiplicand.
041: *
042: *  Arguments
043: *  ==========
044: *
045: *  UPLO   - INTEGER
046: *           On entry, UPLO specifies whether the upper or lower
047: *           triangular part of the array A is to be referenced as
048: *           follows:
049: *
050: *              UPLO = BLAS_UPPER   Only the upper triangular part of A
051: *                                  is to be referenced.
052: *
053: *              UPLO = BLAS_LOWER   Only the lower triangular part of A
054: *                                  is to be referenced.
055: *
056: *           Unchanged on exit.
057: *
058: *  N      - INTEGER.
059: *           On entry, N specifies the number of columns of the matrix A.
060: *           N must be at least zero.
061: *           Unchanged on exit.
062: *
063: *  ALPHA  - REAL            .
064: *           On entry, ALPHA specifies the scalar alpha.
065: *           Unchanged on exit.
066: *
067: *  A      - COMPLEX             array of DIMENSION ( LDA, n ).
068: *           Before entry, the leading m by n part of the array A must
069: *           contain the matrix of coefficients.
070: *           Unchanged on exit.
071: *
072: *  LDA    - INTEGER.
073: *           On entry, LDA specifies the first dimension of A as declared
074: *           in the calling (sub) program. LDA must be at least
075: *           max( 1, n ).
076: *           Unchanged on exit.
077: *
078: *  X      - COMPLEX             array of DIMENSION at least
079: *           ( 1 + ( n - 1 )*abs( INCX ) )
080: *           Before entry, the incremented array X must contain the
081: *           vector x.
082: *           Unchanged on exit.
083: *
084: *  INCX   - INTEGER.
085: *           On entry, INCX specifies the increment for the elements of
086: *           X. INCX must not be zero.
087: *           Unchanged on exit.
088: *
089: *  BETA   - REAL            .
090: *           On entry, BETA specifies the scalar beta. When BETA is
091: *           supplied as zero then Y need not be set on input.
092: *           Unchanged on exit.
093: *
094: *  Y      - REAL             array of DIMENSION at least
095: *           ( 1 + ( n - 1 )*abs( INCY ) )
096: *           Before entry with BETA non-zero, the incremented array Y
097: *           must contain the vector y. On exit, Y is overwritten by the
098: *           updated vector y.
099: *
100: *  INCY   - INTEGER.
101: *           On entry, INCY specifies the increment for the elements of
102: *           Y. INCY must not be zero.
103: *           Unchanged on exit.
104: *
105: *  Further Details
106: *  ===============
107: *
108: *  Level 2 Blas routine.
109: *
110: *  -- Written on 22-October-1986.
111: *     Jack Dongarra, Argonne National Lab.
112: *     Jeremy Du Croz, Nag Central Office.
113: *     Sven Hammarling, Nag Central Office.
114: *     Richard Hanson, Sandia National Labs.
115: *  -- Modified for the absolute-value product, April 2006
116: *     Jason Riedy, UC Berkeley
117: *
118: *  =====================================================================
119: *
120: *     .. Parameters ..
121:       REAL               ONE, ZERO
122:       PARAMETER          ( ONE = 1.0E+0, ZERO = 0.0E+0 )
123: *     ..
124: *     .. Local Scalars ..
125:       LOGICAL            SYMB_ZERO
126:       REAL               TEMP, SAFE1
127:       INTEGER            I, INFO, IY, J, JX, KX, KY
128:       COMPLEX            ZDUM
129: *     ..
130: *     .. External Subroutines ..
131:       EXTERNAL           XERBLA, SLAMCH
132:       REAL               SLAMCH
133: *     ..
134: *     .. External Functions ..
135:       EXTERNAL           ILAUPLO
136:       INTEGER            ILAUPLO
137: *     ..
138: *     .. Intrinsic Functions ..
139:       INTRINSIC          MAX, ABS, SIGN, REAL, AIMAG
140: *     ..
141: *     .. Statement Functions ..
142:       REAL               CABS1
143: *     ..
144: *     .. Statement Function Definitions ..
145:       CABS1( ZDUM ) = ABS( REAL ( ZDUM ) ) + ABS( AIMAG ( ZDUM ) )
146: *     ..
147: *     .. Executable Statements ..
148: *
149: *     Test the input parameters.
150: *
151:       INFO = 0
152:       IF     ( UPLO.NE.ILAUPLO( 'U' ) .AND.
153:      $         UPLO.NE.ILAUPLO( 'L' ) )THEN
154:          INFO = 1
155:       ELSE IF( N.LT.0 )THEN
156:          INFO = 2
157:       ELSE IF( LDA.LT.MAX( 1, N ) )THEN
158:          INFO = 5
159:       ELSE IF( INCX.EQ.0 )THEN
160:          INFO = 7
161:       ELSE IF( INCY.EQ.0 )THEN
162:          INFO = 10
163:       END IF
164:       IF( INFO.NE.0 )THEN
165:          CALL XERBLA( 'CHEMV ', INFO )
166:          RETURN
167:       END IF
168: *
169: *     Quick return if possible.
170: *
171:       IF( ( N.EQ.0 ).OR.( ( ALPHA.EQ.ZERO ).AND.( BETA.EQ.ONE ) ) )
172:      $   RETURN
173: *
174: *     Set up the start points in  X  and  Y.
175: *
176:       IF( INCX.GT.0 )THEN
177:          KX = 1
178:       ELSE
179:          KX = 1 - ( N - 1 )*INCX
180:       END IF
181:       IF( INCY.GT.0 )THEN
182:          KY = 1
183:       ELSE
184:          KY = 1 - ( N - 1 )*INCY
185:       END IF
186: *
187: *     Set SAFE1 essentially to be the underflow threshold times the
188: *     number of additions in each row.
189: *
190:       SAFE1 = SLAMCH( 'Safe minimum' )
191:       SAFE1 = (N+1)*SAFE1
192: *
193: *     Form  y := alpha*abs(A)*abs(x) + beta*abs(y).
194: *
195: *     The O(N^2) SYMB_ZERO tests could be replaced by O(N) queries to
196: *     the inexact flag.  Still doesn't help change the iteration order
197: *     to per-column.
198: *
199:       IY = KY
200:       IF ( INCX.EQ.1 ) THEN
201:          IF ( UPLO .EQ. ILAUPLO( 'U' ) ) THEN
202:             DO I = 1, N
203:                IF ( BETA .EQ. ZERO ) THEN
204:                   SYMB_ZERO = .TRUE.
205:                   Y( IY ) = 0.0
206:                ELSE IF ( Y( IY ) .EQ. ZERO ) THEN
207:                   SYMB_ZERO = .TRUE.
208:                ELSE
209:                   SYMB_ZERO = .FALSE.
210:                   Y( IY ) = BETA * ABS( Y( IY ) )
211:                END IF
212:                IF ( ALPHA .NE. ZERO ) THEN
213:                   DO J = 1, I
214:                      TEMP = CABS1( A( J, I ) )
215:                      SYMB_ZERO = SYMB_ZERO .AND.
216:      $                    ( X( J ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
217: 
218:                      Y( IY ) = Y( IY ) + ALPHA*CABS1( X( J ) )*TEMP
219:                   END DO
220:                   DO J = I+1, N
221:                      TEMP = CABS1( A( I, J ) )
222:                      SYMB_ZERO = SYMB_ZERO .AND.
223:      $                    ( X( J ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
224: 
225:                      Y( IY ) = Y( IY ) + ALPHA*CABS1( X( J ) )*TEMP
226:                   END DO
227:                END IF
228: 
229:                IF (.NOT.SYMB_ZERO)
230:      $              Y( IY ) = Y( IY ) + SIGN( SAFE1, Y( IY ) )
231: 
232:                IY = IY + INCY
233:             END DO
234:          ELSE
235:             DO I = 1, N
236:                IF ( BETA .EQ. ZERO ) THEN
237:                   SYMB_ZERO = .TRUE.
238:                   Y( IY ) = 0.0
239:                ELSE IF ( Y( IY ) .EQ. ZERO ) THEN
240:                   SYMB_ZERO = .TRUE.
241:                ELSE
242:                   SYMB_ZERO = .FALSE.
243:                   Y( IY ) = BETA * ABS( Y( IY ) )
244:                END IF
245:                IF ( ALPHA .NE. ZERO ) THEN
246:                   DO J = 1, I
247:                      TEMP = CABS1( A( I, J ) )
248:                      SYMB_ZERO = SYMB_ZERO .AND.
249:      $                    ( X( J ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
250: 
251:                      Y( IY ) = Y( IY ) + ALPHA*CABS1( X( J ) )*TEMP
252:                   END DO
253:                   DO J = I+1, N
254:                      TEMP = CABS1( A( J, I ) )
255:                      SYMB_ZERO = SYMB_ZERO .AND.
256:      $                    ( X( J ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
257: 
258:                      Y( IY ) = Y( IY ) + ALPHA*CABS1( X( J ) )*TEMP
259:                   END DO
260:                END IF
261: 
262:                IF (.NOT.SYMB_ZERO)
263:      $              Y( IY ) = Y( IY ) + SIGN( SAFE1, Y( IY ) )
264: 
265:                IY = IY + INCY
266:             END DO
267:          END IF
268:       ELSE
269:          IF ( UPLO .EQ. ILAUPLO( 'U' ) ) THEN
270:             DO I = 1, N
271:                IF ( BETA .EQ. ZERO ) THEN
272:                   SYMB_ZERO = .TRUE.
273:                   Y( IY ) = 0.0
274:                ELSE IF ( Y( IY ) .EQ. ZERO ) THEN
275:                   SYMB_ZERO = .TRUE.
276:                ELSE
277:                   SYMB_ZERO = .FALSE.
278:                   Y( IY ) = BETA * ABS( Y( IY ) )
279:                END IF
280:                JX = KX
281:                IF ( ALPHA .NE. ZERO ) THEN
282:                   DO J = 1, I
283:                      TEMP = CABS1( A( J, I ) )
284:                      SYMB_ZERO = SYMB_ZERO .AND.
285:      $                    ( X( J ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
286: 
287:                      Y( IY ) = Y( IY ) + ALPHA*CABS1( X( JX ) )*TEMP
288:                      JX = JX + INCX
289:                   END DO
290:                   DO J = I+1, N
291:                      TEMP = CABS1( A( I, J ) )
292:                      SYMB_ZERO = SYMB_ZERO .AND.
293:      $                    ( X( J ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
294: 
295:                      Y( IY ) = Y( IY ) + ALPHA*CABS1( X( JX ) )*TEMP
296:                      JX = JX + INCX
297:                   END DO
298:                END IF
299: 
300:                IF ( .NOT.SYMB_ZERO )
301:      $              Y( IY ) = Y( IY ) + SIGN( SAFE1, Y( IY ) )
302: 
303:                IY = IY + INCY
304:             END DO
305:          ELSE
306:             DO I = 1, N
307:                IF ( BETA .EQ. ZERO ) THEN
308:                   SYMB_ZERO = .TRUE.
309:                   Y( IY ) = 0.0
310:                ELSE IF ( Y( IY ) .EQ. ZERO ) THEN
311:                   SYMB_ZERO = .TRUE.
312:                ELSE
313:                   SYMB_ZERO = .FALSE.
314:                   Y( IY ) = BETA * ABS( Y( IY ) )
315:                END IF
316:                JX = KX
317:                IF ( ALPHA .NE. ZERO ) THEN
318:                   DO J = 1, I
319:                      TEMP = CABS1( A( I, J ) )
320:                      SYMB_ZERO = SYMB_ZERO .AND.
321:      $                    ( X( J ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
322: 
323:                      Y( IY ) = Y( IY ) + ALPHA*CABS1( X( JX ) )*TEMP
324:                      JX = JX + INCX
325:                   END DO
326:                   DO J = I+1, N
327:                      TEMP = CABS1( A( J, I ) )
328:                      SYMB_ZERO = SYMB_ZERO .AND.
329:      $                    ( X( J ) .EQ. ZERO .OR. TEMP .EQ. ZERO )
330: 
331:                      Y( IY ) = Y( IY ) + ALPHA*CABS1( X( JX ) )*TEMP
332:                      JX = JX + INCX
333:                   END DO
334:                END IF
335: 
336:                IF ( .NOT.SYMB_ZERO )
337:      $              Y( IY ) = Y( IY ) + SIGN( SAFE1, Y( IY ) )
338: 
339:                IY = IY + INCY
340:             END DO
341:          END IF
342: 
343:       END IF
344: *
345:       RETURN
346: *
347: *     End of CLA_HEAMV
348: *
349:       END
350: