001:       SUBROUTINE SLARFT( DIRECT, STOREV, N, K, V, LDV, TAU, T, LDT )
002:       IMPLICIT NONE
003: *
004: *  -- LAPACK auxiliary routine (version 3.2) --
005: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
006: *     November 2006
007: *
008: *     .. Scalar Arguments ..
009:       CHARACTER          DIRECT, STOREV
010:       INTEGER            K, LDT, LDV, N
011: *     ..
012: *     .. Array Arguments ..
013:       REAL               T( LDT, * ), TAU( * ), V( LDV, * )
014: *     ..
015: *
016: *  Purpose
017: *  =======
018: *
019: *  SLARFT forms the triangular factor T of a real block reflector H
020: *  of order n, which is defined as a product of k elementary reflectors.
021: *
022: *  If DIRECT = 'F', H = H(1) H(2) . . . H(k) and T is upper triangular;
023: *
024: *  If DIRECT = 'B', H = H(k) . . . H(2) H(1) and T is lower triangular.
025: *
026: *  If STOREV = 'C', the vector which defines the elementary reflector
027: *  H(i) is stored in the i-th column of the array V, and
028: *
029: *     H  =  I - V * T * V'
030: *
031: *  If STOREV = 'R', the vector which defines the elementary reflector
032: *  H(i) is stored in the i-th row of the array V, and
033: *
034: *     H  =  I - V' * T * V
035: *
036: *  Arguments
037: *  =========
038: *
039: *  DIRECT  (input) CHARACTER*1
040: *          Specifies the order in which the elementary reflectors are
041: *          multiplied to form the block reflector:
042: *          = 'F': H = H(1) H(2) . . . H(k) (Forward)
043: *          = 'B': H = H(k) . . . H(2) H(1) (Backward)
044: *
045: *  STOREV  (input) CHARACTER*1
046: *          Specifies how the vectors which define the elementary
047: *          reflectors are stored (see also Further Details):
048: *          = 'C': columnwise
049: *          = 'R': rowwise
050: *
051: *  N       (input) INTEGER
052: *          The order of the block reflector H. N >= 0.
053: *
054: *  K       (input) INTEGER
055: *          The order of the triangular factor T (= the number of
056: *          elementary reflectors). K >= 1.
057: *
058: *  V       (input/output) REAL array, dimension
059: *                               (LDV,K) if STOREV = 'C'
060: *                               (LDV,N) if STOREV = 'R'
061: *          The matrix V. See further details.
062: *
063: *  LDV     (input) INTEGER
064: *          The leading dimension of the array V.
065: *          If STOREV = 'C', LDV >= max(1,N); if STOREV = 'R', LDV >= K.
066: *
067: *  TAU     (input) REAL array, dimension (K)
068: *          TAU(i) must contain the scalar factor of the elementary
069: *          reflector H(i).
070: *
071: *  T       (output) REAL array, dimension (LDT,K)
072: *          The k by k triangular factor T of the block reflector.
073: *          If DIRECT = 'F', T is upper triangular; if DIRECT = 'B', T is
074: *          lower triangular. The rest of the array is not used.
075: *
076: *  LDT     (input) INTEGER
077: *          The leading dimension of the array T. LDT >= K.
078: *
079: *  Further Details
080: *  ===============
081: *
082: *  The shape of the matrix V and the storage of the vectors which define
083: *  the H(i) is best illustrated by the following example with n = 5 and
084: *  k = 3. The elements equal to 1 are not stored; the corresponding
085: *  array elements are modified but restored on exit. The rest of the
086: *  array is not used.
087: *
088: *  DIRECT = 'F' and STOREV = 'C':         DIRECT = 'F' and STOREV = 'R':
089: *
090: *               V = (  1       )                 V = (  1 v1 v1 v1 v1 )
091: *                   ( v1  1    )                     (     1 v2 v2 v2 )
092: *                   ( v1 v2  1 )                     (        1 v3 v3 )
093: *                   ( v1 v2 v3 )
094: *                   ( v1 v2 v3 )
095: *
096: *  DIRECT = 'B' and STOREV = 'C':         DIRECT = 'B' and STOREV = 'R':
097: *
098: *               V = ( v1 v2 v3 )                 V = ( v1 v1  1       )
099: *                   ( v1 v2 v3 )                     ( v2 v2 v2  1    )
100: *                   (  1 v2 v3 )                     ( v3 v3 v3 v3  1 )
101: *                   (     1 v3 )
102: *                   (        1 )
103: *
104: *  =====================================================================
105: *
106: *     .. Parameters ..
107:       REAL               ONE, ZERO
108:       PARAMETER          ( ONE = 1.0E+0, ZERO = 0.0E+0 )
109: *     ..
110: *     .. Local Scalars ..
111:       INTEGER            I, J, PREVLASTV, LASTV
112:       REAL               VII
113: *     ..
114: *     .. External Subroutines ..
115:       EXTERNAL           SGEMV, STRMV
116: *     ..
117: *     .. External Functions ..
118:       LOGICAL            LSAME
119:       EXTERNAL           LSAME
120: *     ..
121: *     .. Executable Statements ..
122: *
123: *     Quick return if possible
124: *
125:       IF( N.EQ.0 )
126:      $   RETURN
127: *
128:       IF( LSAME( DIRECT, 'F' ) ) THEN
129:          PREVLASTV = N
130:          DO 20 I = 1, K
131:             PREVLASTV = MAX( I, PREVLASTV )
132:             IF( TAU( I ).EQ.ZERO ) THEN
133: *
134: *              H(i)  =  I
135: *
136:                DO 10 J = 1, I
137:                   T( J, I ) = ZERO
138:    10          CONTINUE
139:             ELSE
140: *
141: *              general case
142: *
143:                VII = V( I, I )
144:                V( I, I ) = ONE
145:                IF( LSAME( STOREV, 'C' ) ) THEN
146: !                 Skip any trailing zeros.
147:                   DO LASTV = N, I+1, -1
148:                      IF( V( LASTV, I ).NE.ZERO ) EXIT
149:                   END DO
150:                   J = MIN( LASTV, PREVLASTV )
151: *
152: *                 T(1:i-1,i) := - tau(i) * V(i:j,1:i-1)' * V(i:j,i)
153: *
154:                   CALL SGEMV( 'Transpose', J-I+1, I-1, -TAU( I ),
155:      $                        V( I, 1 ), LDV, V( I, I ), 1, ZERO,
156:      $                        T( 1, I ), 1 )
157:                ELSE
158: !                 Skip any trailing zeros.
159:                   DO LASTV = N, I+1, -1
160:                      IF( V( I, LASTV ).NE.ZERO ) EXIT
161:                   END DO
162:                   J = MIN( LASTV, PREVLASTV )
163: *
164: *                 T(1:i-1,i) := - tau(i) * V(1:i-1,i:j) * V(i,i:j)'
165: *
166:                   CALL SGEMV( 'No transpose', I-1, J-I+1, -TAU( I ),
167:      $                        V( 1, I ), LDV, V( I, I ), LDV, ZERO,
168:      $                        T( 1, I ), 1 )
169:                END IF
170:                V( I, I ) = VII
171: *
172: *              T(1:i-1,i) := T(1:i-1,1:i-1) * T(1:i-1,i)
173: *
174:                CALL STRMV( 'Upper', 'No transpose', 'Non-unit', I-1, T,
175:      $                     LDT, T( 1, I ), 1 )
176:                T( I, I ) = TAU( I )
177:                IF( I.GT.1 ) THEN
178:                   PREVLASTV = MAX( PREVLASTV, LASTV )
179:                ELSE
180:                   PREVLASTV = LASTV
181:                END IF
182:             END IF
183:    20    CONTINUE
184:       ELSE
185:          PREVLASTV = 1
186:          DO 40 I = K, 1, -1
187:             IF( TAU( I ).EQ.ZERO ) THEN
188: *
189: *              H(i)  =  I
190: *
191:                DO 30 J = I, K
192:                   T( J, I ) = ZERO
193:    30          CONTINUE
194:             ELSE
195: *
196: *              general case
197: *
198:                IF( I.LT.K ) THEN
199:                   IF( LSAME( STOREV, 'C' ) ) THEN
200:                      VII = V( N-K+I, I )
201:                      V( N-K+I, I ) = ONE
202: !                    Skip any leading zeros.
203:                      DO LASTV = 1, I-1
204:                         IF( V( LASTV, I ).NE.ZERO ) EXIT
205:                      END DO
206:                      J = MAX( LASTV, PREVLASTV )
207: *
208: *                    T(i+1:k,i) :=
209: *                            - tau(i) * V(j:n-k+i,i+1:k)' * V(j:n-k+i,i)
210: *
211:                      CALL SGEMV( 'Transpose', N-K+I-J+1, K-I, -TAU( I ),
212:      $                           V( J, I+1 ), LDV, V( J, I ), 1, ZERO,
213:      $                           T( I+1, I ), 1 )
214:                      V( N-K+I, I ) = VII
215:                   ELSE
216:                      VII = V( I, N-K+I )
217:                      V( I, N-K+I ) = ONE
218: !                    Skip any leading zeros.
219:                      DO LASTV = 1, I-1
220:                         IF( V( I, LASTV ).NE.ZERO ) EXIT
221:                      END DO
222:                      J = MAX( LASTV, PREVLASTV )
223: *
224: *                    T(i+1:k,i) :=
225: *                            - tau(i) * V(i+1:k,j:n-k+i) * V(i,j:n-k+i)'
226: *
227:                      CALL SGEMV( 'No transpose', K-I, N-K+I-J+1,
228:      $                    -TAU( I ), V( I+1, J ), LDV, V( I, J ), LDV,
229:      $                    ZERO, T( I+1, I ), 1 )
230:                      V( I, N-K+I ) = VII
231:                   END IF
232: *
233: *                 T(i+1:k,i) := T(i+1:k,i+1:k) * T(i+1:k,i)
234: *
235:                   CALL STRMV( 'Lower', 'No transpose', 'Non-unit', K-I,
236:      $                        T( I+1, I+1 ), LDT, T( I+1, I ), 1 )
237:                   IF( I.GT.1 ) THEN
238:                      PREVLASTV = MIN( PREVLASTV, LASTV )
239:                   ELSE
240:                      PREVLASTV = LASTV
241:                   END IF
242:                END IF
243:                T( I, I ) = TAU( I )
244:             END IF
245:    40    CONTINUE
246:       END IF
247:       RETURN
248: *
249: *     End of SLARFT
250: *
251:       END
252: