001:       SUBROUTINE ZTREXC( COMPQ, N, T, LDT, Q, LDQ, IFST, ILST, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
005: *     November 2006
006: *
007: *     .. Scalar Arguments ..
008:       CHARACTER          COMPQ
009:       INTEGER            IFST, ILST, INFO, LDQ, LDT, N
010: *     ..
011: *     .. Array Arguments ..
012:       COMPLEX*16         Q( LDQ, * ), T( LDT, * )
013: *     ..
014: *
015: *  Purpose
016: *  =======
017: *
018: *  ZTREXC reorders the Schur factorization of a complex matrix
019: *  A = Q*T*Q**H, so that the diagonal element of T with row index IFST
020: *  is moved to row ILST.
021: *
022: *  The Schur form T is reordered by a unitary similarity transformation
023: *  Z**H*T*Z, and optionally the matrix Q of Schur vectors is updated by
024: *  postmultplying it with Z.
025: *
026: *  Arguments
027: *  =========
028: *
029: *  COMPQ   (input) CHARACTER*1
030: *          = 'V':  update the matrix Q of Schur vectors;
031: *          = 'N':  do not update Q.
032: *
033: *  N       (input) INTEGER
034: *          The order of the matrix T. N >= 0.
035: *
036: *  T       (input/output) COMPLEX*16 array, dimension (LDT,N)
037: *          On entry, the upper triangular matrix T.
038: *          On exit, the reordered upper triangular matrix.
039: *
040: *  LDT     (input) INTEGER
041: *          The leading dimension of the array T. LDT >= max(1,N).
042: *
043: *  Q       (input/output) COMPLEX*16 array, dimension (LDQ,N)
044: *          On entry, if COMPQ = 'V', the matrix Q of Schur vectors.
045: *          On exit, if COMPQ = 'V', Q has been postmultiplied by the
046: *          unitary transformation matrix Z which reorders T.
047: *          If COMPQ = 'N', Q is not referenced.
048: *
049: *  LDQ     (input) INTEGER
050: *          The leading dimension of the array Q.  LDQ >= max(1,N).
051: *
052: *  IFST    (input) INTEGER
053: *  ILST    (input) INTEGER
054: *          Specify the reordering of the diagonal elements of T:
055: *          The element with row index IFST is moved to row ILST by a
056: *          sequence of transpositions between adjacent elements.
057: *          1 <= IFST <= N; 1 <= ILST <= N.
058: *
059: *  INFO    (output) INTEGER
060: *          = 0:  successful exit
061: *          < 0:  if INFO = -i, the i-th argument had an illegal value
062: *
063: *  =====================================================================
064: *
065: *     .. Local Scalars ..
066:       LOGICAL            WANTQ
067:       INTEGER            K, M1, M2, M3
068:       DOUBLE PRECISION   CS
069:       COMPLEX*16         SN, T11, T22, TEMP
070: *     ..
071: *     .. External Functions ..
072:       LOGICAL            LSAME
073:       EXTERNAL           LSAME
074: *     ..
075: *     .. External Subroutines ..
076:       EXTERNAL           XERBLA, ZLARTG, ZROT
077: *     ..
078: *     .. Intrinsic Functions ..
079:       INTRINSIC          DCONJG, MAX
080: *     ..
081: *     .. Executable Statements ..
082: *
083: *     Decode and test the input parameters.
084: *
085:       INFO = 0
086:       WANTQ = LSAME( COMPQ, 'V' )
087:       IF( .NOT.LSAME( COMPQ, 'N' ) .AND. .NOT.WANTQ ) THEN
088:          INFO = -1
089:       ELSE IF( N.LT.0 ) THEN
090:          INFO = -2
091:       ELSE IF( LDT.LT.MAX( 1, N ) ) THEN
092:          INFO = -4
093:       ELSE IF( LDQ.LT.1 .OR. ( WANTQ .AND. LDQ.LT.MAX( 1, N ) ) ) THEN
094:          INFO = -6
095:       ELSE IF( IFST.LT.1 .OR. IFST.GT.N ) THEN
096:          INFO = -7
097:       ELSE IF( ILST.LT.1 .OR. ILST.GT.N ) THEN
098:          INFO = -8
099:       END IF
100:       IF( INFO.NE.0 ) THEN
101:          CALL XERBLA( 'ZTREXC', -INFO )
102:          RETURN
103:       END IF
104: *
105: *     Quick return if possible
106: *
107:       IF( N.EQ.1 .OR. IFST.EQ.ILST )
108:      $   RETURN
109: *
110:       IF( IFST.LT.ILST ) THEN
111: *
112: *        Move the IFST-th diagonal element forward down the diagonal.
113: *
114:          M1 = 0
115:          M2 = -1
116:          M3 = 1
117:       ELSE
118: *
119: *        Move the IFST-th diagonal element backward up the diagonal.
120: *
121:          M1 = -1
122:          M2 = 0
123:          M3 = -1
124:       END IF
125: *
126:       DO 10 K = IFST + M1, ILST + M2, M3
127: *
128: *        Interchange the k-th and (k+1)-th diagonal elements.
129: *
130:          T11 = T( K, K )
131:          T22 = T( K+1, K+1 )
132: *
133: *        Determine the transformation to perform the interchange.
134: *
135:          CALL ZLARTG( T( K, K+1 ), T22-T11, CS, SN, TEMP )
136: *
137: *        Apply transformation to the matrix T.
138: *
139:          IF( K+2.LE.N )
140:      $      CALL ZROT( N-K-1, T( K, K+2 ), LDT, T( K+1, K+2 ), LDT, CS,
141:      $                 SN )
142:          CALL ZROT( K-1, T( 1, K ), 1, T( 1, K+1 ), 1, CS,
143:      $              DCONJG( SN ) )
144: *
145:          T( K, K ) = T22
146:          T( K+1, K+1 ) = T11
147: *
148:          IF( WANTQ ) THEN
149: *
150: *           Accumulate transformation in the matrix Q.
151: *
152:             CALL ZROT( N, Q( 1, K ), 1, Q( 1, K+1 ), 1, CS,
153:      $                 DCONJG( SN ) )
154:          END IF
155: *
156:    10 CONTINUE
157: *
158:       RETURN
159: *
160: *     End of ZTREXC
161: *
162:       END
163: