```01:       COMPLEX FUNCTION CDOTU(N,CX,INCX,CY,INCY)
02: *     .. Scalar Arguments ..
03:       INTEGER INCX,INCY,N
04: *     ..
05: *     .. Array Arguments ..
06:       COMPLEX CX(*),CY(*)
07: *     ..
08: *
09: *  Purpose
10: *  =======
11: *
12: *     CDOTU forms the dot product of two vectors.
13: *
14: *  Further Details
15: *  ===============
16: *
17: *     jack dongarra, linpack, 3/11/78.
18: *     modified 12/3/93, array(1) declarations changed to array(*)
19: *
20: *  =====================================================================
21: *
22: *     .. Local Scalars ..
23:       COMPLEX CTEMP
24:       INTEGER I,IX,IY
25: *     ..
26:       CTEMP = (0.0,0.0)
27:       CDOTU = (0.0,0.0)
28:       IF (N.LE.0) RETURN
29:       IF (INCX.EQ.1 .AND. INCY.EQ.1) GO TO 20
30: *
31: *        code for unequal increments or equal increments
32: *          not equal to 1
33: *
34:       IX = 1
35:       IY = 1
36:       IF (INCX.LT.0) IX = (-N+1)*INCX + 1
37:       IF (INCY.LT.0) IY = (-N+1)*INCY + 1
38:       DO 10 I = 1,N
39:           CTEMP = CTEMP + CX(IX)*CY(IY)
40:           IX = IX + INCX
41:           IY = IY + INCY
42:    10 CONTINUE
43:       CDOTU = CTEMP
44:       RETURN
45: *
46: *        code for both increments equal to 1
47: *
48:    20 DO 30 I = 1,N
49:           CTEMP = CTEMP + CX(I)*CY(I)
50:    30 CONTINUE
51:       CDOTU = CTEMP
52:       RETURN
53:       END
54: ```