001:       REAL             FUNCTION SLANGE( NORM, M, N, A, LDA, WORK )
002: *
003: *  -- LAPACK auxiliary routine (version 3.2) --
004: *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
005: *     November 2006
006: *
007: *     .. Scalar Arguments ..
008:       CHARACTER          NORM
009:       INTEGER            LDA, M, N
010: *     ..
011: *     .. Array Arguments ..
012:       REAL               A( LDA, * ), WORK( * )
013: *     ..
014: *
015: *  Purpose
016: *  =======
017: *
018: *  SLANGE  returns the value of the one norm,  or the Frobenius norm, or
019: *  the  infinity norm,  or the  element of  largest absolute value  of a
020: *  real matrix A.
021: *
022: *  Description
023: *  ===========
024: *
025: *  SLANGE returns the value
026: *
027: *     SLANGE = ( max(abs(A(i,j))), NORM = 'M' or 'm'
028: *              (
029: *              ( norm1(A),         NORM = '1', 'O' or 'o'
030: *              (
031: *              ( normI(A),         NORM = 'I' or 'i'
032: *              (
033: *              ( normF(A),         NORM = 'F', 'f', 'E' or 'e'
034: *
035: *  where  norm1  denotes the  one norm of a matrix (maximum column sum),
036: *  normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
037: *  normF  denotes the  Frobenius norm of a matrix (square root of sum of
038: *  squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
039: *
040: *  Arguments
041: *  =========
042: *
043: *  NORM    (input) CHARACTER*1
044: *          Specifies the value to be returned in SLANGE as described
045: *          above.
046: *
047: *  M       (input) INTEGER
048: *          The number of rows of the matrix A.  M >= 0.  When M = 0,
049: *          SLANGE is set to zero.
050: *
051: *  N       (input) INTEGER
052: *          The number of columns of the matrix A.  N >= 0.  When N = 0,
053: *          SLANGE is set to zero.
054: *
055: *  A       (input) REAL array, dimension (LDA,N)
056: *          The m by n matrix A.
057: *
058: *  LDA     (input) INTEGER
059: *          The leading dimension of the array A.  LDA >= max(M,1).
060: *
061: *  WORK    (workspace) REAL array, dimension (MAX(1,LWORK)),
062: *          where LWORK >= M when NORM = 'I'; otherwise, WORK is not
063: *          referenced.
064: *
065: * =====================================================================
066: *
067: *     .. Parameters ..
068:       REAL               ONE, ZERO
069:       PARAMETER          ( ONE = 1.0E+0, ZERO = 0.0E+0 )
070: *     ..
071: *     .. Local Scalars ..
072:       INTEGER            I, J
073:       REAL               SCALE, SUM, VALUE
074: *     ..
075: *     .. External Subroutines ..
076:       EXTERNAL           SLASSQ
077: *     ..
078: *     .. External Functions ..
079:       LOGICAL            LSAME
080:       EXTERNAL           LSAME
081: *     ..
082: *     .. Intrinsic Functions ..
083:       INTRINSIC          ABS, MAX, MIN, SQRT
084: *     ..
085: *     .. Executable Statements ..
086: *
087:       IF( MIN( M, N ).EQ.0 ) THEN
088:          VALUE = ZERO
089:       ELSE IF( LSAME( NORM, 'M' ) ) THEN
090: *
091: *        Find max(abs(A(i,j))).
092: *
093:          VALUE = ZERO
094:          DO 20 J = 1, N
095:             DO 10 I = 1, M
096:                VALUE = MAX( VALUE, ABS( A( I, J ) ) )
097:    10       CONTINUE
098:    20    CONTINUE
099:       ELSE IF( ( LSAME( NORM, 'O' ) ) .OR. ( NORM.EQ.'1' ) ) THEN
100: *
101: *        Find norm1(A).
102: *
103:          VALUE = ZERO
104:          DO 40 J = 1, N
105:             SUM = ZERO
106:             DO 30 I = 1, M
107:                SUM = SUM + ABS( A( I, J ) )
108:    30       CONTINUE
109:             VALUE = MAX( VALUE, SUM )
110:    40    CONTINUE
111:       ELSE IF( LSAME( NORM, 'I' ) ) THEN
112: *
113: *        Find normI(A).
114: *
115:          DO 50 I = 1, M
116:             WORK( I ) = ZERO
117:    50    CONTINUE
118:          DO 70 J = 1, N
119:             DO 60 I = 1, M
120:                WORK( I ) = WORK( I ) + ABS( A( I, J ) )
121:    60       CONTINUE
122:    70    CONTINUE
123:          VALUE = ZERO
124:          DO 80 I = 1, M
125:             VALUE = MAX( VALUE, WORK( I ) )
126:    80    CONTINUE
127:       ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
128: *
129: *        Find normF(A).
130: *
131:          SCALE = ZERO
132:          SUM = ONE
133:          DO 90 J = 1, N
134:             CALL SLASSQ( M, A( 1, J ), 1, SCALE, SUM )
135:    90    CONTINUE
136:          VALUE = SCALE*SQRT( SUM )
137:       END IF
138: *
139:       SLANGE = VALUE
140:       RETURN
141: *
142: *     End of SLANGE
143: *
144:       END
145: