001:       SUBROUTINE ZGERFS( TRANS, N, NRHS, A, LDA, AF, LDAF, IPIV, B, LDB,
002:      $                   X, LDX, FERR, BERR, WORK, RWORK, INFO )
003: *
004: *  -- LAPACK routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     Modified to call ZLACN2 in place of ZLACON, 10 Feb 03, SJH.
009: *
010: *     .. Scalar Arguments ..
011:       CHARACTER          TRANS
012:       INTEGER            INFO, LDA, LDAF, LDB, LDX, N, NRHS
013: *     ..
014: *     .. Array Arguments ..
015:       INTEGER            IPIV( * )
016:       DOUBLE PRECISION   BERR( * ), FERR( * ), RWORK( * )
017:       COMPLEX*16         A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
018:      $                   WORK( * ), X( LDX, * )
019: *     ..
020: *
021: *  Purpose
022: *  =======
023: *
024: *  ZGERFS improves the computed solution to a system of linear
025: *  equations and provides error bounds and backward error estimates for
026: *  the solution.
027: *
028: *  Arguments
029: *  =========
030: *
031: *  TRANS   (input) CHARACTER*1
032: *          Specifies the form of the system of equations:
033: *          = 'N':  A * X = B     (No transpose)
034: *          = 'T':  A**T * X = B  (Transpose)
035: *          = 'C':  A**H * X = B  (Conjugate transpose)
036: *
037: *  N       (input) INTEGER
038: *          The order of the matrix A.  N >= 0.
039: *
040: *  NRHS    (input) INTEGER
041: *          The number of right hand sides, i.e., the number of columns
042: *          of the matrices B and X.  NRHS >= 0.
043: *
044: *  A       (input) COMPLEX*16 array, dimension (LDA,N)
045: *          The original N-by-N matrix A.
046: *
047: *  LDA     (input) INTEGER
048: *          The leading dimension of the array A.  LDA >= max(1,N).
049: *
050: *  AF      (input) COMPLEX*16 array, dimension (LDAF,N)
051: *          The factors L and U from the factorization A = P*L*U
052: *          as computed by ZGETRF.
053: *
054: *  LDAF    (input) INTEGER
055: *          The leading dimension of the array AF.  LDAF >= max(1,N).
056: *
057: *  IPIV    (input) INTEGER array, dimension (N)
058: *          The pivot indices from ZGETRF; for 1<=i<=N, row i of the
059: *          matrix was interchanged with row IPIV(i).
060: *
061: *  B       (input) COMPLEX*16 array, dimension (LDB,NRHS)
062: *          The right hand side matrix B.
063: *
064: *  LDB     (input) INTEGER
065: *          The leading dimension of the array B.  LDB >= max(1,N).
066: *
067: *  X       (input/output) COMPLEX*16 array, dimension (LDX,NRHS)
068: *          On entry, the solution matrix X, as computed by ZGETRS.
069: *          On exit, the improved solution matrix X.
070: *
071: *  LDX     (input) INTEGER
072: *          The leading dimension of the array X.  LDX >= max(1,N).
073: *
074: *  FERR    (output) DOUBLE PRECISION array, dimension (NRHS)
075: *          The estimated forward error bound for each solution vector
076: *          X(j) (the j-th column of the solution matrix X).
077: *          If XTRUE is the true solution corresponding to X(j), FERR(j)
078: *          is an estimated upper bound for the magnitude of the largest
079: *          element in (X(j) - XTRUE) divided by the magnitude of the
080: *          largest element in X(j).  The estimate is as reliable as
081: *          the estimate for RCOND, and is almost always a slight
082: *          overestimate of the true error.
083: *
084: *  BERR    (output) DOUBLE PRECISION array, dimension (NRHS)
085: *          The componentwise relative backward error of each solution
086: *          vector X(j) (i.e., the smallest relative change in
087: *          any element of A or B that makes X(j) an exact solution).
088: *
089: *  WORK    (workspace) COMPLEX*16 array, dimension (2*N)
090: *
091: *  RWORK   (workspace) DOUBLE PRECISION array, dimension (N)
092: *
093: *  INFO    (output) INTEGER
094: *          = 0:  successful exit
095: *          < 0:  if INFO = -i, the i-th argument had an illegal value
096: *
097: *  Internal Parameters
098: *  ===================
099: *
100: *  ITMAX is the maximum number of steps of iterative refinement.
101: *
102: *  =====================================================================
103: *
104: *     .. Parameters ..
105:       INTEGER            ITMAX
106:       PARAMETER          ( ITMAX = 5 )
107:       DOUBLE PRECISION   ZERO
108:       PARAMETER          ( ZERO = 0.0D+0 )
109:       COMPLEX*16         ONE
110:       PARAMETER          ( ONE = ( 1.0D+0, 0.0D+0 ) )
111:       DOUBLE PRECISION   TWO
112:       PARAMETER          ( TWO = 2.0D+0 )
113:       DOUBLE PRECISION   THREE
114:       PARAMETER          ( THREE = 3.0D+0 )
115: *     ..
116: *     .. Local Scalars ..
117:       LOGICAL            NOTRAN
118:       CHARACTER          TRANSN, TRANST
119:       INTEGER            COUNT, I, J, K, KASE, NZ
120:       DOUBLE PRECISION   EPS, LSTRES, S, SAFE1, SAFE2, SAFMIN, XK
121:       COMPLEX*16         ZDUM
122: *     ..
123: *     .. Local Arrays ..
124:       INTEGER            ISAVE( 3 )
125: *     ..
126: *     .. External Functions ..
127:       LOGICAL            LSAME
128:       DOUBLE PRECISION   DLAMCH
129:       EXTERNAL           LSAME, DLAMCH
130: *     ..
131: *     .. External Subroutines ..
132:       EXTERNAL           XERBLA, ZAXPY, ZCOPY, ZGEMV, ZGETRS, ZLACN2
133: *     ..
134: *     .. Intrinsic Functions ..
135:       INTRINSIC          ABS, DBLE, DIMAG, MAX
136: *     ..
137: *     .. Statement Functions ..
138:       DOUBLE PRECISION   CABS1
139: *     ..
140: *     .. Statement Function definitions ..
141:       CABS1( ZDUM ) = ABS( DBLE( ZDUM ) ) + ABS( DIMAG( ZDUM ) )
142: *     ..
143: *     .. Executable Statements ..
144: *
145: *     Test the input parameters.
146: *
147:       INFO = 0
148:       NOTRAN = LSAME( TRANS, 'N' )
149:       IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) .AND. .NOT.
150:      $    LSAME( TRANS, 'C' ) ) THEN
151:          INFO = -1
152:       ELSE IF( N.LT.0 ) THEN
153:          INFO = -2
154:       ELSE IF( NRHS.LT.0 ) THEN
155:          INFO = -3
156:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
157:          INFO = -5
158:       ELSE IF( LDAF.LT.MAX( 1, N ) ) THEN
159:          INFO = -7
160:       ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
161:          INFO = -10
162:       ELSE IF( LDX.LT.MAX( 1, N ) ) THEN
163:          INFO = -12
164:       END IF
165:       IF( INFO.NE.0 ) THEN
166:          CALL XERBLA( 'ZGERFS', -INFO )
167:          RETURN
168:       END IF
169: *
170: *     Quick return if possible
171: *
172:       IF( N.EQ.0 .OR. NRHS.EQ.0 ) THEN
173:          DO 10 J = 1, NRHS
174:             FERR( J ) = ZERO
175:             BERR( J ) = ZERO
176:    10    CONTINUE
177:          RETURN
178:       END IF
179: *
180:       IF( NOTRAN ) THEN
181:          TRANSN = 'N'
182:          TRANST = 'C'
183:       ELSE
184:          TRANSN = 'C'
185:          TRANST = 'N'
186:       END IF
187: *
188: *     NZ = maximum number of nonzero elements in each row of A, plus 1
189: *
190:       NZ = N + 1
191:       EPS = DLAMCH( 'Epsilon' )
192:       SAFMIN = DLAMCH( 'Safe minimum' )
193:       SAFE1 = NZ*SAFMIN
194:       SAFE2 = SAFE1 / EPS
195: *
196: *     Do for each right hand side
197: *
198:       DO 140 J = 1, NRHS
199: *
200:          COUNT = 1
201:          LSTRES = THREE
202:    20    CONTINUE
203: *
204: *        Loop until stopping criterion is satisfied.
205: *
206: *        Compute residual R = B - op(A) * X,
207: *        where op(A) = A, A**T, or A**H, depending on TRANS.
208: *
209:          CALL ZCOPY( N, B( 1, J ), 1, WORK, 1 )
210:          CALL ZGEMV( TRANS, N, N, -ONE, A, LDA, X( 1, J ), 1, ONE, WORK,
211:      $               1 )
212: *
213: *        Compute componentwise relative backward error from formula
214: *
215: *        max(i) ( abs(R(i)) / ( abs(op(A))*abs(X) + abs(B) )(i) )
216: *
217: *        where abs(Z) is the componentwise absolute value of the matrix
218: *        or vector Z.  If the i-th component of the denominator is less
219: *        than SAFE2, then SAFE1 is added to the i-th components of the
220: *        numerator and denominator before dividing.
221: *
222:          DO 30 I = 1, N
223:             RWORK( I ) = CABS1( B( I, J ) )
224:    30    CONTINUE
225: *
226: *        Compute abs(op(A))*abs(X) + abs(B).
227: *
228:          IF( NOTRAN ) THEN
229:             DO 50 K = 1, N
230:                XK = CABS1( X( K, J ) )
231:                DO 40 I = 1, N
232:                   RWORK( I ) = RWORK( I ) + CABS1( A( I, K ) )*XK
233:    40          CONTINUE
234:    50       CONTINUE
235:          ELSE
236:             DO 70 K = 1, N
237:                S = ZERO
238:                DO 60 I = 1, N
239:                   S = S + CABS1( A( I, K ) )*CABS1( X( I, J ) )
240:    60          CONTINUE
241:                RWORK( K ) = RWORK( K ) + S
242:    70       CONTINUE
243:          END IF
244:          S = ZERO
245:          DO 80 I = 1, N
246:             IF( RWORK( I ).GT.SAFE2 ) THEN
247:                S = MAX( S, CABS1( WORK( I ) ) / RWORK( I ) )
248:             ELSE
249:                S = MAX( S, ( CABS1( WORK( I ) )+SAFE1 ) /
250:      $             ( RWORK( I )+SAFE1 ) )
251:             END IF
252:    80    CONTINUE
253:          BERR( J ) = S
254: *
255: *        Test stopping criterion. Continue iterating if
256: *           1) The residual BERR(J) is larger than machine epsilon, and
257: *           2) BERR(J) decreased by at least a factor of 2 during the
258: *              last iteration, and
259: *           3) At most ITMAX iterations tried.
260: *
261:          IF( BERR( J ).GT.EPS .AND. TWO*BERR( J ).LE.LSTRES .AND.
262:      $       COUNT.LE.ITMAX ) THEN
263: *
264: *           Update solution and try again.
265: *
266:             CALL ZGETRS( TRANS, N, 1, AF, LDAF, IPIV, WORK, N, INFO )
267:             CALL ZAXPY( N, ONE, WORK, 1, X( 1, J ), 1 )
268:             LSTRES = BERR( J )
269:             COUNT = COUNT + 1
270:             GO TO 20
271:          END IF
272: *
273: *        Bound error from formula
274: *
275: *        norm(X - XTRUE) / norm(X) .le. FERR =
276: *        norm( abs(inv(op(A)))*
277: *           ( abs(R) + NZ*EPS*( abs(op(A))*abs(X)+abs(B) ))) / norm(X)
278: *
279: *        where
280: *          norm(Z) is the magnitude of the largest component of Z
281: *          inv(op(A)) is the inverse of op(A)
282: *          abs(Z) is the componentwise absolute value of the matrix or
283: *             vector Z
284: *          NZ is the maximum number of nonzeros in any row of A, plus 1
285: *          EPS is machine epsilon
286: *
287: *        The i-th component of abs(R)+NZ*EPS*(abs(op(A))*abs(X)+abs(B))
288: *        is incremented by SAFE1 if the i-th component of
289: *        abs(op(A))*abs(X) + abs(B) is less than SAFE2.
290: *
291: *        Use ZLACN2 to estimate the infinity-norm of the matrix
292: *           inv(op(A)) * diag(W),
293: *        where W = abs(R) + NZ*EPS*( abs(op(A))*abs(X)+abs(B) )))
294: *
295:          DO 90 I = 1, N
296:             IF( RWORK( I ).GT.SAFE2 ) THEN
297:                RWORK( I ) = CABS1( WORK( I ) ) + NZ*EPS*RWORK( I )
298:             ELSE
299:                RWORK( I ) = CABS1( WORK( I ) ) + NZ*EPS*RWORK( I ) +
300:      $                      SAFE1
301:             END IF
302:    90    CONTINUE
303: *
304:          KASE = 0
305:   100    CONTINUE
306:          CALL ZLACN2( N, WORK( N+1 ), WORK, FERR( J ), KASE, ISAVE )
307:          IF( KASE.NE.0 ) THEN
308:             IF( KASE.EQ.1 ) THEN
309: *
310: *              Multiply by diag(W)*inv(op(A)**H).
311: *
312:                CALL ZGETRS( TRANST, N, 1, AF, LDAF, IPIV, WORK, N,
313:      $                      INFO )
314:                DO 110 I = 1, N
315:                   WORK( I ) = RWORK( I )*WORK( I )
316:   110          CONTINUE
317:             ELSE
318: *
319: *              Multiply by inv(op(A))*diag(W).
320: *
321:                DO 120 I = 1, N
322:                   WORK( I ) = RWORK( I )*WORK( I )
323:   120          CONTINUE
324:                CALL ZGETRS( TRANSN, N, 1, AF, LDAF, IPIV, WORK, N,
325:      $                      INFO )
326:             END IF
327:             GO TO 100
328:          END IF
329: *
330: *        Normalize error.
331: *
332:          LSTRES = ZERO
333:          DO 130 I = 1, N
334:             LSTRES = MAX( LSTRES, CABS1( X( I, J ) ) )
335:   130    CONTINUE
336:          IF( LSTRES.NE.ZERO )
337:      $      FERR( J ) = FERR( J ) / LSTRES
338: *
339:   140 CONTINUE
340: *
341:       RETURN
342: *
343: *     End of ZGERFS
344: *
345:       END
346: