001:       SUBROUTINE CHPEV( JOBZ, UPLO, N, AP, W, Z, LDZ, WORK, RWORK,
002:      $                  INFO )
003: *
004: *  -- LAPACK driver routine (version 3.2) --
005: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
006: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
007: *     November 2006
008: *
009: *     .. Scalar Arguments ..
010:       CHARACTER          JOBZ, UPLO
011:       INTEGER            INFO, LDZ, N
012: *     ..
013: *     .. Array Arguments ..
014:       REAL               RWORK( * ), W( * )
015:       COMPLEX            AP( * ), WORK( * ), Z( LDZ, * )
016: *     ..
017: *
018: *  Purpose
019: *  =======
020: *
021: *  CHPEV computes all the eigenvalues and, optionally, eigenvectors of a
022: *  complex Hermitian matrix in packed storage.
023: *
024: *  Arguments
025: *  =========
026: *
027: *  JOBZ    (input) CHARACTER*1
028: *          = 'N':  Compute eigenvalues only;
029: *          = 'V':  Compute eigenvalues and eigenvectors.
030: *
031: *  UPLO    (input) CHARACTER*1
032: *          = 'U':  Upper triangle of A is stored;
033: *          = 'L':  Lower triangle of A is stored.
034: *
035: *  N       (input) INTEGER
036: *          The order of the matrix A.  N >= 0.
037: *
038: *  AP      (input/output) COMPLEX array, dimension (N*(N+1)/2)
039: *          On entry, the upper or lower triangle of the Hermitian matrix
040: *          A, packed columnwise in a linear array.  The j-th column of A
041: *          is stored in the array AP as follows:
042: *          if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
043: *          if UPLO = 'L', AP(i + (j-1)*(2*n-j)/2) = A(i,j) for j<=i<=n.
044: *
045: *          On exit, AP is overwritten by values generated during the
046: *          reduction to tridiagonal form.  If UPLO = 'U', the diagonal
047: *          and first superdiagonal of the tridiagonal matrix T overwrite
048: *          the corresponding elements of A, and if UPLO = 'L', the
049: *          diagonal and first subdiagonal of T overwrite the
050: *          corresponding elements of A.
051: *
052: *  W       (output) REAL array, dimension (N)
053: *          If INFO = 0, the eigenvalues in ascending order.
054: *
055: *  Z       (output) COMPLEX array, dimension (LDZ, N)
056: *          If JOBZ = 'V', then if INFO = 0, Z contains the orthonormal
057: *          eigenvectors of the matrix A, with the i-th column of Z
058: *          holding the eigenvector associated with W(i).
059: *          If JOBZ = 'N', then Z is not referenced.
060: *
061: *  LDZ     (input) INTEGER
062: *          The leading dimension of the array Z.  LDZ >= 1, and if
063: *          JOBZ = 'V', LDZ >= max(1,N).
064: *
065: *  WORK    (workspace) COMPLEX array, dimension (max(1, 2*N-1))
066: *
067: *  RWORK   (workspace) REAL array, dimension (max(1, 3*N-2))
068: *
069: *  INFO    (output) INTEGER
070: *          = 0:  successful exit.
071: *          < 0:  if INFO = -i, the i-th argument had an illegal value.
072: *          > 0:  if INFO = i, the algorithm failed to converge; i
073: *                off-diagonal elements of an intermediate tridiagonal
074: *                form did not converge to zero.
075: *
076: *  =====================================================================
077: *
078: *     .. Parameters ..
079:       REAL               ZERO, ONE
080:       PARAMETER          ( ZERO = 0.0E0, ONE = 1.0E0 )
081: *     ..
082: *     .. Local Scalars ..
083:       LOGICAL            WANTZ
084:       INTEGER            IINFO, IMAX, INDE, INDRWK, INDTAU, INDWRK,
085:      $                   ISCALE
086:       REAL               ANRM, BIGNUM, EPS, RMAX, RMIN, SAFMIN, SIGMA,
087:      $                   SMLNUM
088: *     ..
089: *     .. External Functions ..
090:       LOGICAL            LSAME
091:       REAL               CLANHP, SLAMCH
092:       EXTERNAL           LSAME, CLANHP, SLAMCH
093: *     ..
094: *     .. External Subroutines ..
095:       EXTERNAL           CHPTRD, CSSCAL, CSTEQR, CUPGTR, SSCAL, SSTERF,
096:      $                   XERBLA
097: *     ..
098: *     .. Intrinsic Functions ..
099:       INTRINSIC          SQRT
100: *     ..
101: *     .. Executable Statements ..
102: *
103: *     Test the input parameters.
104: *
105:       WANTZ = LSAME( JOBZ, 'V' )
106: *
107:       INFO = 0
108:       IF( .NOT.( WANTZ .OR. LSAME( JOBZ, 'N' ) ) ) THEN
109:          INFO = -1
110:       ELSE IF( .NOT.( LSAME( UPLO, 'L' ) .OR. LSAME( UPLO, 'U' ) ) )
111:      $          THEN
112:          INFO = -2
113:       ELSE IF( N.LT.0 ) THEN
114:          INFO = -3
115:       ELSE IF( LDZ.LT.1 .OR. ( WANTZ .AND. LDZ.LT.N ) ) THEN
116:          INFO = -7
117:       END IF
118: *
119:       IF( INFO.NE.0 ) THEN
120:          CALL XERBLA( 'CHPEV ', -INFO )
121:          RETURN
122:       END IF
123: *
124: *     Quick return if possible
125: *
126:       IF( N.EQ.0 )
127:      $   RETURN
128: *
129:       IF( N.EQ.1 ) THEN
130:          W( 1 ) = AP( 1 )
131:          RWORK( 1 ) = 1
132:          IF( WANTZ )
133:      $      Z( 1, 1 ) = ONE
134:          RETURN
135:       END IF
136: *
137: *     Get machine constants.
138: *
139:       SAFMIN = SLAMCH( 'Safe minimum' )
140:       EPS = SLAMCH( 'Precision' )
141:       SMLNUM = SAFMIN / EPS
142:       BIGNUM = ONE / SMLNUM
143:       RMIN = SQRT( SMLNUM )
144:       RMAX = SQRT( BIGNUM )
145: *
146: *     Scale matrix to allowable range, if necessary.
147: *
148:       ANRM = CLANHP( 'M', UPLO, N, AP, RWORK )
149:       ISCALE = 0
150:       IF( ANRM.GT.ZERO .AND. ANRM.LT.RMIN ) THEN
151:          ISCALE = 1
152:          SIGMA = RMIN / ANRM
153:       ELSE IF( ANRM.GT.RMAX ) THEN
154:          ISCALE = 1
155:          SIGMA = RMAX / ANRM
156:       END IF
157:       IF( ISCALE.EQ.1 ) THEN
158:          CALL CSSCAL( ( N*( N+1 ) ) / 2, SIGMA, AP, 1 )
159:       END IF
160: *
161: *     Call CHPTRD to reduce Hermitian packed matrix to tridiagonal form.
162: *
163:       INDE = 1
164:       INDTAU = 1
165:       CALL CHPTRD( UPLO, N, AP, W, RWORK( INDE ), WORK( INDTAU ),
166:      $             IINFO )
167: *
168: *     For eigenvalues only, call SSTERF.  For eigenvectors, first call
169: *     CUPGTR to generate the orthogonal matrix, then call CSTEQR.
170: *
171:       IF( .NOT.WANTZ ) THEN
172:          CALL SSTERF( N, W, RWORK( INDE ), INFO )
173:       ELSE
174:          INDWRK = INDTAU + N
175:          CALL CUPGTR( UPLO, N, AP, WORK( INDTAU ), Z, LDZ,
176:      $                WORK( INDWRK ), IINFO )
177:          INDRWK = INDE + N
178:          CALL CSTEQR( JOBZ, N, W, RWORK( INDE ), Z, LDZ,
179:      $                RWORK( INDRWK ), INFO )
180:       END IF
181: *
182: *     If matrix was scaled, then rescale eigenvalues appropriately.
183: *
184:       IF( ISCALE.EQ.1 ) THEN
185:          IF( INFO.EQ.0 ) THEN
186:             IMAX = N
187:          ELSE
188:             IMAX = INFO - 1
189:          END IF
190:          CALL SSCAL( IMAX, ONE / SIGMA, W, 1 )
191:       END IF
192: *
193:       RETURN
194: *
195: *     End of CHPEV
196: *
197:       END
198: