001:       SUBROUTINE ZPOTRF( UPLO, N, A, LDA, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
005: *     November 2006
006: *
007: *     .. Scalar Arguments ..
008:       CHARACTER          UPLO
009:       INTEGER            INFO, LDA, N
010: *     ..
011: *     .. Array Arguments ..
012:       COMPLEX*16         A( LDA, * )
013: *     ..
014: *
015: *  Purpose
016: *  =======
017: *
018: *  ZPOTRF computes the Cholesky factorization of a complex Hermitian
019: *  positive definite matrix A.
020: *
021: *  The factorization has the form
022: *     A = U**H * U,  if UPLO = 'U', or
023: *     A = L  * L**H,  if UPLO = 'L',
024: *  where U is an upper triangular matrix and L is lower triangular.
025: *
026: *  This is the block version of the algorithm, calling Level 3 BLAS.
027: *
028: *  Arguments
029: *  =========
030: *
031: *  UPLO    (input) CHARACTER*1
032: *          = 'U':  Upper triangle of A is stored;
033: *          = 'L':  Lower triangle of A is stored.
034: *
035: *  N       (input) INTEGER
036: *          The order of the matrix A.  N >= 0.
037: *
038: *  A       (input/output) COMPLEX*16 array, dimension (LDA,N)
039: *          On entry, the Hermitian matrix A.  If UPLO = 'U', the leading
040: *          N-by-N upper triangular part of A contains the upper
041: *          triangular part of the matrix A, and the strictly lower
042: *          triangular part of A is not referenced.  If UPLO = 'L', the
043: *          leading N-by-N lower triangular part of A contains the lower
044: *          triangular part of the matrix A, and the strictly upper
045: *          triangular part of A is not referenced.
046: *
047: *          On exit, if INFO = 0, the factor U or L from the Cholesky
048: *          factorization A = U**H*U or A = L*L**H.
049: *
050: *  LDA     (input) INTEGER
051: *          The leading dimension of the array A.  LDA >= max(1,N).
052: *
053: *  INFO    (output) INTEGER
054: *          = 0:  successful exit
055: *          < 0:  if INFO = -i, the i-th argument had an illegal value
056: *          > 0:  if INFO = i, the leading minor of order i is not
057: *                positive definite, and the factorization could not be
058: *                completed.
059: *
060: *  =====================================================================
061: *
062: *     .. Parameters ..
063:       DOUBLE PRECISION   ONE
064:       COMPLEX*16         CONE
065:       PARAMETER          ( ONE = 1.0D+0, CONE = ( 1.0D+0, 0.0D+0 ) )
066: *     ..
067: *     .. Local Scalars ..
068:       LOGICAL            UPPER
069:       INTEGER            J, JB, NB
070: *     ..
071: *     .. External Functions ..
072:       LOGICAL            LSAME
073:       INTEGER            ILAENV
074:       EXTERNAL           LSAME, ILAENV
075: *     ..
076: *     .. External Subroutines ..
077:       EXTERNAL           XERBLA, ZGEMM, ZHERK, ZPOTF2, ZTRSM
078: *     ..
079: *     .. Intrinsic Functions ..
080:       INTRINSIC          MAX, MIN
081: *     ..
082: *     .. Executable Statements ..
083: *
084: *     Test the input parameters.
085: *
086:       INFO = 0
087:       UPPER = LSAME( UPLO, 'U' )
088:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
089:          INFO = -1
090:       ELSE IF( N.LT.0 ) THEN
091:          INFO = -2
092:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
093:          INFO = -4
094:       END IF
095:       IF( INFO.NE.0 ) THEN
096:          CALL XERBLA( 'ZPOTRF', -INFO )
097:          RETURN
098:       END IF
099: *
100: *     Quick return if possible
101: *
102:       IF( N.EQ.0 )
103:      $   RETURN
104: *
105: *     Determine the block size for this environment.
106: *
107:       NB = ILAENV( 1, 'ZPOTRF', UPLO, N, -1, -1, -1 )
108:       IF( NB.LE.1 .OR. NB.GE.N ) THEN
109: *
110: *        Use unblocked code.
111: *
112:          CALL ZPOTF2( UPLO, N, A, LDA, INFO )
113:       ELSE
114: *
115: *        Use blocked code.
116: *
117:          IF( UPPER ) THEN
118: *
119: *           Compute the Cholesky factorization A = U'*U.
120: *
121:             DO 10 J = 1, N, NB
122: *
123: *              Update and factorize the current diagonal block and test
124: *              for non-positive-definiteness.
125: *
126:                JB = MIN( NB, N-J+1 )
127:                CALL ZHERK( 'Upper', 'Conjugate transpose', JB, J-1,
128:      $                     -ONE, A( 1, J ), LDA, ONE, A( J, J ), LDA )
129:                CALL ZPOTF2( 'Upper', JB, A( J, J ), LDA, INFO )
130:                IF( INFO.NE.0 )
131:      $            GO TO 30
132:                IF( J+JB.LE.N ) THEN
133: *
134: *                 Compute the current block row.
135: *
136:                   CALL ZGEMM( 'Conjugate transpose', 'No transpose', JB,
137:      $                        N-J-JB+1, J-1, -CONE, A( 1, J ), LDA,
138:      $                        A( 1, J+JB ), LDA, CONE, A( J, J+JB ),
139:      $                        LDA )
140:                   CALL ZTRSM( 'Left', 'Upper', 'Conjugate transpose',
141:      $                        'Non-unit', JB, N-J-JB+1, CONE, A( J, J ),
142:      $                        LDA, A( J, J+JB ), LDA )
143:                END IF
144:    10       CONTINUE
145: *
146:          ELSE
147: *
148: *           Compute the Cholesky factorization A = L*L'.
149: *
150:             DO 20 J = 1, N, NB
151: *
152: *              Update and factorize the current diagonal block and test
153: *              for non-positive-definiteness.
154: *
155:                JB = MIN( NB, N-J+1 )
156:                CALL ZHERK( 'Lower', 'No transpose', JB, J-1, -ONE,
157:      $                     A( J, 1 ), LDA, ONE, A( J, J ), LDA )
158:                CALL ZPOTF2( 'Lower', JB, A( J, J ), LDA, INFO )
159:                IF( INFO.NE.0 )
160:      $            GO TO 30
161:                IF( J+JB.LE.N ) THEN
162: *
163: *                 Compute the current block column.
164: *
165:                   CALL ZGEMM( 'No transpose', 'Conjugate transpose',
166:      $                        N-J-JB+1, JB, J-1, -CONE, A( J+JB, 1 ),
167:      $                        LDA, A( J, 1 ), LDA, CONE, A( J+JB, J ),
168:      $                        LDA )
169:                   CALL ZTRSM( 'Right', 'Lower', 'Conjugate transpose',
170:      $                        'Non-unit', N-J-JB+1, JB, CONE, A( J, J ),
171:      $                        LDA, A( J+JB, J ), LDA )
172:                END IF
173:    20       CONTINUE
174:          END IF
175:       END IF
176:       GO TO 40
177: *
178:    30 CONTINUE
179:       INFO = INFO + J - 1
180: *
181:    40 CONTINUE
182:       RETURN
183: *
184: *     End of ZPOTRF
185: *
186:       END
187: