001:       REAL FUNCTION SLA_SYRCOND( UPLO, N, A, LDA, AF, LDAF, IPIV, CMODE,
002:      $                           C, INFO, WORK, IWORK )
003: *
004: *     -- LAPACK routine (version 3.2)                                 --
005: *     -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
006: *     -- Jason Riedy of Univ. of California Berkeley.                 --
007: *     -- November 2008                                                --
008: *
009: *     -- LAPACK is a software package provided by Univ. of Tennessee, --
010: *     -- Univ. of California Berkeley and NAG Ltd.                    --
011: *
012:       IMPLICIT NONE
013: *     ..
014: *     .. Scalar Arguments ..
015:       CHARACTER          UPLO
016:       INTEGER            N, LDA, LDAF, INFO, CMODE
017: *     ..
018: *     .. Array Arguments
019:       INTEGER            IWORK( * ), IPIV( * )
020:       REAL               A( LDA, * ), AF( LDAF, * ), WORK( * ), C( * )
021: *
022: *     SLA_SYRCOND estimates the Skeel condition number of  op(A) * op2(C)
023: *     where op2 is determined by CMODE as follows
024: *     CMODE =  1    op2(C) = C
025: *     CMODE =  0    op2(C) = I
026: *     CMODE = -1    op2(C) = inv(C)
027: *     The Skeel condition number cond(A) = norminf( |inv(A)||A| )
028: *     is computed by computing scaling factors R such that
029: *     diag(R)*A*op2(C) is row equilibrated and computing the standard
030: *     infinity-norm condition number.
031: *     WORK is a real workspace of size 3*N, and
032: *     IWORK is an integer workspace of size N.
033: *     ..
034: *     .. Local Scalars ..
035:       CHARACTER          NORMIN
036:       INTEGER            KASE, I, J
037:       REAL               AINVNM, SMLNUM, TMP
038:       LOGICAL            UP
039: *     ..
040: *     .. Local Arrays ..
041:       INTEGER            ISAVE( 3 )
042: *     ..
043: *     .. External Functions ..
044:       LOGICAL            LSAME
045:       INTEGER            ISAMAX
046:       REAL               SLAMCH
047:       EXTERNAL           LSAME, ISAMAX, SLAMCH
048: *     ..
049: *     .. External Subroutines ..
050:       EXTERNAL           SLACN2, SLATRS, SRSCL, XERBLA, SSYTRS
051: *     ..
052: *     .. Intrinsic Functions ..
053:       INTRINSIC          ABS, MAX
054: *     ..
055: *     .. Executable Statements ..
056: *
057:       SLA_SYRCOND = 0.0
058: *
059:       INFO = 0
060:       IF( N.LT.0 ) THEN
061:          INFO = -2
062:       END IF
063:       IF( INFO.NE.0 ) THEN
064:          CALL XERBLA( 'SLA_SYRCOND', -INFO )
065:          RETURN
066:       END IF
067:       IF( N.EQ.0 ) THEN
068:          SLA_SYRCOND = 1.0
069:          RETURN
070:       END IF
071:       UP = .FALSE.
072:       IF ( LSAME( UPLO, 'U' ) ) UP = .TRUE.
073: *
074: *     Compute the equilibration matrix R such that
075: *     inv(R)*A*C has unit 1-norm.
076: *
077:       IF ( UP ) THEN
078:          DO I = 1, N
079:             TMP = 0.0
080:             IF ( CMODE .EQ. 1 ) THEN
081:                DO J = 1, I
082:                   TMP = TMP + ABS( A( J, I ) * C( J ) )
083:                END DO
084:                DO J = I+1, N
085:                   TMP = TMP + ABS( A( I, J ) * C( J ) )
086:                END DO
087:             ELSE IF ( CMODE .EQ. 0 ) THEN
088:                DO J = 1, I
089:                   TMP = TMP + ABS( A( J, I ) )
090:                END DO
091:                DO J = I+1, N
092:                   TMP = TMP + ABS( A( I, J ) )
093:                END DO
094:             ELSE
095:                DO J = 1, I
096:                   TMP = TMP + ABS( A( J, I ) / C( J ) )
097:                END DO
098:                DO J = I+1, N
099:                   TMP = TMP + ABS( A( I, J ) / C( J ) )
100:                END DO
101:             END IF
102:             WORK( 2*N+I ) = TMP
103:          END DO
104:       ELSE
105:          DO I = 1, N
106:             TMP = 0.0
107:             IF ( CMODE .EQ. 1 ) THEN
108:                DO J = 1, I
109:                   TMP = TMP + ABS( A( I, J ) * C( J ) )
110:                END DO
111:                DO J = I+1, N
112:                   TMP = TMP + ABS( A( J, I ) * C( J ) )
113:                END DO
114:             ELSE IF ( CMODE .EQ. 0 ) THEN
115:                DO J = 1, I
116:                   TMP = TMP + ABS( A( I, J ) )
117:                END DO
118:                DO J = I+1, N
119:                   TMP = TMP + ABS( A( J, I ) )
120:                END DO
121:             ELSE
122:                DO J = 1, I
123:                   TMP = TMP + ABS( A( I, J) / C( J ) )
124:                END DO
125:                DO J = I+1, N
126:                   TMP = TMP + ABS( A( J, I) / C( J ) )
127:                END DO
128:             END IF
129:             WORK( 2*N+I ) = TMP
130:          END DO
131:       ENDIF
132: *
133: *     Estimate the norm of inv(op(A)).
134: *
135:       SMLNUM = SLAMCH( 'Safe minimum' )
136:       AINVNM = 0.0
137:       NORMIN = 'N'
138: 
139:       KASE = 0
140:    10 CONTINUE
141:       CALL SLACN2( N, WORK( N+1 ), WORK, IWORK, AINVNM, KASE, ISAVE )
142:       IF( KASE.NE.0 ) THEN
143:          IF( KASE.EQ.2 ) THEN
144: *
145: *           Multiply by R.
146: *
147:             DO I = 1, N
148:                WORK( I ) = WORK( I ) * WORK( 2*N+I )
149:             END DO
150: 
151:             IF ( UP ) THEN
152:                call ssytrs( 'U', n, 1, af, ldaf, ipiv, work, n, info )
153:             ELSE
154:                call ssytrs( 'L', n, 1, af, ldaf, ipiv, work, n, info )
155:             ENDIF
156: *
157: *           Multiply by inv(C).
158: *
159:             IF ( CMODE .EQ. 1 ) THEN
160:                DO I = 1, N
161:                   WORK( I ) = WORK( I ) / C( I )
162:                END DO
163:             ELSE IF ( CMODE .EQ. -1 ) THEN
164:                DO I = 1, N
165:                   WORK( I ) = WORK( I ) * C( I )
166:                END DO
167:             END IF
168:          ELSE
169: *
170: *           Multiply by inv(C').
171: *
172:             IF ( CMODE .EQ. 1 ) THEN
173:                DO I = 1, N
174:                   WORK( I ) = WORK( I ) / C( I )
175:                END DO
176:             ELSE IF ( CMODE .EQ. -1 ) THEN
177:                DO I = 1, N
178:                   WORK( I ) = WORK( I ) * C( I )
179:                END DO
180:             END IF
181: 
182:             IF ( UP ) THEN
183:                call ssytrs( 'U', n, 1, af, ldaf, ipiv, work, n, info )
184:             ELSE
185:                call ssytrs( 'L', n, 1, af, ldaf, ipiv, work, n, info )
186:             ENDIF
187: *
188: *           Multiply by R.
189: *
190:             DO I = 1, N
191:                WORK( I ) = WORK( I ) * WORK( 2*N+I )
192:             END DO
193:          END IF
194: *
195:          GO TO 10
196:       END IF
197: *
198: *     Compute the estimate of the reciprocal condition number.
199: *
200:       IF( AINVNM .NE. 0.0 )
201:      $   SLA_SYRCOND = ( 1.0 / AINVNM )
202: *
203:       RETURN
204: *
205:       END
206: