001:       SUBROUTINE ZGETRI( N, A, LDA, IPIV, WORK, LWORK, INFO )
002: *
003: *  -- LAPACK routine (version 3.2) --
004: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
005: *     November 2006
006: *
007: *     .. Scalar Arguments ..
008:       INTEGER            INFO, LDA, LWORK, N
009: *     ..
010: *     .. Array Arguments ..
011:       INTEGER            IPIV( * )
012:       COMPLEX*16         A( LDA, * ), WORK( * )
013: *     ..
014: *
015: *  Purpose
016: *  =======
017: *
018: *  ZGETRI computes the inverse of a matrix using the LU factorization
019: *  computed by ZGETRF.
020: *
021: *  This method inverts U and then computes inv(A) by solving the system
022: *  inv(A)*L = inv(U) for inv(A).
023: *
024: *  Arguments
025: *  =========
026: *
027: *  N       (input) INTEGER
028: *          The order of the matrix A.  N >= 0.
029: *
030: *  A       (input/output) COMPLEX*16 array, dimension (LDA,N)
031: *          On entry, the factors L and U from the factorization
032: *          A = P*L*U as computed by ZGETRF.
033: *          On exit, if INFO = 0, the inverse of the original matrix A.
034: *
035: *  LDA     (input) INTEGER
036: *          The leading dimension of the array A.  LDA >= max(1,N).
037: *
038: *  IPIV    (input) INTEGER array, dimension (N)
039: *          The pivot indices from ZGETRF; for 1<=i<=N, row i of the
040: *          matrix was interchanged with row IPIV(i).
041: *
042: *  WORK    (workspace/output) COMPLEX*16 array, dimension (MAX(1,LWORK))
043: *          On exit, if INFO=0, then WORK(1) returns the optimal LWORK.
044: *
045: *  LWORK   (input) INTEGER
046: *          The dimension of the array WORK.  LWORK >= max(1,N).
047: *          For optimal performance LWORK >= N*NB, where NB is
048: *          the optimal blocksize returned by ILAENV.
049: *
050: *          If LWORK = -1, then a workspace query is assumed; the routine
051: *          only calculates the optimal size of the WORK array, returns
052: *          this value as the first entry of the WORK array, and no error
053: *          message related to LWORK is issued by XERBLA.
054: *
055: *  INFO    (output) INTEGER
056: *          = 0:  successful exit
057: *          < 0:  if INFO = -i, the i-th argument had an illegal value
058: *          > 0:  if INFO = i, U(i,i) is exactly zero; the matrix is
059: *                singular and its inverse could not be computed.
060: *
061: *  =====================================================================
062: *
063: *     .. Parameters ..
064:       COMPLEX*16         ZERO, ONE
065:       PARAMETER          ( ZERO = ( 0.0D+0, 0.0D+0 ),
066:      $                   ONE = ( 1.0D+0, 0.0D+0 ) )
067: *     ..
068: *     .. Local Scalars ..
069:       LOGICAL            LQUERY
070:       INTEGER            I, IWS, J, JB, JJ, JP, LDWORK, LWKOPT, NB,
071:      $                   NBMIN, NN
072: *     ..
073: *     .. External Functions ..
074:       INTEGER            ILAENV
075:       EXTERNAL           ILAENV
076: *     ..
077: *     .. External Subroutines ..
078:       EXTERNAL           XERBLA, ZGEMM, ZGEMV, ZSWAP, ZTRSM, ZTRTRI
079: *     ..
080: *     .. Intrinsic Functions ..
081:       INTRINSIC          MAX, MIN
082: *     ..
083: *     .. Executable Statements ..
084: *
085: *     Test the input parameters.
086: *
087:       INFO = 0
088:       NB = ILAENV( 1, 'ZGETRI', ' ', N, -1, -1, -1 )
089:       LWKOPT = N*NB
090:       WORK( 1 ) = LWKOPT
091:       LQUERY = ( LWORK.EQ.-1 )
092:       IF( N.LT.0 ) THEN
093:          INFO = -1
094:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
095:          INFO = -3
096:       ELSE IF( LWORK.LT.MAX( 1, N ) .AND. .NOT.LQUERY ) THEN
097:          INFO = -6
098:       END IF
099:       IF( INFO.NE.0 ) THEN
100:          CALL XERBLA( 'ZGETRI', -INFO )
101:          RETURN
102:       ELSE IF( LQUERY ) THEN
103:          RETURN
104:       END IF
105: *
106: *     Quick return if possible
107: *
108:       IF( N.EQ.0 )
109:      $   RETURN
110: *
111: *     Form inv(U).  If INFO > 0 from ZTRTRI, then U is singular,
112: *     and the inverse is not computed.
113: *
114:       CALL ZTRTRI( 'Upper', 'Non-unit', N, A, LDA, INFO )
115:       IF( INFO.GT.0 )
116:      $   RETURN
117: *
118:       NBMIN = 2
119:       LDWORK = N
120:       IF( NB.GT.1 .AND. NB.LT.N ) THEN
121:          IWS = MAX( LDWORK*NB, 1 )
122:          IF( LWORK.LT.IWS ) THEN
123:             NB = LWORK / LDWORK
124:             NBMIN = MAX( 2, ILAENV( 2, 'ZGETRI', ' ', N, -1, -1, -1 ) )
125:          END IF
126:       ELSE
127:          IWS = N
128:       END IF
129: *
130: *     Solve the equation inv(A)*L = inv(U) for inv(A).
131: *
132:       IF( NB.LT.NBMIN .OR. NB.GE.N ) THEN
133: *
134: *        Use unblocked code.
135: *
136:          DO 20 J = N, 1, -1
137: *
138: *           Copy current column of L to WORK and replace with zeros.
139: *
140:             DO 10 I = J + 1, N
141:                WORK( I ) = A( I, J )
142:                A( I, J ) = ZERO
143:    10       CONTINUE
144: *
145: *           Compute current column of inv(A).
146: *
147:             IF( J.LT.N )
148:      $         CALL ZGEMV( 'No transpose', N, N-J, -ONE, A( 1, J+1 ),
149:      $                     LDA, WORK( J+1 ), 1, ONE, A( 1, J ), 1 )
150:    20    CONTINUE
151:       ELSE
152: *
153: *        Use blocked code.
154: *
155:          NN = ( ( N-1 ) / NB )*NB + 1
156:          DO 50 J = NN, 1, -NB
157:             JB = MIN( NB, N-J+1 )
158: *
159: *           Copy current block column of L to WORK and replace with
160: *           zeros.
161: *
162:             DO 40 JJ = J, J + JB - 1
163:                DO 30 I = JJ + 1, N
164:                   WORK( I+( JJ-J )*LDWORK ) = A( I, JJ )
165:                   A( I, JJ ) = ZERO
166:    30          CONTINUE
167:    40       CONTINUE
168: *
169: *           Compute current block column of inv(A).
170: *
171:             IF( J+JB.LE.N )
172:      $         CALL ZGEMM( 'No transpose', 'No transpose', N, JB,
173:      $                     N-J-JB+1, -ONE, A( 1, J+JB ), LDA,
174:      $                     WORK( J+JB ), LDWORK, ONE, A( 1, J ), LDA )
175:             CALL ZTRSM( 'Right', 'Lower', 'No transpose', 'Unit', N, JB,
176:      $                  ONE, WORK( J ), LDWORK, A( 1, J ), LDA )
177:    50    CONTINUE
178:       END IF
179: *
180: *     Apply column interchanges.
181: *
182:       DO 60 J = N - 1, 1, -1
183:          JP = IPIV( J )
184:          IF( JP.NE.J )
185:      $      CALL ZSWAP( N, A( 1, J ), 1, A( 1, JP ), 1 )
186:    60 CONTINUE
187: *
188:       WORK( 1 ) = IWS
189:       RETURN
190: *
191: *     End of ZGETRI
192: *
193:       END
194: