```001:       SUBROUTINE CGEHD2( N, ILO, IHI, A, LDA, TAU, WORK, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
005: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       INTEGER            IHI, ILO, INFO, LDA, N
010: *     ..
011: *     .. Array Arguments ..
012:       COMPLEX            A( LDA, * ), TAU( * ), WORK( * )
013: *     ..
014: *
015: *  Purpose
016: *  =======
017: *
018: *  CGEHD2 reduces a complex general matrix A to upper Hessenberg form H
019: *  by a unitary similarity transformation:  Q' * A * Q = H .
020: *
021: *  Arguments
022: *  =========
023: *
024: *  N       (input) INTEGER
025: *          The order of the matrix A.  N >= 0.
026: *
027: *  ILO     (input) INTEGER
028: *  IHI     (input) INTEGER
029: *          It is assumed that A is already upper triangular in rows
030: *          and columns 1:ILO-1 and IHI+1:N. ILO and IHI are normally
031: *          set by a previous call to CGEBAL; otherwise they should be
032: *          set to 1 and N respectively. See Further Details.
033: *          1 <= ILO <= IHI <= max(1,N).
034: *
035: *  A       (input/output) COMPLEX array, dimension (LDA,N)
036: *          On entry, the n by n general matrix to be reduced.
037: *          On exit, the upper triangle and the first subdiagonal of A
038: *          are overwritten with the upper Hessenberg matrix H, and the
039: *          elements below the first subdiagonal, with the array TAU,
040: *          represent the unitary matrix Q as a product of elementary
041: *          reflectors. See Further Details.
042: *
043: *  LDA     (input) INTEGER
044: *          The leading dimension of the array A.  LDA >= max(1,N).
045: *
046: *  TAU     (output) COMPLEX array, dimension (N-1)
047: *          The scalar factors of the elementary reflectors (see Further
048: *          Details).
049: *
050: *  WORK    (workspace) COMPLEX array, dimension (N)
051: *
052: *  INFO    (output) INTEGER
053: *          = 0:  successful exit
054: *          < 0:  if INFO = -i, the i-th argument had an illegal value.
055: *
056: *  Further Details
057: *  ===============
058: *
059: *  The matrix Q is represented as a product of (ihi-ilo) elementary
060: *  reflectors
061: *
062: *     Q = H(ilo) H(ilo+1) . . . H(ihi-1).
063: *
064: *  Each H(i) has the form
065: *
066: *     H(i) = I - tau * v * v'
067: *
068: *  where tau is a complex scalar, and v is a complex vector with
069: *  v(1:i) = 0, v(i+1) = 1 and v(ihi+1:n) = 0; v(i+2:ihi) is stored on
070: *  exit in A(i+2:ihi,i), and tau in TAU(i).
071: *
072: *  The contents of A are illustrated by the following example, with
073: *  n = 7, ilo = 2 and ihi = 6:
074: *
075: *  on entry,                        on exit,
076: *
077: *  ( a   a   a   a   a   a   a )    (  a   a   h   h   h   h   a )
078: *  (     a   a   a   a   a   a )    (      a   h   h   h   h   a )
079: *  (     a   a   a   a   a   a )    (      h   h   h   h   h   h )
080: *  (     a   a   a   a   a   a )    (      v2  h   h   h   h   h )
081: *  (     a   a   a   a   a   a )    (      v2  v3  h   h   h   h )
082: *  (     a   a   a   a   a   a )    (      v2  v3  v4  h   h   h )
083: *  (                         a )    (                          a )
084: *
085: *  where a denotes an element of the original matrix A, h denotes a
086: *  modified element of the upper Hessenberg matrix H, and vi denotes an
087: *  element of the vector defining H(i).
088: *
089: *  =====================================================================
090: *
091: *     .. Parameters ..
092:       COMPLEX            ONE
093:       PARAMETER          ( ONE = ( 1.0E+0, 0.0E+0 ) )
094: *     ..
095: *     .. Local Scalars ..
096:       INTEGER            I
097:       COMPLEX            ALPHA
098: *     ..
099: *     .. External Subroutines ..
100:       EXTERNAL           CLARF, CLARFG, XERBLA
101: *     ..
102: *     .. Intrinsic Functions ..
103:       INTRINSIC          CONJG, MAX, MIN
104: *     ..
105: *     .. Executable Statements ..
106: *
107: *     Test the input parameters
108: *
109:       INFO = 0
110:       IF( N.LT.0 ) THEN
111:          INFO = -1
112:       ELSE IF( ILO.LT.1 .OR. ILO.GT.MAX( 1, N ) ) THEN
113:          INFO = -2
114:       ELSE IF( IHI.LT.MIN( ILO, N ) .OR. IHI.GT.N ) THEN
115:          INFO = -3
116:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
117:          INFO = -5
118:       END IF
119:       IF( INFO.NE.0 ) THEN
120:          CALL XERBLA( 'CGEHD2', -INFO )
121:          RETURN
122:       END IF
123: *
124:       DO 10 I = ILO, IHI - 1
125: *
126: *        Compute elementary reflector H(i) to annihilate A(i+2:ihi,i)
127: *
128:          ALPHA = A( I+1, I )
129:          CALL CLARFG( IHI-I, ALPHA, A( MIN( I+2, N ), I ), 1, TAU( I ) )
130:          A( I+1, I ) = ONE
131: *
132: *        Apply H(i) to A(1:ihi,i+1:ihi) from the right
133: *
134:          CALL CLARF( 'Right', IHI, IHI-I, A( I+1, I ), 1, TAU( I ),
135:      \$               A( 1, I+1 ), LDA, WORK )
136: *
137: *        Apply H(i)' to A(i+1:ihi,i+1:n) from the left
138: *
139:          CALL CLARF( 'Left', IHI-I, N-I, A( I+1, I ), 1,
140:      \$               CONJG( TAU( I ) ), A( I+1, I+1 ), LDA, WORK )
141: *
142:          A( I+1, I ) = ALPHA
143:    10 CONTINUE
144: *
145:       RETURN
146: *
147: *     End of CGEHD2
148: *
149:       END
150: ```