001:       DOUBLE PRECISION FUNCTION ZLA_GBRCOND_X( TRANS, N, KL, KU, AB, 
002:      $                             LDAB, AFB, LDAFB, IPIV, X, INFO, 
003:      $     WORK, RWORK )
004: *
005: *     -- LAPACK routine (version 3.2)                                 --
006: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
007: *     -- Jason Riedy of Univ. of California Berkeley.                 --
008: *     -- November 2008                                                --
009: *
010: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
011: *     -- Univ. of California Berkeley and NAG Ltd.                    --
012: *
013:       IMPLICIT NONE
014: *     ..
015: *     .. Scalar Arguments ..
016:       CHARACTER          TRANS
017:       INTEGER            N, KL, KU, KD, LDAB, LDAFB, INFO
018: *     ..
019: *     .. Array Arguments ..
020:       INTEGER            IPIV( * )
021:       COMPLEX*16         AB( LDAB, * ), AFB( LDAFB, * ), WORK( * ),
022:      $                   X( * )
023:       DOUBLE PRECISION   RWORK( * )
024: *
025: *     ZLA_GBRCOND_X Computes the infinity norm condition number of
026: *     op(A) * diag(X) where X is a COMPLEX*16 vector.
027: *     WORK is a COMPLEX*16 workspace of size 2*N, and
028: *     RWORK is a DOUBLE PRECISION workspace of size 3*N.
029: *     ..
030: *     .. Local Scalars ..
031:       LOGICAL            NOTRANS
032:       INTEGER            KASE, I, J
033:       DOUBLE PRECISION   AINVNM, ANORM, TMP
034:       COMPLEX*16         ZDUM
035: *     ..
036: *     .. Local Arrays ..
037:       INTEGER            ISAVE( 3 )
038: *     ..
039: *     .. External Functions ..
040:       LOGICAL            LSAME
041:       EXTERNAL           LSAME
042: *     ..
043: *     .. External Subroutines ..
044:       EXTERNAL           ZLACN2, ZGBTRS, XERBLA
045: *     ..
046: *     .. Intrinsic Functions ..
047:       INTRINSIC          ABS, MAX
048: *     ..
049: *     .. Statement Functions ..
050:       DOUBLE PRECISION   CABS1
051: *     ..
052: *     .. Statement Function Definitions ..
053:       CABS1( ZDUM ) = ABS( DBLE( ZDUM ) ) + ABS( DIMAG( ZDUM ) )
054: *     ..
055: *     .. Executable Statements ..
056: *
057:       ZLA_GBRCOND_X = 0.0D+0
058: *
059:       INFO = 0
060:       NOTRANS = LSAME( TRANS, 'N' )
061:       IF ( .NOT. NOTRANS .AND. .NOT. LSAME(TRANS, 'T') .AND. .NOT.
062:      $     LSAME( TRANS, 'C' ) ) THEN
063:          INFO = -1
064:       ELSE IF( N.LT.0 ) THEN
065:          INFO = -2
066:       END IF
067:       IF( INFO.NE.0 ) THEN
068:          CALL XERBLA( 'ZLA_GBRCOND_X', -INFO )
069:          RETURN
070:       END IF
071: *
072: *     Compute norm of op(A)*op2(C).
073: *
074:       KD = KU + 1
075:       ANORM = 0.0D+0
076:       IF ( NOTRANS ) THEN
077:          DO I = 1, N
078:             TMP = 0.0D+0
079:             DO J = 1, N
080:                IF ( I.GE.MAX( 1, J-KU ) .AND. I.LE.MIN( N, J+KL ) ) THEN
081:                   TMP = TMP + CABS1( AB( KD+I-J, J) * X( J ) )
082:                END IF
083:             END DO
084:             RWORK( 2*N+I ) = TMP
085:             ANORM = MAX( ANORM, TMP )
086:          END DO
087:       ELSE
088:          DO I = 1, N
089:             TMP = 0.0D+0
090:             DO J = 1, N
091:                IF ( I.GE.MAX( 1, J-KU ) .AND. I.LE.MIN( N, J+KL ) ) THEN
092:                   TMP = TMP + CABS1( AB( J, KD+I-J ) * X( J ) )
093:                END IF
094:             END DO
095:             RWORK( 2*N+I ) = TMP
096:             ANORM = MAX( ANORM, TMP )
097:          END DO
098:       END IF
099: *
100: *     Quick return if possible.
101: *
102:       IF( N.EQ.0 ) THEN
103:          ZLA_GBRCOND_X = 1.0D+0
104:          RETURN
105:       ELSE IF( ANORM .EQ. 0.0D+0 ) THEN
106:          RETURN
107:       END IF
108: *
109: *     Estimate the norm of inv(op(A)).
110: *
111:       AINVNM = 0.0D+0
112: *
113:       KASE = 0
114:    10 CONTINUE
115:       CALL ZLACN2( N, WORK( N+1 ), WORK, AINVNM, KASE, ISAVE )
116:       IF( KASE.NE.0 ) THEN
117:          IF( KASE.EQ.2 ) THEN
118: *
119: *           Multiply by R.
120: *
121:             DO I = 1, N
122:                WORK( I ) = WORK( I ) * RWORK( 2*N+I )
123:             END DO
124: *
125:             IF ( NOTRANS ) THEN
126:                CALL ZGBTRS( 'No transpose', N, KL, KU, 1, AFB, LDAFB,
127:      $              IPIV, WORK, N, INFO )
128:             ELSE
129:                CALL ZGBTRS( 'Conjugate transpose', N, KL, KU, 1, AFB,
130:      $              LDAFB, IPIV, WORK, N, INFO )
131:             ENDIF
132: *
133: *           Multiply by inv(X).
134: *
135:             DO I = 1, N
136:                WORK( I ) = WORK( I ) / X( I )
137:             END DO
138:          ELSE
139: *
140: *           Multiply by inv(X').
141: *
142:             DO I = 1, N
143:                WORK( I ) = WORK( I ) / X( I )
144:             END DO
145: *
146:             IF ( NOTRANS ) THEN
147:                CALL ZGBTRS( 'Conjugate transpose', N, KL, KU, 1, AFB,
148:      $              LDAFB, IPIV, WORK, N, INFO )
149:             ELSE
150:                CALL ZGBTRS( 'No transpose', N, KL, KU, 1, AFB, LDAFB,
151:      $              IPIV, WORK, N, INFO )
152:             END IF
153: *
154: *           Multiply by R.
155: *
156:             DO I = 1, N
157:                WORK( I ) = WORK( I ) * RWORK( 2*N+I )
158:             END DO
159:          END IF
160:          GO TO 10
161:       END IF
162: *
163: *     Compute the estimate of the reciprocal condition number.
164: *
165:       IF( AINVNM .NE. 0.0D+0 )
166:      $   ZLA_GBRCOND_X = 1.0D+0 / AINVNM
167: *
168:       RETURN
169: *
170:       END
171: