001:       DOUBLE PRECISION FUNCTION ZLANHB( NORM, UPLO, N, K, AB, LDAB,
002:      $                 WORK )
003: *
004: *  -- LAPACK auxiliary routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          NORM, UPLO
010:       INTEGER            K, LDAB, N
011: *     ..
012: *     .. Array Arguments ..
013:       DOUBLE PRECISION   WORK( * )
014:       COMPLEX*16         AB( LDAB, * )
015: *     ..
016: *
017: *  Purpose
018: *  =======
019: *
020: *  ZLANHB  returns the value of the one norm,  or the Frobenius norm, or
021: *  the  infinity norm,  or the element of  largest absolute value  of an
022: *  n by n hermitian band matrix A,  with k super-diagonals.
023: *
024: *  Description
025: *  ===========
026: *
027: *  ZLANHB returns the value
028: *
029: *     ZLANHB = ( max(abs(A(i,j))), NORM = 'M' or 'm'
030: *              (
031: *              ( norm1(A),         NORM = '1', 'O' or 'o'
032: *              (
033: *              ( normI(A),         NORM = 'I' or 'i'
034: *              (
035: *              ( normF(A),         NORM = 'F', 'f', 'E' or 'e'
036: *
037: *  where  norm1  denotes the  one norm of a matrix (maximum column sum),
038: *  normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
039: *  normF  denotes the  Frobenius norm of a matrix (square root of sum of
040: *  squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
041: *
042: *  Arguments
043: *  =========
044: *
045: *  NORM    (input) CHARACTER*1
046: *          Specifies the value to be returned in ZLANHB as described
047: *          above.
048: *
049: *  UPLO    (input) CHARACTER*1
050: *          Specifies whether the upper or lower triangular part of the
051: *          band matrix A is supplied.
052: *          = 'U':  Upper triangular
053: *          = 'L':  Lower triangular
054: *
055: *  N       (input) INTEGER
056: *          The order of the matrix A.  N >= 0.  When N = 0, ZLANHB is
057: *          set to zero.
058: *
059: *  K       (input) INTEGER
060: *          The number of super-diagonals or sub-diagonals of the
061: *          band matrix A.  K >= 0.
062: *
063: *  AB      (input) COMPLEX*16 array, dimension (LDAB,N)
064: *          The upper or lower triangle of the hermitian band matrix A,
065: *          stored in the first K+1 rows of AB.  The j-th column of A is
066: *          stored in the j-th column of the array AB as follows:
067: *          if UPLO = 'U', AB(k+1+i-j,j) = A(i,j) for max(1,j-k)<=i<=j;
068: *          if UPLO = 'L', AB(1+i-j,j)   = A(i,j) for j<=i<=min(n,j+k).
069: *          Note that the imaginary parts of the diagonal elements need
070: *          not be set and are assumed to be zero.
071: *
072: *  LDAB    (input) INTEGER
073: *          The leading dimension of the array AB.  LDAB >= K+1.
074: *
075: *  WORK    (workspace) DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
076: *          where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
077: *          WORK is not referenced.
078: *
079: * =====================================================================
080: *
081: *     .. Parameters ..
082:       DOUBLE PRECISION   ONE, ZERO
083:       PARAMETER          ( ONE = 1.0D+0, ZERO = 0.0D+0 )
084: *     ..
085: *     .. Local Scalars ..
086:       INTEGER            I, J, L
087:       DOUBLE PRECISION   ABSA, SCALE, SUM, VALUE
088: *     ..
089: *     .. External Functions ..
090:       LOGICAL            LSAME
091:       EXTERNAL           LSAME
092: *     ..
093: *     .. External Subroutines ..
094:       EXTERNAL           ZLASSQ
095: *     ..
096: *     .. Intrinsic Functions ..
097:       INTRINSIC          ABS, DBLE, MAX, MIN, SQRT
098: *     ..
099: *     .. Executable Statements ..
100: *
101:       IF( N.EQ.0 ) THEN
102:          VALUE = ZERO
103:       ELSE IF( LSAME( NORM, 'M' ) ) THEN
104: *
105: *        Find max(abs(A(i,j))).
106: *
107:          VALUE = ZERO
108:          IF( LSAME( UPLO, 'U' ) ) THEN
109:             DO 20 J = 1, N
110:                DO 10 I = MAX( K+2-J, 1 ), K
111:                   VALUE = MAX( VALUE, ABS( AB( I, J ) ) )
112:    10          CONTINUE
113:                VALUE = MAX( VALUE, ABS( DBLE( AB( K+1, J ) ) ) )
114:    20       CONTINUE
115:          ELSE
116:             DO 40 J = 1, N
117:                VALUE = MAX( VALUE, ABS( DBLE( AB( 1, J ) ) ) )
118:                DO 30 I = 2, MIN( N+1-J, K+1 )
119:                   VALUE = MAX( VALUE, ABS( AB( I, J ) ) )
120:    30          CONTINUE
121:    40       CONTINUE
122:          END IF
123:       ELSE IF( ( LSAME( NORM, 'I' ) ) .OR. ( LSAME( NORM, 'O' ) ) .OR.
124:      $         ( NORM.EQ.'1' ) ) THEN
125: *
126: *        Find normI(A) ( = norm1(A), since A is hermitian).
127: *
128:          VALUE = ZERO
129:          IF( LSAME( UPLO, 'U' ) ) THEN
130:             DO 60 J = 1, N
131:                SUM = ZERO
132:                L = K + 1 - J
133:                DO 50 I = MAX( 1, J-K ), J - 1
134:                   ABSA = ABS( AB( L+I, J ) )
135:                   SUM = SUM + ABSA
136:                   WORK( I ) = WORK( I ) + ABSA
137:    50          CONTINUE
138:                WORK( J ) = SUM + ABS( DBLE( AB( K+1, J ) ) )
139:    60       CONTINUE
140:             DO 70 I = 1, N
141:                VALUE = MAX( VALUE, WORK( I ) )
142:    70       CONTINUE
143:          ELSE
144:             DO 80 I = 1, N
145:                WORK( I ) = ZERO
146:    80       CONTINUE
147:             DO 100 J = 1, N
148:                SUM = WORK( J ) + ABS( DBLE( AB( 1, J ) ) )
149:                L = 1 - J
150:                DO 90 I = J + 1, MIN( N, J+K )
151:                   ABSA = ABS( AB( L+I, J ) )
152:                   SUM = SUM + ABSA
153:                   WORK( I ) = WORK( I ) + ABSA
154:    90          CONTINUE
155:                VALUE = MAX( VALUE, SUM )
156:   100       CONTINUE
157:          END IF
158:       ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
159: *
160: *        Find normF(A).
161: *
162:          SCALE = ZERO
163:          SUM = ONE
164:          IF( K.GT.0 ) THEN
165:             IF( LSAME( UPLO, 'U' ) ) THEN
166:                DO 110 J = 2, N
167:                   CALL ZLASSQ( MIN( J-1, K ), AB( MAX( K+2-J, 1 ), J ),
168:      $                         1, SCALE, SUM )
169:   110          CONTINUE
170:                L = K + 1
171:             ELSE
172:                DO 120 J = 1, N - 1
173:                   CALL ZLASSQ( MIN( N-J, K ), AB( 2, J ), 1, SCALE,
174:      $                         SUM )
175:   120          CONTINUE
176:                L = 1
177:             END IF
178:             SUM = 2*SUM
179:          ELSE
180:             L = 1
181:          END IF
182:          DO 130 J = 1, N
183:             IF( DBLE( AB( L, J ) ).NE.ZERO ) THEN
184:                ABSA = ABS( DBLE( AB( L, J ) ) )
185:                IF( SCALE.LT.ABSA ) THEN
186:                   SUM = ONE + SUM*( SCALE / ABSA )**2
187:                   SCALE = ABSA
188:                ELSE
189:                   SUM = SUM + ( ABSA / SCALE )**2
190:                END IF
191:             END IF
192:   130    CONTINUE
193:          VALUE = SCALE*SQRT( SUM )
194:       END IF
195: *
196:       ZLANHB = VALUE
197:       RETURN
198: *
199: *     End of ZLANHB
200: *
201:       END
202: