001:       SUBROUTINE STPSV(UPLO,TRANS,DIAG,N,AP,X,INCX)
002: *     .. Scalar Arguments ..
003:       INTEGER INCX,N
004:       CHARACTER DIAG,TRANS,UPLO
005: *     ..
006: *     .. Array Arguments ..
007:       REAL AP(*),X(*)
008: *     ..
009: *
010: *  Purpose
011: *  =======
012: *
013: *  STPSV  solves one of the systems of equations
014: *
015: *     A*x = b,   or   A'*x = b,
016: *
017: *  where b and x are n element vectors and A is an n by n unit, or
018: *  non-unit, upper or lower triangular matrix, supplied in packed form.
019: *
020: *  No test for singularity or near-singularity is included in this
021: *  routine. Such tests must be performed before calling this routine.
022: *
023: *  Arguments
024: *  ==========
025: *
026: *  UPLO   - CHARACTER*1.
027: *           On entry, UPLO specifies whether the matrix is an upper or
028: *           lower triangular matrix as follows:
029: *
030: *              UPLO = 'U' or 'u'   A is an upper triangular matrix.
031: *
032: *              UPLO = 'L' or 'l'   A is a lower triangular matrix.
033: *
034: *           Unchanged on exit.
035: *
036: *  TRANS  - CHARACTER*1.
037: *           On entry, TRANS specifies the equations to be solved as
038: *           follows:
039: *
040: *              TRANS = 'N' or 'n'   A*x = b.
041: *
042: *              TRANS = 'T' or 't'   A'*x = b.
043: *
044: *              TRANS = 'C' or 'c'   A'*x = b.
045: *
046: *           Unchanged on exit.
047: *
048: *  DIAG   - CHARACTER*1.
049: *           On entry, DIAG specifies whether or not A is unit
050: *           triangular as follows:
051: *
052: *              DIAG = 'U' or 'u'   A is assumed to be unit triangular.
053: *
054: *              DIAG = 'N' or 'n'   A is not assumed to be unit
055: *                                  triangular.
056: *
057: *           Unchanged on exit.
058: *
059: *  N      - INTEGER.
060: *           On entry, N specifies the order of the matrix A.
061: *           N must be at least zero.
062: *           Unchanged on exit.
063: *
064: *  AP     - REAL             array of DIMENSION at least
065: *           ( ( n*( n + 1 ) )/2 ).
066: *           Before entry with  UPLO = 'U' or 'u', the array AP must
067: *           contain the upper triangular matrix packed sequentially,
068: *           column by column, so that AP( 1 ) contains a( 1, 1 ),
069: *           AP( 2 ) and AP( 3 ) contain a( 1, 2 ) and a( 2, 2 )
070: *           respectively, and so on.
071: *           Before entry with UPLO = 'L' or 'l', the array AP must
072: *           contain the lower triangular matrix packed sequentially,
073: *           column by column, so that AP( 1 ) contains a( 1, 1 ),
074: *           AP( 2 ) and AP( 3 ) contain a( 2, 1 ) and a( 3, 1 )
075: *           respectively, and so on.
076: *           Note that when  DIAG = 'U' or 'u', the diagonal elements of
077: *           A are not referenced, but are assumed to be unity.
078: *           Unchanged on exit.
079: *
080: *  X      - REAL             array of dimension at least
081: *           ( 1 + ( n - 1 )*abs( INCX ) ).
082: *           Before entry, the incremented array X must contain the n
083: *           element right-hand side vector b. On exit, X is overwritten
084: *           with the solution vector x.
085: *
086: *  INCX   - INTEGER.
087: *           On entry, INCX specifies the increment for the elements of
088: *           X. INCX must not be zero.
089: *           Unchanged on exit.
090: *
091: *
092: *  Level 2 Blas routine.
093: *
094: *  -- Written on 22-October-1986.
095: *     Jack Dongarra, Argonne National Lab.
096: *     Jeremy Du Croz, Nag Central Office.
097: *     Sven Hammarling, Nag Central Office.
098: *     Richard Hanson, Sandia National Labs.
099: *
100: *
101: *     .. Parameters ..
102:       REAL ZERO
103:       PARAMETER (ZERO=0.0E+0)
104: *     ..
105: *     .. Local Scalars ..
106:       REAL TEMP
107:       INTEGER I,INFO,IX,J,JX,K,KK,KX
108:       LOGICAL NOUNIT
109: *     ..
110: *     .. External Functions ..
111:       LOGICAL LSAME
112:       EXTERNAL LSAME
113: *     ..
114: *     .. External Subroutines ..
115:       EXTERNAL XERBLA
116: *     ..
117: *
118: *     Test the input parameters.
119: *
120:       INFO = 0
121:       IF (.NOT.LSAME(UPLO,'U') .AND. .NOT.LSAME(UPLO,'L')) THEN
122:           INFO = 1
123:       ELSE IF (.NOT.LSAME(TRANS,'N') .AND. .NOT.LSAME(TRANS,'T') .AND.
124:      +         .NOT.LSAME(TRANS,'C')) THEN
125:           INFO = 2
126:       ELSE IF (.NOT.LSAME(DIAG,'U') .AND. .NOT.LSAME(DIAG,'N')) THEN
127:           INFO = 3
128:       ELSE IF (N.LT.0) THEN
129:           INFO = 4
130:       ELSE IF (INCX.EQ.0) THEN
131:           INFO = 7
132:       END IF
133:       IF (INFO.NE.0) THEN
134:           CALL XERBLA('STPSV ',INFO)
135:           RETURN
136:       END IF
137: *
138: *     Quick return if possible.
139: *
140:       IF (N.EQ.0) RETURN
141: *
142:       NOUNIT = LSAME(DIAG,'N')
143: *
144: *     Set up the start point in X if the increment is not unity. This
145: *     will be  ( N - 1 )*INCX  too small for descending loops.
146: *
147:       IF (INCX.LE.0) THEN
148:           KX = 1 - (N-1)*INCX
149:       ELSE IF (INCX.NE.1) THEN
150:           KX = 1
151:       END IF
152: *
153: *     Start the operations. In this version the elements of AP are
154: *     accessed sequentially with one pass through AP.
155: *
156:       IF (LSAME(TRANS,'N')) THEN
157: *
158: *        Form  x := inv( A )*x.
159: *
160:           IF (LSAME(UPLO,'U')) THEN
161:               KK = (N* (N+1))/2
162:               IF (INCX.EQ.1) THEN
163:                   DO 20 J = N,1,-1
164:                       IF (X(J).NE.ZERO) THEN
165:                           IF (NOUNIT) X(J) = X(J)/AP(KK)
166:                           TEMP = X(J)
167:                           K = KK - 1
168:                           DO 10 I = J - 1,1,-1
169:                               X(I) = X(I) - TEMP*AP(K)
170:                               K = K - 1
171:    10                     CONTINUE
172:                       END IF
173:                       KK = KK - J
174:    20             CONTINUE
175:               ELSE
176:                   JX = KX + (N-1)*INCX
177:                   DO 40 J = N,1,-1
178:                       IF (X(JX).NE.ZERO) THEN
179:                           IF (NOUNIT) X(JX) = X(JX)/AP(KK)
180:                           TEMP = X(JX)
181:                           IX = JX
182:                           DO 30 K = KK - 1,KK - J + 1,-1
183:                               IX = IX - INCX
184:                               X(IX) = X(IX) - TEMP*AP(K)
185:    30                     CONTINUE
186:                       END IF
187:                       JX = JX - INCX
188:                       KK = KK - J
189:    40             CONTINUE
190:               END IF
191:           ELSE
192:               KK = 1
193:               IF (INCX.EQ.1) THEN
194:                   DO 60 J = 1,N
195:                       IF (X(J).NE.ZERO) THEN
196:                           IF (NOUNIT) X(J) = X(J)/AP(KK)
197:                           TEMP = X(J)
198:                           K = KK + 1
199:                           DO 50 I = J + 1,N
200:                               X(I) = X(I) - TEMP*AP(K)
201:                               K = K + 1
202:    50                     CONTINUE
203:                       END IF
204:                       KK = KK + (N-J+1)
205:    60             CONTINUE
206:               ELSE
207:                   JX = KX
208:                   DO 80 J = 1,N
209:                       IF (X(JX).NE.ZERO) THEN
210:                           IF (NOUNIT) X(JX) = X(JX)/AP(KK)
211:                           TEMP = X(JX)
212:                           IX = JX
213:                           DO 70 K = KK + 1,KK + N - J
214:                               IX = IX + INCX
215:                               X(IX) = X(IX) - TEMP*AP(K)
216:    70                     CONTINUE
217:                       END IF
218:                       JX = JX + INCX
219:                       KK = KK + (N-J+1)
220:    80             CONTINUE
221:               END IF
222:           END IF
223:       ELSE
224: *
225: *        Form  x := inv( A' )*x.
226: *
227:           IF (LSAME(UPLO,'U')) THEN
228:               KK = 1
229:               IF (INCX.EQ.1) THEN
230:                   DO 100 J = 1,N
231:                       TEMP = X(J)
232:                       K = KK
233:                       DO 90 I = 1,J - 1
234:                           TEMP = TEMP - AP(K)*X(I)
235:                           K = K + 1
236:    90                 CONTINUE
237:                       IF (NOUNIT) TEMP = TEMP/AP(KK+J-1)
238:                       X(J) = TEMP
239:                       KK = KK + J
240:   100             CONTINUE
241:               ELSE
242:                   JX = KX
243:                   DO 120 J = 1,N
244:                       TEMP = X(JX)
245:                       IX = KX
246:                       DO 110 K = KK,KK + J - 2
247:                           TEMP = TEMP - AP(K)*X(IX)
248:                           IX = IX + INCX
249:   110                 CONTINUE
250:                       IF (NOUNIT) TEMP = TEMP/AP(KK+J-1)
251:                       X(JX) = TEMP
252:                       JX = JX + INCX
253:                       KK = KK + J
254:   120             CONTINUE
255:               END IF
256:           ELSE
257:               KK = (N* (N+1))/2
258:               IF (INCX.EQ.1) THEN
259:                   DO 140 J = N,1,-1
260:                       TEMP = X(J)
261:                       K = KK
262:                       DO 130 I = N,J + 1,-1
263:                           TEMP = TEMP - AP(K)*X(I)
264:                           K = K - 1
265:   130                 CONTINUE
266:                       IF (NOUNIT) TEMP = TEMP/AP(KK-N+J)
267:                       X(J) = TEMP
268:                       KK = KK - (N-J+1)
269:   140             CONTINUE
270:               ELSE
271:                   KX = KX + (N-1)*INCX
272:                   JX = KX
273:                   DO 160 J = N,1,-1
274:                       TEMP = X(JX)
275:                       IX = KX
276:                       DO 150 K = KK,KK - (N- (J+1)),-1
277:                           TEMP = TEMP - AP(K)*X(IX)
278:                           IX = IX - INCX
279:   150                 CONTINUE
280:                       IF (NOUNIT) TEMP = TEMP/AP(KK-N+J)
281:                       X(JX) = TEMP
282:                       JX = JX - INCX
283:                       KK = KK - (N-J+1)
284:   160             CONTINUE
285:               END IF
286:           END IF
287:       END IF
288: *
289:       RETURN
290: *
291: *     End of STPSV .
292: *
293:       END
294: