```01:       SUBROUTINE ZAXPY(N,ZA,ZX,INCX,ZY,INCY)
02: *     .. Scalar Arguments ..
03:       DOUBLE COMPLEX ZA
04:       INTEGER INCX,INCY,N
05: *     ..
06: *     .. Array Arguments ..
07:       DOUBLE COMPLEX ZX(*),ZY(*)
08: *     ..
09: *
10: *  Purpose
11: *  =======
12: *
13: *     constant times a vector plus a vector.
14: *     jack dongarra, 3/11/78.
15: *     modified 12/3/93, array(1) declarations changed to array(*)
16: *
17:
18: *     .. Local Scalars ..
19:       INTEGER I,IX,IY
20: *     ..
21: *     .. External Functions ..
22:       DOUBLE PRECISION DCABS1
23:       EXTERNAL DCABS1
24: *     ..
25:       IF (N.LE.0) RETURN
26:       IF (DCABS1(ZA).EQ.0.0d0) RETURN
27:       IF (INCX.EQ.1 .AND. INCY.EQ.1) GO TO 20
28: *
29: *        code for unequal increments or equal increments
30: *          not equal to 1
31: *
32:       IX = 1
33:       IY = 1
34:       IF (INCX.LT.0) IX = (-N+1)*INCX + 1
35:       IF (INCY.LT.0) IY = (-N+1)*INCY + 1
36:       DO 10 I = 1,N
37:           ZY(IY) = ZY(IY) + ZA*ZX(IX)
38:           IX = IX + INCX
39:           IY = IY + INCY
40:    10 CONTINUE
41:       RETURN
42: *
43: *        code for both increments equal to 1
44: *
45:    20 DO 30 I = 1,N
46:           ZY(I) = ZY(I) + ZA*ZX(I)
47:    30 CONTINUE
48:       RETURN
49:       END
50: ```